lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Four shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 Similar problem for
  23
  24  * \markup identifier.
  25  * \markup { }
  26
  27
  28 2.  \repeat
  29         \repeat .. \alternative
  30
  31
  32     \repeat { \repeat .. \alternative }
  33
  34 or
  35
  36     \repeat { \repeat } \alternative
  37
  38 )
  39
  40 --hwn
  41
  42  */
  43
  44 /*
  45
  46 TODO:
  47
  48 * The rules for who is protecting what are very shady. Uniformise
  49   this.
  50
  51 * There are too many lexical modes?
  52
  53 */
  54
  55 #include <ctype.h>
  56 #include <stdlib.h>
  57 #include <stdio.h>
  58
  59
  60 #include "scm-option.hh"
  61 #include "context-def.hh"
  62 #include "lily-guile.hh"
  63 #include "misc.hh"
  64 #include "my-lily-lexer.hh"
  65 #include "paper-def.hh"
  66 #include "midi-def.hh"
  67 #include "main.hh"
  68 #include "file-path.hh"
  69 #include "warn.hh"
  70 #include "dimensions.hh"
  71 #include "my-lily-parser.hh"
  72 #include "score.hh"
  73 #include "input-file-results.hh"
  74 #include "input.hh"
  75 #include "lilypond-input-version.hh"
  76 #include "scm-hash.hh"
  77 #include "ly-module.hh"
  78 #include "music-sequence.hh"
  79 #include "input-smob.hh"
  80 #include "event.hh"
  81 #include "text-item.hh"
  82 #include "music-list.hh"
  83 #include "paper-book.hh"
  84
  85 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  86
  87 Music *property_op_to_music (SCM op);
  88 Music *context_spec_music (SCM type, SCM id, Music * m, SCM ops_);
  89 SCM get_next_unique_context ();
  90
  91 #define YYERROR_VERBOSE 1
  92
  93 My_lily_parser* my_lily_parser;
  94 #define YYPARSE_PARAM my_lily_parser
  95 #define YYLEX_PARAM my_lily_parser
  96 #define THIS\
  97         ((My_lily_parser *) my_lily_parser)
  98
  99 #define yyerror THIS->parser_error
 100
 101 /*
 102   Add symbols to the  TAGS field of a music object.
 103 */
 104
 105 void
 106 tag_music (Music*m,  SCM tag, Input ip)
 107 {
 108         SCM tags = m->get_property ("tags");
 109         if (gh_symbol_p (tag))
 110                 tags = scm_cons (tag, tags);
 111         else if (gh_list_p (tag))
 112                 tags = gh_append2 (tag, tags);
 113         else
 114                 ip.warning (_("Tag must be symbol or list of symbols."));
 115
 116         m->set_property ("tags", tags);
 117 }
 118
 119
 120
 121 bool
 122 is_regular_identifier (SCM id)
 123 {
 124   String str = ly_scm2string (id);
 125   char const *s = str.to_str0 () ;
 126
 127   bool v = true;
 128 /*
 129   isalpha (*s);
 130   s++;
 131 */
 132   while (*s && v)
 133    {
 134         v = v && isalnum (*s);
 135         s++;
 136    }
 137   return v;
 138 }
 139
 140 SCM
 141 make_simple_markup (SCM a)
 142 {
 143         SCM simple = ly_scheme_function ("simple-markup");
 144
 145         return scm_list_2 (simple, a);
 146 }
 147
 148
 149 bool
 150 is_is_duration (int t)
 151 {
 152   return t && t == 1 << intlog2 (t);
 153 }
 154
 155 void
 156 set_music_properties (Music *p, SCM a)
 157 {
 158   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 159         {
 160         p->internal_set_property (ly_caar (k), ly_cdar (k));
 161         }
 162 }
 163
 164 SCM
 165 make_chord_step (int step, int alter)
 166 {
 167         if (step == 7)
 168                 alter += FLAT;
 169
 170         while(step < 0)
 171                 step += 7;
 172         Pitch m((step -1) / 7 , (step - 1) % 7, alter);
 173         return m.smobbed_copy ();
 174 }
 175
 176
 177 SCM
 178 make_chord (SCM pitch, SCM dur, SCM modification_list)
 179 {
 180         SCM chord_ctor = ly_scheme_function ("construct-chord");
 181         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 182         scm_gc_protect_object (ch);
 183         return ch;
 184 }
 185
 186 /*
 187   Todo: actually also use apply iso. call too ...
 188 */
 189 bool
 190 ly_input_procedure_p (SCM x)
 191 {
 192         return gh_procedure_p (x)
 193                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 194 }
 195
 196 Music*
 197 set_property_music (SCM sym, SCM value)
 198 {
 199         Music * p = MY_MAKE_MUSIC ("PropertySet");
 200         p->set_property ("symbol", sym);
 201         p->set_property ("value", value);
 202         return p;
 203 }
 204
 205 %}
 206
 207 /* We use SCMs to do strings, because it saves us the trouble of
 208 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 209 of the parse stack onto the heap. */
 210
 211
 212 %union {
 213         String * string;
 214     Music *music;
 215     Score *score;
 216     Music_output_def * outputdef;
 217     SCM scm;
 218     int i;
 219 }
 220 %{
 221
 222 int
 223 yylex (YYSTYPE *s,  void * v)
 224 {
 225         My_lily_parser   *pars = (My_lily_parser*) v;
 226         My_lily_lexer * lex = pars->lexer_;
 227
 228         lex->lexval = (void*) s;
 229         lex->prepare_for_next_token ();
 230         return lex->yylex ();
 231 }
 232
 233
 234 %}
 235
 236 %pure_parser
 237
 238
 239 %token ACCEPTS
 240 %token ADDLYRICS
 241 %token ADDQUOTE
 242 %token NEWADDLYRICS
 243 %token ALIAS
 244 %token ALTERNATIVE
 245 %token APPLY
 246 %token APPLYCONTEXT
 247 %token APPLYOUTPUT
 248 %token AUTOCHANGE
 249 %token BAR
 250 %token BREATHE
 251 %token CHANGE
 252 %token CHORDMODIFIERS
 253 %token CHORDS
 254 %token LESSLESS
 255 %token MOREMORE
 256 %token CLEF
 257 %token COMMANDSPANREQUEST
 258 %token CONSISTS
 259 %token CONSISTSEND
 260 %token CONTEXT
 261 %token DEFAULT
 262 %token DENIES
 263 %token DESCRIPTION
 264 %token EXTENDER
 265 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 266 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 267 %token GRACE
 268 %token ACCIACCATURA
 269 %token APPOGGIATURA
 270 %token GROBDESCRIPTIONS
 271 %token HEADER
 272 %token HYPHEN
 273 %token INVALID
 274 %token KEY
 275 %token LYRICS
 276 %token MARK
 277 %token MIDI
 278 %token MULTI_MEASURE_REST
 279 %token NAME
 280 %token NEWCONTEXT
 281 %token NOTES
 282 %token OCTAVE
 283 %token ONCE
 284 %token OVERRIDE SET REVERT
 285 %token PAPER
 286 %token PARTCOMBINE
 287 %token PARTIAL
 288 %token QUOTE
 289 %token RELATIVE
 290 %token REMOVE
 291 %token REPEAT
 292 %token REST
 293 %token SCM_T
 294 %token SCORE
 295 %token SEQUENTIAL
 296 %token SIMULTANEOUS
 297 %token SKIP
 298 %token SPANREQUEST
 299 %token TAG
 300 %token TEMPO
 301 %token TIMES
 302 %token TIME_T
 303 %token TRANSPOSE
 304 %token TRANSPOSITION
 305 %token TYPE
 306 %token UNSET
 307 %token WITH
 308
 309 /* escaped */
 310 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 311 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 312 %token E_BACKSLASH
 313 %token <i> E_UNSIGNED
 314 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 315 %token FIGURE_SPACE
 316
 317 %type <i>       exclamations questions dots optional_rest
 318 %type <i>        bass_mod
 319 %type <scm>     grace_head
 320 %type <scm>     oct_check
 321 %type <scm>     context_mod_list
 322 %type <scm>     lyric_element
 323 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 324 %token <i>      DIGIT
 325 %token <scm>    NOTENAME_PITCH
 326 %token <scm>    TONICNAME_PITCH
 327 %token <scm>    CHORDMODIFIER_PITCH
 328 %token <scm>    DURATION_IDENTIFIER
 329 %token <scm>    FRACTION
 330 %token <id>     IDENTIFIER
 331 %token DRUMS
 332 %token <scm>    DRUM_PITCH
 333 %token <scm>    CHORD_MODIFIER
 334 %token <scm>    SCORE_IDENTIFIER
 335 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 336 %token <scm>    NUMBER_IDENTIFIER
 337 %token <scm>    EVENT_IDENTIFIER
 338 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 339 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 340 %token <scm>    RESTNAME
 341 %token <scm>    STRING
 342 %token <scm>    SCM_T
 343 %token <i>      UNSIGNED
 344 %token <scm>   REAL
 345
 346 %token MARKUP
 347 %token <scm> MARKUP_HEAD_MARKUP0
 348 %token <scm> MARKUP_HEAD_EMPTY
 349 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 350 %token <scm> MARKUP_HEAD_SCM0
 351 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 352 %token <scm> MARKUP_HEAD_SCM0_SCM1
 353 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 354 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 355
 356 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 357 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 358
 359 %type <outputdef> output_def
 360 %type <scm>     lilypond_header lilypond_header_body
 361 %type <music>   open_event close_event
 362 %type <i>       sub_quotes sup_quotes
 363 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 364 %type <music>   Repeated_music
 365 %type <scm>     Alternative_music
 366 %type <i>       tremolo_type
 367 %type <i>       bare_int  bare_unsigned
 368 %type <i>       script_dir
 369 %type <scm>     identifier_init
 370
 371 %type <music> note_chord_element chord_body chord_body_element
 372 %type <scm>  chord_body_elements
 373 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 374
 375 %type <scm>   post_events
 376 %type <music> gen_text_def direction_less_event direction_reqd_event
 377 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 378 %type <scm>    steno_tonic_pitch
 379 %type <scm>     duration_length fraction
 380
 381 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 382
 383 %type <scm>  embedded_scm scalar
 384 %type <music>   Music Sequential_music Simultaneous_music
 385 %type <music>   relative_music re_rhythmed_music
 386 %type <music>   music_property_def context_change
 387 %type <scm> context_prop_spec
 388 %type <scm> Music_list
 389 %type <scm> property_operation context_mod context_def_mod optional_context_mod
 390 %type <outputdef>  music_output_def_body music_output_def_head
 391 %type <music>   post_event tagged_post_event
 392 %type <music> command_req
 393 %type <music> string_number_event
 394 %type <scm>     string bare_number number_expression number_term number_factor
 395 %type <score>   score_block score_body
 396
 397 %type <scm>     context_def_spec_block context_def_spec_body
 398 %type <music>   tempo_event
 399 %type <scm>     script_abbreviation
 400
 401
 402
 403 %left '-' '+'
 404
 405 /* We don't assign precedence to / and *, because we might need varied
 406 prec levels in different prods */
 407
 408 %left UNARY_MINUS
 409
 410 %%
 411
 412 lilypond:       /* empty */
 413         | lilypond toplevel_expression {}
 414         | lilypond assignment  { }
 415         | lilypond error {
 416                 THIS->error_level_  = 1;
 417         }
 418         | lilypond INVALID      {
 419                 THIS->error_level_  = 1;
 420         }
 421         ;
 422
 423 toplevel_expression:
 424         lilypond_header {
 425                 THIS->input_file_->header_ = $1;
 426         }
 427         | add_quote {
 428         }
 429         | score_block {
 430                 Score * sc = $1;
 431
 432                 SCM head = ly_module_p (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 433
 434                 Path p = split_path (THIS->output_basename_);
 435                 int *c =  &THIS->input_file_->score_count_;
 436                 if (*c)
 437                         {
 438                         p.base += "-" + to_string (*c);
 439                         }
 440
 441                 (*c)++;
 442                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 443
 444                 for (int i=0; i < sc->defs_.size (); i++)
 445                         default_rendering (sc->music_, sc->defs_[i]->self_scm (), head, outname);
 446
 447                 if (sc->defs_.is_empty ())
 448                 {
 449                    Music_output_def *id =
 450                         unsmob_music_output_def (THIS->lexer_->lookup_identifier
 451                                 ("$defaultpaper"));
 452
 453                    id = id ? id->clone () : new Paper_def;
 454
 455                    default_rendering (sc->music_, id->self_scm (), head, outname);
 456                    scm_gc_unprotect_object (id->self_scm ());
 457                 }
 458                 scm_gc_unprotect_object (sc->self_scm ());
 459         }
 460         | output_def {
 461                 SCM id = SCM_EOL;
 462                 if (dynamic_cast<Paper_def*> ($1))
 463                         id = scm_makfrom0str ("$defaultpaper");
 464                 else if (dynamic_cast<Midi_def*> ($1))
 465                         id = scm_makfrom0str ("$defaultmidi");
 466                 THIS->lexer_->set_identifier (id,   $1->self_scm ());
 467                 scm_gc_unprotect_object ($1->self_scm ());
 468         }
 469         ;
 470
 471
 472 embedded_scm:
 473         SCM_T
 474         | SCM_IDENTIFIER
 475         ;
 476
 477
 478
 479
 480 lilypond_header_body:
 481         {
 482                 $$ = ly_make_anonymous_module ();
 483                 THIS->lexer_->add_scope ($$);
 484         }
 485         | lilypond_header_body assignment  {
 486
 487         }
 488         ;
 489
 490 lilypond_header:
 491         HEADER '{' lilypond_header_body '}'     {
 492                 $$ = THIS->lexer_->remove_scope ();
 493         }
 494         ;
 495
 496
 497 /*
 498         DECLARATIONS
 499 */
 500 assignment:
 501         STRING {
 502                 THIS->push_spot ();
 503         }
 504         /* cont */ '=' identifier_init  {
 505
 506         /*
 507                 Should find generic way of associating input with objects.
 508         */
 509                 Input ip = THIS->pop_spot ();
 510
 511                 if (! is_regular_identifier ($1))
 512                 {
 513                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 514                 }
 515
 516                 THIS->lexer_->set_identifier ($1, $4);
 517
 518 /*
 519  TODO: devise standard for protection in parser.
 520
 521   The parser stack lives on the C-stack, which means that
 522 all objects can be unprotected as soon as they're here.
 523
 524 */
 525         }
 526         | embedded_scm { }
 527         ;
 528
 529
 530 identifier_init:
 531         score_block {
 532                 $$ = $1->self_scm ();
 533                 scm_gc_unprotect_object ($$);
 534         }
 535         | full_markup {
 536                 $$ = $1;
 537         }
 538         | output_def {
 539                 $$ = $1->self_scm ();
 540                 scm_gc_unprotect_object ($$);
 541         }
 542         | context_def_spec_block {
 543                 $$ = $1;
 544         }
 545         | Music  {
 546                 $$ = $1->self_scm ();
 547                 scm_gc_unprotect_object ($$);
 548         }
 549         | post_event {
 550                 $$ = $1->self_scm ();
 551                 scm_gc_unprotect_object ($$);
 552         }
 553         | number_expression {
 554                 $$ = $1;
 555         }
 556         | string {
 557                 $$ = $1;
 558         }
 559         | embedded_scm  {
 560                 $$ = $1;
 561         }
 562         ;
 563
 564 context_def_spec_block:
 565         CONTEXT '{' context_def_spec_body '}'
 566                 {
 567                 $$ = $3;
 568         }
 569         ;
 570
 571 context_def_spec_body:
 572         /**/ {
 573                 $$ = Context_def::make_scm ();
 574                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 575         }
 576         | CONTEXT_DEF_IDENTIFIER        {
 577                 $$ = $1;
 578                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 579         }
 580         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 581                 Context_def*td = unsmob_context_def ($$);
 582
 583                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p)) {
 584                         SCM tag = gh_caar (p);
 585
 586                         /* TODO: should make new tag "grob-definition" ? */
 587                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 588                                                         tag, gh_cons (ly_cdar (p), SCM_EOL)));
 589                 }
 590         }
 591         | context_def_spec_body context_mod {
 592                 unsmob_context_def ($$)->add_context_mod ($2);
 593         }
 594         ;
 595
 596 /*
 597         SCORE
 598 */
 599 score_block:
 600         SCORE {
 601                 THIS->push_spot ();
 602         }
 603         /*cont*/ '{' score_body '}'     {
 604                 THIS->pop_spot ();
 605                 $$ = $4;
 606
 607         }
 608         ;
 609
 610 score_body:
 611         Music   {
 612                 $$ = new Score;
 613
 614                 $$->set_spot (THIS->here_input ());
 615                 SCM m = $1->self_scm ();
 616                 scm_gc_unprotect_object (m);
 617
 618                 /*
 619                         guh.
 620                 */
 621                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 622                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 623                         m = gh_call1 (gh_car (check_funcs), m);
 624                 $$->music_ = m;
 625
 626         }
 627         | SCORE_IDENTIFIER {
 628                 $$ = new Score ( *unsmob_score ($1));
 629                 $$->set_spot (THIS->here_input ());
 630         }
 631         | score_body lilypond_header    {
 632                 $$->header_ = $2;
 633         }
 634         | score_body output_def {
 635                 $$->defs_.push ($2);
 636                 scm_gc_unprotect_object ($2->self_scm ());
 637         }
 638         | score_body error {
 639
 640         }
 641         ;
 642
 643
 644 /*
 645         MIDI
 646 */
 647 output_def:
 648         music_output_def_body '}' {
 649                 $$ = $1;
 650                 THIS-> lexer_-> remove_scope ();
 651         }
 652         ;
 653
 654 music_output_def_head:
 655         MIDI    {
 656                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 657
 658
 659                 Midi_def* p =0;
 660                 if (id)
 661                         p = dynamic_cast<Midi_def*> (id->clone ());
 662                 else
 663                         p = new Midi_def;
 664
 665                 $$ = p;
 666                 THIS->lexer_->add_scope (p->scope_);
 667         }
 668         | PAPER         {
 669                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 670                   Paper_def *p = 0;
 671                 if (id)
 672                         p = dynamic_cast<Paper_def*> (id->clone ());
 673                 else
 674                         p = new Paper_def;
 675
 676                 THIS->lexer_->add_scope (p->scope_);
 677                 $$ = p;
 678         }
 679         ;
 680
 681
 682 music_output_def_body:
 683         music_output_def_head '{' {
 684                 $$ = $1;
 685                 $$->input_origin_. set_spot (THIS->here_input ());
 686
 687         }
 688         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 689                 scm_gc_unprotect_object ($1->self_scm ());
 690                 Music_output_def * o =  unsmob_music_output_def ($3);
 691                 o->input_origin_.set_spot (THIS->here_input ());
 692                 $$ = o;
 693                 THIS->lexer_->remove_scope ();
 694                 THIS->lexer_->add_scope (o->scope_);
 695         }
 696         | music_output_def_body assignment  {
 697
 698         }
 699         | music_output_def_body context_def_spec_block  {
 700                 $$->assign_context_def ($2);
 701         }
 702         | music_output_def_body tempo_event  {
 703                 /*
 704                         junk this ? there already is tempo stuff in
 705                         music.
 706                 */
 707                 int m = gh_scm2int ( $2->get_property ("metronome-count"));
 708                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 709                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 710                 if (md)
 711                         md->set_tempo (d->get_length (), m);
 712                 scm_gc_unprotect_object ($2->self_scm ());
 713         }
 714         | music_output_def_body error {
 715
 716         }
 717         ;
 718
 719 tempo_event:
 720         TEMPO steno_duration '=' bare_unsigned  {
 721                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 722                 $$->set_property ("tempo-unit", $2);
 723                 $$->set_property ("metronome-count", gh_int2scm ( $4));
 724         }
 725         ;
 726
 727 /*
 728 The representation of a  list is the
 729
 730   (LIST . LAST-CONS)
 731
 732  to have  efficient append.
 733 */
 734 Music_list:
 735         /* empty */ {
 736                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 737         }
 738         | Music_list Music {
 739                 SCM s = $$;
 740                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 741                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 742                 if (gh_pair_p (ly_cdr (s)))
 743                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 744                 else
 745                         gh_set_car_x (s, c); /* set first cons */
 746                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 747         }
 748         | Music_list error {
 749         }
 750         ;
 751
 752
 753 Music:
 754         Simple_music
 755         | Composite_music
 756         ;
 757
 758 Alternative_music:
 759         /* empty */ {
 760                 $$ = SCM_EOL;
 761         }
 762         | ALTERNATIVE '{' Music_list '}' {
 763                 $$ = $3;
 764         }
 765         ;
 766
 767 Repeated_music:
 768         REPEAT string bare_unsigned Music Alternative_music
 769         {
 770                 Music *beg = $4;
 771                 int times = $3;
 772                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 773                 if (times < scm_ilength (alts)) {
 774                   unsmob_music (gh_car (alts))
 775                     ->origin ()->warning (
 776                     _("More alternatives than repeats.  Junking excess alternatives."));
 777                   alts = ly_truncate_list (times, alts);
 778                 }
 779
 780
 781                 SCM proc = ly_scheme_function ("make-repeated-music");
 782
 783                 SCM mus = scm_call_1 (proc, $2);
 784                 scm_gc_protect_object (mus); // UGH.
 785                 Music *r =unsmob_music (mus);
 786                 if (beg)
 787                         {
 788                         r-> set_property ("element", beg->self_scm ());
 789                         scm_gc_unprotect_object (beg->self_scm ());
 790                         }
 791                 r->set_property ("repeat-count", gh_int2scm (times >? 1));
 792
 793                 r-> set_property ("elements",alts);
 794                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 795                         /*
 796                         we can not get durations and other stuff correct down the line, so we have to
 797                         add to the duration log here.
 798                         */
 799                         SCM func = ly_scheme_function ("shift-duration-log");
 800
 801                         int dots = ($3 % 3) ? 0 : 1;
 802                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 803
 804                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 805
 806                         if (seq) {
 807                                 int list_len =scm_ilength (seq->music_list ());
 808                                 if (list_len != 2)
 809                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 810                                 shift -= 1;
 811                                 r->compress (Moment (Rational (1,list_len)));
 812                                 }
 813                         gh_call3 (func, r->self_scm (), gh_int2scm (shift),gh_int2scm (dots));
 814
 815                 }
 816                 r->set_spot (*$4->origin ());
 817
 818                 $$ = r;
 819         }
 820         ;
 821
 822 Sequential_music:
 823         SEQUENTIAL '{' Music_list '}'           {
 824                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 825                 $$->set_property ("elements", ly_car ($3));
 826                 $$->set_spot (THIS->here_input ());
 827         }
 828         | '{' Music_list '}'            {
 829                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 830                 $$->set_property ("elements", ly_car ($2));
 831                 $$->set_spot (THIS->here_input ());
 832         }
 833         ;
 834
 835 Simultaneous_music:
 836         SIMULTANEOUS '{' Music_list '}'{
 837                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 838                 $$->set_property ("elements", ly_car ($3));
 839                 $$->set_spot (THIS->here_input ());
 840
 841         }
 842         | simul_open Music_list simul_close     {
 843                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 844                 $$->set_property ("elements", ly_car ($2));
 845                 $$->set_spot (THIS->here_input ());
 846         }
 847         ;
 848
 849 Simple_music:
 850         event_chord             { $$ = $1; }
 851         | APPLYOUTPUT embedded_scm {
 852                 if (!ly_input_procedure_p ($2))
 853                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 854                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 855                 $$->set_property ("procedure", $2);
 856                 $$->set_spot (THIS->here_input ());
 857         }
 858         | APPLYCONTEXT embedded_scm {
 859                 if (!ly_input_procedure_p ($2))
 860                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 861                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 862                 $$->set_property ("procedure", $2);
 863                 $$->set_spot (THIS->here_input ());
 864         }
 865         | MUSIC_IDENTIFIER {
 866                 $$ = unsmob_music ($1);
 867         }
 868         | music_property_def
 869         | context_change
 870         ;
 871
 872
 873 optional_context_mod:
 874         /**/ { $$ = SCM_EOL; }
 875         | WITH '{' context_mod_list '}'  { $$ = $3; }
 876         ;
 877
 878 grace_head:
 879         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 880         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 881         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 882         ;
 883
 884 context_mod_list:
 885         /* */  { $$ = SCM_EOL; }
 886         | context_mod_list context_mod  {
 887                  $$ = gh_cons ($2, $1);
 888         }
 889         ;
 890
 891 Composite_music:
 892         AUTOCHANGE Music        {
 893                 SCM proc = ly_scheme_function ("make-autochange-music");
 894
 895                 SCM res = scm_call_1 (proc,  $2->self_scm ());
 896                 scm_gc_unprotect_object ($2->self_scm ());
 897                 $$ = unsmob_music (res);
 898                 scm_gc_protect_object (res);
 899                 $$->set_spot (THIS->here_input ());
 900         }
 901         | PARTCOMBINE Music Music {
 902                 SCM proc = ly_scheme_function ("make-part-combine-music");
 903
 904                 SCM res = scm_call_1 (proc, gh_list ($2->self_scm (),
 905                         $3->self_scm (), SCM_UNDEFINED));
 906                 scm_gc_unprotect_object ($3->self_scm ());
 907                 scm_gc_unprotect_object ($2->self_scm ());
 908                 $$ = unsmob_music (res);
 909                 scm_gc_protect_object (res);
 910                 $$->set_spot (THIS->here_input ());
 911         }
 912         | grace_head Music {
 913 #if 1
 914         /*
 915                 The other version is for easier debugging  of
 916                 Sequential_music_iterator in combination with grace notes.
 917         */
 918
 919 /*
 920
 921 TODO: should distinguish between both grace types in the
 922 basic music objects too, since the meaning is different.
 923
 924 */
 925
 926                 String start_str = "start" + ly_scm2string ($1) + "Music";
 927                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 928
 929                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 930                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 931
 932                 Music *startm = unsmob_music (start);
 933                 Music *stopm = unsmob_music (stop);
 934
 935                 SCM ms = SCM_EOL;
 936                 if (stopm) {
 937                         stopm = stopm->clone ();
 938                         ms = scm_cons (stopm->self_scm (), ms);
 939                         scm_gc_unprotect_object (stopm->self_scm ());
 940                 }
 941                 ms = scm_cons ($2->self_scm (), ms);
 942                 scm_gc_unprotect_object ($2->self_scm ());
 943                 if (startm) {
 944                         startm = startm->clone ();
 945                         ms = scm_cons (startm->self_scm () , ms);
 946                         scm_gc_unprotect_object (startm->self_scm ());
 947                 }
 948
 949                 Music* seq = MY_MAKE_MUSIC ("SequentialMusic");
 950                 seq->set_property ("elements", ms);
 951
 952
 953                 $$ = MY_MAKE_MUSIC ("GraceMusic");
 954                 $$->set_property ("element", seq->self_scm ());
 955                 scm_gc_unprotect_object (seq->self_scm ());
 956 #else
 957                 $$ = MY_MAKE_MUSIC ("GraceMusic");
 958                 $$->set_property ("element", $2->self_scm ());
 959                 scm_gc_unprotect_object ($2->self_scm ());
 960 #endif
 961         }
 962         | CONTEXT string '=' string optional_context_mod Music {
 963                 $$ = context_spec_music ($2, $4, $6, $5);
 964
 965         }
 966         | CONTEXT STRING optional_context_mod Music {
 967                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
 968         }
 969         | NEWCONTEXT string optional_context_mod Music {
 970                 $$ = context_spec_music ($2, get_next_unique_context (),
 971                                          $4, $3);
 972         }
 973
 974         | TIMES {
 975                 THIS->push_spot ();
 976         }
 977         /* CONTINUED */
 978                 fraction Music
 979
 980         {
 981                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 982                 Music *mp = $4;
 983
 984                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
 985                 $$->set_spot (THIS->pop_spot ());
 986
 987                 $$->set_property ("element", mp->self_scm ());
 988                 scm_gc_unprotect_object (mp->self_scm ());
 989                 $$->set_property ("numerator", gh_int2scm (n));
 990                 $$->set_property ("denominator", gh_int2scm (d));
 991                 $$->compress (Moment (Rational (n,d)));
 992
 993         }
 994         | Repeated_music                { $$ = $1; }
 995         | Simultaneous_music            { $$ = $1; }
 996         | Sequential_music              { $$ = $1; }
 997         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
 998                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
 999                 Music *p = $4;
1000                 Pitch from = *unsmob_pitch ($2);
1001                 Pitch to = *unsmob_pitch ($3);
1002
1003                 p->transpose (interval (from, to));
1004                 $$->set_property ("element", p->self_scm ());
1005                 scm_gc_unprotect_object (p->self_scm ());
1006         }
1007         | APPLY embedded_scm Music  {
1008                 if (!ly_input_procedure_p ($2))
1009                         {
1010                         THIS->parser_error (_ ("\\apply takes function argument"));
1011                         $$ = $3;
1012                         }
1013                 else
1014                         {
1015                         SCM ret = gh_call1 ($2, $3->self_scm ());
1016                         Music *m = unsmob_music (ret);
1017                         if (!m) {
1018                                 THIS->parser_error ("\\apply must return a Music");
1019                                 m = MY_MAKE_MUSIC ("Music");
1020                                 }
1021                         $$ = m;
1022                         }
1023         }
1024         | NOTES
1025                 {
1026                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1027                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1028         }
1029         Music
1030                 { $$ = $3;
1031                   THIS->lexer_->pop_state ();
1032                 }
1033         | DRUMS
1034                 {
1035                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1036                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1037         }
1038         Music
1039                 { $$ = $3;
1040                   THIS->lexer_->pop_state ();
1041                 }
1042         | FIGURES
1043                 { THIS->lexer_->push_figuredbass_state (); }
1044         Music
1045                 {
1046                   Music * chm = MY_MAKE_MUSIC ("UntransposableMusic");
1047                   chm->set_property ("element", $3->self_scm ());
1048                   $$ = chm;
1049                   scm_gc_unprotect_object ($3->self_scm ());
1050
1051                   THIS->lexer_->pop_state ();
1052         }
1053         | CHORDS {
1054                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1055                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1056                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1057                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1058
1059         } Music {
1060                   Music * chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1061                   chm->set_property ("element", $3->self_scm ());
1062                   scm_gc_unprotect_object ($3->self_scm ());
1063                   $$ = chm;
1064
1065                   THIS->lexer_->pop_state ();
1066         }
1067         | LYRICS
1068                 { THIS->lexer_->push_lyric_state (); }
1069         Music
1070                 {
1071                   $$ = $3;
1072                   THIS->lexer_->pop_state ();
1073         }
1074         | relative_music        { $$ = $1; }
1075         | re_rhythmed_music     { $$ = $1; }
1076         | TAG embedded_scm Music {
1077                 tag_music ($3, $2, THIS->here_input ());
1078                 $$ = $3;
1079         }
1080         ;
1081
1082 relative_music:
1083         RELATIVE absolute_pitch Music {
1084                 Music * p = $3;
1085                 Pitch pit = *unsmob_pitch ($2);
1086                 $$ = MY_MAKE_MUSIC ("RelativeOctaveMusic");
1087
1088                 $$->set_property ("element", p->self_scm ());
1089                 scm_gc_unprotect_object (p->self_scm ());
1090
1091
1092                 Pitch retpitch = p->to_relative_octave (pit);
1093                 if (lily_1_8_relative)
1094                         $$->set_property ("last-pitch", retpitch.smobbed_copy ());
1095         }
1096         ;
1097
1098 re_rhythmed_music:
1099         ADDLYRICS Music Music {
1100         Music*l =MY_MAKE_MUSIC ("LyricCombineMusic");
1101           l->set_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1102           scm_gc_unprotect_object ($3->self_scm ());
1103           scm_gc_unprotect_object ($2->self_scm ());
1104           $$ = l;
1105         }
1106         | NEWADDLYRICS string Music {
1107           Music*l =MY_MAKE_MUSIC ("NewLyricCombineMusic");
1108           l->set_property ("element", $3->self_scm ());
1109           scm_gc_unprotect_object ($3->self_scm ());
1110           $$ = l;
1111           l->set_property ("associated-context", $2);
1112         }
1113         ;
1114
1115 context_change:
1116         CHANGE STRING '=' STRING  {
1117                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1118                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1119                 t-> set_property ("change-to-id", $4);
1120
1121                 $$ = t;
1122                 $$->set_spot (THIS->here_input ());
1123         }
1124         ;
1125
1126 property_operation:
1127         STRING '='  scalar {
1128                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1129                         scm_string_to_symbol ($1), $3);
1130         }
1131         | UNSET STRING {
1132                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1133                         scm_string_to_symbol ($2));
1134         }
1135         | OVERRIDE STRING embedded_scm '=' embedded_scm {
1136                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1137                         scm_string_to_symbol ($2), $3, $5);
1138         }
1139         | REVERT STRING embedded_scm {
1140                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1141                         scm_string_to_symbol ($2), $3);
1142         }
1143         ;
1144
1145 context_def_mod:
1146         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1147         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1148         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1149
1150         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1151         | DENIES { $$ = ly_symbol2scm ("denies"); }
1152
1153         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1154         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1155         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1156         | NAME { $$ = ly_symbol2scm ("context-name"); }
1157         ;
1158
1159 context_mod:
1160         property_operation { $$ = $1; }
1161         | context_def_mod STRING {
1162                 $$ = scm_list_2 ($1, $2);
1163         }
1164         ;
1165
1166 context_prop_spec:
1167         STRING  {
1168                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"), scm_string_to_symbol ($1));
1169         }
1170         | STRING '.' STRING {
1171                 $$ = scm_list_2 (scm_string_to_symbol ($1), scm_string_to_symbol ($3));
1172         }
1173         ;
1174
1175 music_property_def:
1176         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1177                 $$ = property_op_to_music (scm_list_4 (
1178                         ly_symbol2scm ("poppush"),
1179                         gh_cadr ($2),
1180                         $3, $5));
1181                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1182         }
1183         | REVERT context_prop_spec embedded_scm {
1184                 $$ = property_op_to_music (scm_list_3 (
1185                         ly_symbol2scm ("pop"),
1186                         gh_cadr ($2),
1187                         $3));
1188
1189                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1190         }
1191         | SET context_prop_spec '=' scalar {
1192                 $$ = property_op_to_music (scm_list_3 (
1193                         ly_symbol2scm ("assign"),
1194                         gh_cadr ($2),
1195                         $4));
1196                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1197         }
1198         | UNSET context_prop_spec {
1199                 $$ = property_op_to_music (scm_list_2 (
1200                         ly_symbol2scm ("unset"),
1201                         gh_cadr ($2)));
1202                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1203         }
1204         | ONCE music_property_def {
1205                 SCM e = $2->get_property ("element");
1206                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1207                 $$ = $2;
1208
1209         }
1210         ;
1211
1212
1213
1214 scalar:
1215         string          { $$ = $1; }
1216         | bare_int      { $$ = gh_int2scm ($1); }
1217         | embedded_scm  { $$ = $1; }
1218         | full_markup {  $$ = $1; }
1219         | DIGIT { $$ = gh_int2scm ($1); }
1220         ;
1221
1222 /*
1223 This is a trick:
1224
1225 Adding pre_events to the simple_element
1226 makes the choice between
1227
1228   string:  STRING
1229
1230 and
1231
1232   simple_element: STRING
1233
1234 a single shift/reduction conflict.
1235
1236 nevertheless, this is not very clean, and we should find a different
1237 solution.
1238
1239 */
1240 pre_events: {
1241                 THIS->push_spot ();
1242         }
1243         ;
1244
1245 event_chord:
1246         pre_events simple_element post_events   {
1247                 SCM elts = $2-> get_property ("elements");
1248
1249                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1250
1251                 $2->set_property ("elements", elts);
1252                 $$ = $2;
1253         }
1254         | command_element
1255         | note_chord_element
1256         ;
1257
1258
1259 note_chord_element:
1260         chord_body optional_notemode_duration post_events
1261         {
1262                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1263                 SCM es = $1->get_property ("elements");
1264                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1265
1266                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1267                   unsmob_music (gh_car (s))->set_property ("duration", dur);
1268                 es = gh_append2 (es, postevs);
1269
1270                 $1-> set_property ("elements", es);
1271                 $$ = $1;
1272         }
1273         ;
1274
1275 chord_open: '<'
1276         ;
1277
1278 chord_close: '>'
1279         ;
1280
1281 simul_open: LESSLESS
1282         ;
1283
1284 simul_close: MOREMORE
1285         ;
1286
1287 chord_body:
1288         chord_open chord_body_elements chord_close
1289         {
1290                 $$ = MY_MAKE_MUSIC ("EventChord");
1291                 $$->set_property ("elements",
1292                         scm_reverse_x ($2, SCM_EOL));
1293         }
1294         ;
1295
1296 chord_body_elements:
1297         /* empty */             { $$ = SCM_EOL; }
1298         | chord_body_elements chord_body_element {
1299                 $$ = gh_cons ($2->self_scm (), $1);
1300                 scm_gc_unprotect_object ($2->self_scm ());
1301         }
1302         ;
1303
1304 chord_body_element:
1305         pitch exclamations questions post_events
1306         {
1307                 Music * n = MY_MAKE_MUSIC ("NoteEvent");
1308                 n->set_property ("pitch", $1);
1309                 if ($3 % 2)
1310                         n->set_property ("cautionary", SCM_BOOL_T);
1311                 if ($2 % 2 || $3 % 2)
1312                         n->set_property ("force-accidental", SCM_BOOL_T);
1313
1314                 if (gh_pair_p ($4)) {
1315                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1316                         n->set_property ("articulations", arts);
1317                 }
1318                 $$ = n;
1319         }
1320         | DRUM_PITCH post_events {
1321                 Music *n =  MY_MAKE_MUSIC ("NoteEvent");
1322                 n->set_property ("duration" ,$2);
1323                 n->set_property ("drum-type" , $1);
1324                 n->set_spot (THIS->here_input ());
1325
1326                 if (gh_pair_p ($2)) {
1327                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1328                         n->set_property ("articulations", arts);
1329                 }
1330                 $$ = n;
1331         }
1332         ;
1333
1334 add_quote:
1335         ADDQUOTE string Music {
1336                 SCM adder = ly_scheme_function ("add-quotable");
1337
1338                 scm_call_2 (adder, $2, $3->self_scm ());
1339                 scm_gc_unprotect_object ($3->self_scm ());
1340         }
1341         ;
1342
1343 command_element:
1344         command_req {
1345                 $$ = MY_MAKE_MUSIC ("EventChord");
1346                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1347                 scm_gc_unprotect_object ($1->self_scm ());
1348
1349                 $$-> set_spot (THIS->here_input ());
1350                 $1-> set_spot (THIS->here_input ());
1351         }
1352         | SKIP duration_length {
1353                 Music * skip = MY_MAKE_MUSIC ("SkipMusic");
1354                 skip->set_property ("duration", $2);
1355
1356                 $$ = skip;
1357         }
1358         | QUOTE STRING duration_length {
1359                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1360                 SCM evs =  SCM_EOL;
1361                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1362                 {
1363                         SCM key = $2; // use symbol?
1364                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1365                 }
1366                 Music * quote = 0;
1367                 if (gh_vector_p (evs))
1368                 {
1369                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1370                         quote->set_property ("duration", $3);
1371                         quote->set_property ("quoted-events", evs);
1372                 } else {
1373                         THIS->here_input ().warning (_f ("Can\'t find music"));
1374                         quote = MY_MAKE_MUSIC ("Event");
1375                 }
1376                 quote->set_spot (THIS->here_input ());
1377                 $$ = quote;
1378         }
1379         | OCTAVE { THIS->push_spot (); }
1380           pitch {
1381                 Music *l = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1382                 $$ = l;
1383                 $$->set_spot (THIS->pop_spot ());
1384                 $$->set_property ("pitch", $3);
1385         }
1386         | E_LEFTSQUARE {
1387                 Music *l = MY_MAKE_MUSIC ("LigatureEvent");
1388                 l->set_property ("span-direction", gh_int2scm (START));
1389                 l->set_spot (THIS->here_input ());
1390
1391                 $$ = MY_MAKE_MUSIC ("EventChord");
1392                 $$->set_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1393                 scm_gc_unprotect_object (l->self_scm ());
1394                 $$->set_spot (THIS->here_input ());
1395         }
1396         | E_RIGHTSQUARE {
1397                 Music *l = MY_MAKE_MUSIC ("LigatureEvent");
1398                 l->set_property ("span-direction", gh_int2scm (STOP));
1399                 l->set_spot (THIS->here_input ());
1400
1401                 $$ = MY_MAKE_MUSIC ("EventChord");
1402                 $$->set_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1403                 $$->set_spot (THIS->here_input ());
1404                 scm_gc_unprotect_object (l->self_scm ());
1405         }
1406         | E_BACKSLASH {
1407                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1408                 $$->set_spot (THIS->here_input ());
1409         }
1410         | '|'      {
1411
1412                 $$ = MY_MAKE_MUSIC ("BarCheck");
1413                 $$->set_spot (THIS->here_input ());
1414         }
1415         | TRANSPOSITION pitch {
1416                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1417                                         $2);
1418                 $$->set_spot (THIS-> here_input ());
1419                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1420                         $$ , SCM_EOL);
1421         }
1422         | BAR STRING                    {
1423                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1424
1425                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1426                                         t, SCM_EOL);
1427                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1428                 $$->set_spot (THIS->here_input ());
1429                 t->set_spot (THIS->here_input ());
1430         }
1431         | PARTIAL duration_length       {
1432                 Moment m = - unsmob_duration ($2)->get_length ();
1433                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1434                 p->set_spot (THIS->here_input ());
1435                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1436                                         p, SCM_EOL);
1437                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1438                                         p, SCM_EOL);
1439                 $$ =p ;
1440         }
1441         | CLEF STRING  {
1442                 SCM proc = ly_scheme_function ("make-clef-set");
1443
1444                 SCM result = scm_call_1 (proc, $2);
1445                 scm_gc_protect_object (result);
1446                 $$ = unsmob_music (result);
1447         }
1448         | TIME_T fraction  {
1449                 SCM proc= ly_scheme_function ("make-time-signature-set");
1450
1451                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1452                 scm_gc_protect_object (result);
1453                 $$ = unsmob_music (result);
1454         }
1455         | MARK scalar {
1456                 SCM proc = ly_scheme_function ("make-mark-set");
1457
1458                 SCM result = scm_call_1 (proc, $2);
1459                 scm_gc_protect_object (result);
1460                 $$ = unsmob_music (result);
1461         }
1462         ;
1463
1464 command_req:
1465         BREATHE {
1466                 $$ = MY_MAKE_MUSIC ("BreathingSignEvent");
1467         }
1468         | E_TILDE {
1469                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1470         }
1471         | MARK DEFAULT  {
1472                 Music * m = MY_MAKE_MUSIC ("MarkEvent");
1473                 $$ = m;
1474         }
1475         | tempo_event {
1476                 $$ = $1;
1477         }
1478         | KEY DEFAULT {
1479                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1480                 $$ = key;
1481         }
1482         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1483
1484                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1485                 if (scm_ilength ($3) > 0)
1486                 {
1487                         key->set_property ("pitch-alist", $3);
1488                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1489                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1490                 } else {
1491                         THIS->parser_error (_("Second argument must be pitch list."));
1492                 }
1493
1494                 $$ = key;
1495         }
1496         ;
1497
1498 post_events:
1499         /* empty */ {
1500                 $$ = SCM_EOL;
1501         }
1502         | post_events post_event {
1503                 $2->set_spot (THIS->here_input ());
1504                 $$ = gh_cons ($2->self_scm (), $$);
1505                 scm_gc_unprotect_object ($2->self_scm ());
1506         }
1507         | post_events tagged_post_event {
1508                 $2 -> set_spot (THIS->here_input ());
1509                 $$ = scm_cons ($2->self_scm (), $$);
1510                 scm_gc_unprotect_object ($2->self_scm ());
1511         }
1512         ;
1513
1514
1515 tagged_post_event:
1516         '-' TAG embedded_scm post_event {
1517                 tag_music ($4, $3, THIS->here_input ());
1518                 $$ = $4;
1519         }
1520         ;
1521
1522 post_event:
1523         direction_less_event {
1524                 $$ = $1;
1525         }
1526         | HYPHEN {
1527                 if (!THIS->lexer_->is_lyric_state ())
1528                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1529                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1530         }
1531         | EXTENDER {
1532                 if (!THIS->lexer_->is_lyric_state ())
1533                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1534                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1535         }
1536         | script_dir direction_reqd_event {
1537                 if ($1)
1538                         $2->set_property ("direction", gh_int2scm ($1));
1539                 $$ = $2;
1540         }
1541         | script_dir direction_less_event {
1542                 if ($1)
1543                         $2->set_property ("direction", gh_int2scm ($1));
1544                 $$ = $2;
1545         }
1546         | string_number_event
1547         ;
1548
1549 string_number_event:
1550         E_UNSIGNED {
1551                 Music * s = MY_MAKE_MUSIC ("StringNumberEvent");
1552                 s->set_property ("string-number",  gh_int2scm ($1));
1553                 s->set_spot (THIS->here_input ());
1554                 $$ = s;
1555         }
1556         ;
1557
1558
1559 direction_less_event:
1560         '['  {
1561
1562
1563 /*
1564
1565 TODO: should take all these defs out of the parser, adn make use
1566 configurable, i.e.
1567
1568
1569 (set-articulation '~ "trill")
1570
1571 */
1572                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1573                 m->set_spot (THIS->here_input ());
1574                 m->set_property ("span-direction" , gh_int2scm (START));
1575                 $$ = m;
1576         }
1577         | ']'  {
1578                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1579                 m->set_spot (THIS->here_input ());
1580                 m->set_property ("span-direction" , gh_int2scm (STOP));
1581                 $$ = m;
1582         }
1583         | '~' {
1584                 Music * m = MY_MAKE_MUSIC ("TieEvent");
1585                 m->set_spot (THIS->here_input ());
1586                 $$ = m;
1587         }
1588         | close_event {
1589                 $$ = $1;
1590                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1591                         gh_int2scm (START));
1592         }
1593         | open_event {
1594                 $$ = $1;
1595                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1596                         gh_int2scm (STOP));
1597         }
1598         | EVENT_IDENTIFIER      {
1599                 $$ = unsmob_music ($1);
1600         }
1601         | tremolo_type  {
1602                Music * a = MY_MAKE_MUSIC ("TremoloEvent");
1603                a->set_spot (THIS->here_input ());
1604                a->set_property ("tremolo-type", gh_int2scm ($1));
1605                $$ = a;
1606         }
1607         ;
1608
1609 direction_reqd_event:
1610         gen_text_def {
1611                 $$ = $1;
1612         }
1613         | script_abbreviation {
1614                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1615                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1616                 if (gh_string_p (s))
1617                         a->set_property ("articulation-type", s);
1618                 else THIS->parser_error (_ ("Expecting string as script definition"));
1619                 $$ = a;
1620         }
1621         ;
1622
1623 oct_check:
1624         /**/ { $$ = SCM_EOL; }
1625         | '='  { $$ = gh_int2scm (0); }
1626         | '=' sub_quotes { $$ = gh_int2scm ($2); }
1627         | '=' sup_quotes { $$ = gh_int2scm ($2); }
1628         ;
1629
1630 sup_quotes:
1631         '\'' {
1632                 $$ = 1;
1633         }
1634         | sup_quotes '\'' {
1635                 $$ ++;
1636         }
1637         ;
1638
1639 sub_quotes:
1640         ',' {
1641                 $$ = 1;
1642         }
1643         | sub_quotes ',' {
1644                 $$ ++ ;
1645         }
1646         ;
1647
1648 steno_pitch:
1649         NOTENAME_PITCH  {
1650                 $$ = $1;
1651         }
1652         | NOTENAME_PITCH sup_quotes     {
1653                 Pitch p = *unsmob_pitch ($1);
1654                 p = p.transposed (Pitch ($2,0,0));
1655                 $$ = p.smobbed_copy ();
1656         }
1657         | NOTENAME_PITCH sub_quotes      {
1658                 Pitch p =* unsmob_pitch ($1);
1659                 p = p.transposed (Pitch (-$2,0,0));
1660                 $$ = p.smobbed_copy ();
1661         }
1662         ;
1663
1664 /*
1665 ugh. duplication
1666 */
1667
1668 steno_tonic_pitch:
1669         TONICNAME_PITCH {
1670                 $$ = $1;
1671         }
1672         | TONICNAME_PITCH sup_quotes    {
1673                 Pitch p = *unsmob_pitch ($1);
1674                 p = p.transposed (Pitch ($2,0,0));
1675                 $$ = p.smobbed_copy ();
1676         }
1677         | TONICNAME_PITCH sub_quotes     {
1678                 Pitch p =* unsmob_pitch ($1);
1679
1680                 p = p.transposed (Pitch (-$2,0,0));
1681                 $$ = p.smobbed_copy ();
1682         }
1683         ;
1684
1685 pitch:
1686         steno_pitch {
1687                 $$ = $1;
1688         }
1689         ;
1690
1691 pitch_also_in_chords:
1692         pitch
1693         | steno_tonic_pitch
1694         ;
1695
1696 close_event:
1697         '('     {
1698                 Music * s= MY_MAKE_MUSIC ("SlurEvent");
1699                 $$ = s;
1700                 s->set_spot (THIS->here_input ());
1701         }
1702         | E_OPEN        {
1703                 Music * s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1704                 $$ = s;
1705                 s->set_spot (THIS->here_input ());
1706         }
1707         | E_SMALLER {
1708                 Music *s =MY_MAKE_MUSIC ("CrescendoEvent");
1709                 $$ = s;
1710                 s->set_spot (THIS->here_input ());
1711         }
1712         | E_BIGGER {
1713                 Music *s =MY_MAKE_MUSIC ("DecrescendoEvent");
1714                 $$ = s;
1715                 s->set_spot (THIS->here_input ());
1716         }
1717         ;
1718
1719
1720 open_event:
1721         E_EXCLAMATION   {
1722                 Music *s =  MY_MAKE_MUSIC ("CrescendoEvent");
1723                 s->set_spot (THIS->here_input ());
1724
1725                 $$ = s;
1726         }
1727         | ')'   {
1728                 Music * s= MY_MAKE_MUSIC ("SlurEvent");
1729                 $$ = s;
1730                 s->set_spot (THIS->here_input ());
1731
1732         }
1733         | E_CLOSE       {
1734                 Music * s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1735                 $$ = s;
1736                 s->set_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1737                 s->set_spot (THIS->here_input ());
1738         }
1739         ;
1740
1741 gen_text_def:
1742         full_markup {
1743                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1744                 t->set_property ("text", $1);
1745                 t->set_spot (THIS->here_input ());
1746                 $$ = t;
1747         }
1748         | string {
1749                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1750                 t->set_property ("text", make_simple_markup ($1));
1751                 t->set_spot (THIS->here_input ());
1752                 $$ = t;
1753
1754         }
1755         | DIGIT {
1756                 Music * t = MY_MAKE_MUSIC ("FingerEvent");
1757                 t->set_property ("digit",  gh_int2scm ($1));
1758                 t->set_spot (THIS->here_input ());
1759                 $$ = t;
1760         }
1761         ;
1762
1763 script_abbreviation:
1764         '^'             {
1765                 $$ = scm_makfrom0str ("Hat");
1766         }
1767         | '+'           {
1768                 $$ = scm_makfrom0str ("Plus");
1769         }
1770         | '-'           {
1771                 $$ = scm_makfrom0str ("Dash");
1772         }
1773         | '|'           {
1774                 $$ = scm_makfrom0str ("Bar");
1775         }
1776         | '>'           {
1777                 $$ = scm_makfrom0str ("Larger");
1778         }
1779         | '.'           {
1780                 $$ = scm_makfrom0str ("Dot");
1781         }
1782         | '_' {
1783                 $$ = scm_makfrom0str ("Underscore");
1784         }
1785         ;
1786
1787 script_dir:
1788         '_'     { $$ = DOWN; }
1789         | '^'   { $$ = UP; }
1790         | '-'   { $$ = CENTER; }
1791         ;
1792
1793
1794 absolute_pitch:
1795         steno_pitch     {
1796                 $$ = $1;
1797         }
1798         ;
1799
1800 duration_length:
1801         multiplied_duration {
1802                 $$ = $1;
1803         }
1804         ;
1805
1806 optional_notemode_duration:
1807         {
1808                 Duration dd = THIS->default_duration_;
1809                 $$ = dd.smobbed_copy ();
1810
1811                 THIS->beam_check ($$);
1812         }
1813         | multiplied_duration   {
1814                 $$ = $1;
1815                 THIS->default_duration_ = *unsmob_duration ($$);
1816
1817                 THIS->beam_check ($$);
1818         }
1819         ;
1820
1821 steno_duration:
1822         bare_unsigned dots              {
1823                 int l = 0;
1824                 if (!is_is_duration ($1))
1825                         THIS->parser_error (_f ("not a duration: %d", $1));
1826                 else
1827                         l =  intlog2 ($1);
1828
1829                 $$ = Duration (l, $2).smobbed_copy ();
1830         }
1831         | DURATION_IDENTIFIER dots      {
1832                 Duration *d =unsmob_duration ($1);
1833                 Duration k (d->duration_log (),d->dot_count () + $2);
1834
1835                 *d = k;
1836                 $$ = $1;
1837         }
1838         ;
1839
1840
1841
1842
1843 multiplied_duration:
1844         steno_duration {
1845                 $$ = $1;
1846         }
1847         | multiplied_duration '*' bare_unsigned {
1848                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1849         }
1850         | multiplied_duration '*' FRACTION {
1851                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1852
1853                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1854         }
1855         ;
1856
1857 fraction:
1858         FRACTION { $$ = $1; }
1859         | UNSIGNED '/' UNSIGNED {
1860                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1861         }
1862         ;
1863
1864 dots:
1865         /* empty */     {
1866                 $$ = 0;
1867         }
1868         | dots '.' {
1869                 $$ ++;
1870         }
1871         ;
1872
1873
1874 tremolo_type:
1875         ':'     {
1876                 $$ =0;
1877         }
1878         | ':' bare_unsigned {
1879                 if (!is_is_duration ($2))
1880                         THIS->parser_error (_f ("not a duration: %d", $2));
1881                 $$ = $2;
1882         }
1883         ;
1884
1885
1886
1887 /*****************************************************************
1888                 BASS FIGURES
1889 *****************************************************************/
1890 bass_number:
1891         DIGIT   {
1892                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1893         }
1894         | UNSIGNED {
1895                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1896         }
1897         | STRING { $$ =  $1; }
1898         ;
1899
1900 bass_mod:
1901         '-'     { $$ = -2; }
1902         | '+'   { $$ = 2; }
1903         | '!'   { $$ = 0; }
1904         ;
1905
1906 bass_figure:
1907         FIGURE_SPACE {
1908                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1909                 $$ = bfr->self_scm ();
1910                 scm_gc_unprotect_object ($$);
1911         }
1912         | bass_number  {
1913                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1914                 $$ = bfr->self_scm ();
1915
1916                 bfr->set_property ("figure", $1);
1917
1918                 scm_gc_unprotect_object ($$);
1919         }
1920         | bass_figure bass_mod {
1921                 Music *m = unsmob_music ($1);
1922                 if ($2) {
1923                         SCM salter =m->get_property ("alteration");
1924                         int alter = gh_number_p (salter) ? gh_scm2int (salter) : 0;
1925                         m->set_property ("alteration",
1926                                 gh_int2scm (alter + $2));
1927                 } else {
1928                         m->set_property ("alteration", gh_int2scm (0));
1929                 }
1930         }
1931         ;
1932
1933 br_bass_figure:
1934         '[' bass_figure {
1935                 $$ = $2;
1936                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
1937         }
1938         | bass_figure   {
1939                 $$ = $1;
1940         }
1941         | br_bass_figure ']' {
1942                 $$ = $1;
1943                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
1944         }
1945         ;
1946
1947 figure_list:
1948         /**/            {
1949                 $$ = SCM_EOL;
1950         }
1951         | figure_list br_bass_figure {
1952                 $$ = scm_cons ($2, $1);
1953         }
1954         ;
1955
1956 figure_spec:
1957         FIGURE_OPEN figure_list FIGURE_CLOSE {
1958                 Music * m = MY_MAKE_MUSIC ("EventChord");
1959                 $2 = scm_reverse_x ($2, SCM_EOL);
1960                 m->set_property ("elements",  $2);
1961                 $$ = m->self_scm ();
1962         }
1963         ;
1964
1965
1966 optional_rest:
1967         /**/   { $$ = 0; }
1968         | REST { $$ = 1; }
1969         ;
1970
1971 simple_element:
1972         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
1973
1974                 Input i = THIS->pop_spot ();
1975                 if (!THIS->lexer_->is_note_state ())
1976                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1977
1978                 Music *n = 0;
1979                 if ($6)
1980                         n =  MY_MAKE_MUSIC ("RestEvent");
1981                 else
1982                         n =  MY_MAKE_MUSIC ("NoteEvent");
1983
1984                 n->set_property ("pitch", $1);
1985                 n->set_property ("duration", $5);
1986
1987                 if (gh_number_p ($4))
1988                 {
1989                         int q = gh_scm2int ($4);
1990                         n->set_property ("absolute-octave", gh_int2scm (q-1));
1991                 }
1992
1993                 if ($3 % 2)
1994                         n->set_property ("cautionary", SCM_BOOL_T);
1995                 if ($2 % 2 || $3 % 2)
1996                         n->set_property ("force-accidental", SCM_BOOL_T);
1997
1998                 Music *v = MY_MAKE_MUSIC ("EventChord");
1999                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2000                 scm_gc_unprotect_object (n->self_scm ());
2001
2002                 v->set_spot (i);
2003                 n->set_spot (i);
2004                 $$ = v;
2005         }
2006         | DRUM_PITCH optional_notemode_duration {
2007                 Input i = THIS->pop_spot ();
2008
2009                 Music *n =  MY_MAKE_MUSIC ("NoteEvent");
2010                 n->set_property ("duration" ,$2);
2011                 n->set_property ("drum-type" , $1);
2012
2013                 Music *v = MY_MAKE_MUSIC ("EventChord");
2014                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2015                 scm_gc_unprotect_object (n->self_scm ());
2016                 v->set_spot (i);
2017                 n->set_spot (i);
2018                 $$ = v;
2019
2020         }
2021         | figure_spec optional_notemode_duration {
2022                 Music * m = unsmob_music ($1);
2023                 Input i = THIS->pop_spot ();
2024                 m->set_spot (i);
2025                 for (SCM s = m->get_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
2026                 {
2027                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2028                 }
2029                 $$ = m;
2030         }
2031         | RESTNAME optional_notemode_duration           {
2032
2033                 Input i = THIS->pop_spot ();
2034                 Music * ev = 0;
2035                 if (ly_scm2string ($1) =="s") {
2036                         /* Space */
2037                         ev = MY_MAKE_MUSIC ("SkipEvent");
2038                   }
2039                 else {
2040                         ev = MY_MAKE_MUSIC ("RestEvent");
2041
2042                     }
2043                 ev->set_property ("duration" ,$2);
2044                 ev->set_spot (i);
2045                 Music * velt = MY_MAKE_MUSIC ("EventChord");
2046                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2047                 velt->set_spot (i);
2048
2049                 scm_gc_unprotect_object (ev->self_scm ());
2050
2051                 $$ = velt;
2052         }
2053         | MULTI_MEASURE_REST optional_notemode_duration         {
2054                 THIS->pop_spot ();
2055
2056                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2057                 SCM mus = scm_call_2 (proc, $2,
2058                         make_input (THIS->here_input ()));
2059                 scm_gc_protect_object (mus);
2060                 $$ = unsmob_music (mus);
2061         }
2062
2063         | lyric_element optional_notemode_duration      {
2064                 Input i = THIS->pop_spot ();
2065                 if (!THIS->lexer_->is_lyric_state ())
2066                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2067
2068                 Music * lreq = MY_MAKE_MUSIC ("LyricEvent");
2069                 lreq->set_property ("text", $1);
2070                 lreq->set_property ("duration",$2);
2071                 lreq->set_spot (i);
2072                 Music * velt = MY_MAKE_MUSIC ("EventChord");
2073                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2074
2075                 $$= velt;
2076         }
2077         | new_chord {
2078                 THIS->pop_spot ();
2079
2080                 if (!THIS->lexer_->is_chord_state ())
2081                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2082                 $$ = unsmob_music ($1);
2083         }
2084         ;
2085
2086 lyric_element:
2087         full_markup { $$ = $1; }
2088         | STRING {  $$ = $1 ; }
2089         ;
2090
2091 new_chord:
2092         steno_tonic_pitch optional_notemode_duration   {
2093                 $$ = make_chord ($1, $2, SCM_EOL);
2094         }
2095         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2096                 SCM its = scm_reverse_x ($4, SCM_EOL);
2097                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2098         }
2099         ;
2100
2101 chord_items:
2102         /**/ {
2103                 $$ = SCM_EOL;
2104         }
2105         | chord_items chord_item {
2106                 $$ = gh_cons ($2, $$);
2107         }
2108         ;
2109
2110 chord_separator:
2111         CHORD_COLON {
2112                 $$ = ly_symbol2scm ("chord-colon");
2113         }
2114         | CHORD_CARET {
2115                 $$ = ly_symbol2scm ("chord-caret");
2116         }
2117         | CHORD_SLASH steno_tonic_pitch {
2118                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2119         }
2120         | CHORD_BASS steno_tonic_pitch {
2121                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2122         }
2123         ;
2124
2125 chord_item:
2126         chord_separator {
2127                 $$ = $1;
2128         }
2129         | step_numbers {
2130                 $$ = scm_reverse_x ($1, SCM_EOL);
2131         }
2132         | CHORD_MODIFIER  {
2133                 $$ = $1;
2134         }
2135         ;
2136
2137 step_numbers:
2138         step_number { $$ = gh_cons ($1, SCM_EOL); }
2139         | step_numbers '.' step_number {
2140                 $$ = gh_cons ($3, $$);
2141         }
2142         ;
2143
2144 step_number:
2145         bare_unsigned {
2146                 $$ = make_chord_step ($1, 0);
2147         }
2148         | bare_unsigned '+' {
2149                 $$ = make_chord_step ($1, SHARP);
2150         }
2151         | bare_unsigned CHORD_MINUS {
2152                 $$ = make_chord_step ($1, FLAT);
2153         }
2154         ;
2155
2156 /*
2157         UTILITIES
2158
2159 TODO: should deprecate in favor of Scheme?
2160
2161  */
2162 number_expression:
2163         number_expression '+' number_term {
2164                 $$ = scm_sum ($1, $3);
2165         }
2166         | number_expression '-' number_term {
2167                 $$ = scm_difference ($1, $3);
2168         }
2169         | number_term
2170         ;
2171
2172 number_term:
2173         number_factor {
2174                 $$ = $1;
2175         }
2176         | number_factor '*' number_factor {
2177                 $$ = scm_product ($1, $3);
2178         }
2179         | number_factor '/' number_factor {
2180                 $$ = scm_divide ($1, $3);
2181         }
2182         ;
2183
2184 number_factor:
2185         '-'  number_factor { /* %prec UNARY_MINUS */
2186                 $$ = scm_difference ($2, SCM_UNDEFINED);
2187         }
2188         | bare_number
2189         ;
2190
2191
2192 bare_number:
2193         UNSIGNED        {
2194                 $$ = gh_int2scm ($1);
2195         }
2196         | REAL          {
2197                 $$ = $1;
2198         }
2199         | NUMBER_IDENTIFIER             {
2200                 $$ = $1;
2201         }
2202         | REAL NUMBER_IDENTIFIER        {
2203                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2204         }
2205         | UNSIGNED NUMBER_IDENTIFIER    {
2206                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2207         }
2208         ;
2209
2210
2211 bare_unsigned:
2212         UNSIGNED {
2213                         $$ = $1;
2214         }
2215         | DIGIT {
2216                 $$ = $1;
2217         }
2218         ;
2219
2220 bare_int:
2221         bare_number {
2222                 if (scm_integer_p ($1) == SCM_BOOL_T)
2223                 {
2224                         int k = gh_scm2int ($1);
2225                         $$ = k;
2226                 } else
2227                 {
2228                         THIS->parser_error (_ ("need integer number arg"));
2229                         $$ = 0;
2230                 }
2231         }
2232         | '-' bare_int {
2233                 $$ = -$2;
2234         }
2235         ;
2236
2237
2238 string:
2239         STRING          {
2240                 $$ = $1;
2241         }
2242         | STRING_IDENTIFIER     {
2243                 $$ = $1;
2244         }
2245         | string '+' string {
2246                 $$ = scm_string_append (scm_list_2 ($1, $3));
2247         }
2248         ;
2249
2250
2251 exclamations:
2252                 { $$ = 0; }
2253         | exclamations '!'      { $$ ++; }
2254         ;
2255
2256 questions:
2257                 { $$ = 0; }
2258         | questions '?' { $$ ++; }
2259         ;
2260
2261
2262
2263 full_markup:
2264         MARKUP_IDENTIFIER {
2265                 $$ = $1;
2266         }
2267         | MARKUP
2268                 { THIS->lexer_->push_markup_state (); }
2269         markup
2270                 { $$ = $3;
2271                   THIS->lexer_->pop_state ();
2272                 }
2273         ;
2274
2275
2276 /*
2277 This should be done more dynamically if possible.
2278 */
2279 markup:
2280         STRING {
2281                 $$ = make_simple_markup ($1);
2282         }
2283         | MARKUP_HEAD_EMPTY {
2284                 $$ = scm_list_1 ($1);
2285         }
2286         | MARKUP_HEAD_MARKUP0 markup {
2287                 $$ = scm_list_2 ($1, $2);
2288         }
2289         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2290                 $$ = scm_list_3 ($1, $2, $3);
2291         }
2292         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2293                 $$  = scm_list_3 ($1, $2, $3);
2294         }
2295         | markup_line {
2296                 $$ = $1;
2297         }
2298         | MARKUP_HEAD_LIST0 markup_list {
2299                 $$ = scm_list_2 ($1,$2);
2300         }
2301         | MARKUP_HEAD_SCM0 embedded_scm {
2302                 $$ = scm_list_2 ($1, $2);
2303         }
2304         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2305                 $$ = scm_list_4 ($1, $2, $3, $4);
2306         }
2307         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2308                 $$ = scm_list_4 ($1, $2, $3, $4);
2309         }
2310         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2311                 $$ = scm_list_3 ($1, $2, $3);
2312         }
2313         | MARKUP_IDENTIFIER {
2314                 $$ = $1;
2315         }
2316         | STRING_IDENTIFIER {
2317                 $$ = $1;
2318         }
2319         ;
2320
2321 markup_list:
2322         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2323         ;
2324
2325 markup_line:
2326         '{' markup_list_body '}' {
2327                 SCM line = ly_scheme_function ("line-markup");
2328
2329                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2330         }
2331         ;
2332
2333 markup_list_body:
2334         /**/ {  $$ = SCM_EOL; }
2335         | markup_list_body markup {
2336                 $$ = gh_cons ($2, $1) ;
2337         }
2338         ;
2339
2340
2341 %%
2342
2343 void
2344 My_lily_parser::set_yydebug (bool )
2345 {
2346 #if 0
2347         yydebug = 1;
2348 #endif
2349 }
2350
2351 extern My_lily_parser * current_parser;
2352
2353 void
2354 My_lily_parser::do_yyparse ()
2355 {
2356         current_parser = this;;
2357         yyparse ((void*)this);
2358 }
2359
2360
2361 /*
2362 Should make this optional?    It will also complain when you do
2363
2364         [s4]
2365
2366 which is entirely legitimate.
2367
2368 Or we can scrap it. Barchecks should detect wrong durations, and
2369 skipTypesetting speeds it up a lot.
2370 */
2371
2372 void
2373 My_lily_parser::beam_check (SCM dur)
2374 {
2375   Duration *d = unsmob_duration (dur);
2376   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2377     {
2378       Music * m = unsmob_music (last_beam_start_);
2379       m->origin ()->warning (_("Suspect duration found following this beam"));
2380     }
2381   last_beam_start_ = SCM_EOL;
2382 }
2383
2384
2385
2386
2387 /*
2388
2389 It is a little strange to have this function in this file, but
2390 otherwise, we have to import music classes into the lexer.
2391
2392 */
2393 int
2394 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2395 {
2396         if (gh_string_p (sid)) {
2397                 *destination = sid;
2398                 return STRING_IDENTIFIER;
2399         } else if (gh_number_p (sid)) {
2400                 *destination = sid;
2401                 return NUMBER_IDENTIFIER;
2402         } else if (unsmob_context_def (sid)) {
2403                 *destination = unsmob_context_def (sid)->clone_scm ();
2404                 return CONTEXT_DEF_IDENTIFIER;
2405         } else if (unsmob_score (sid)) {
2406                 Score *sc =  new Score (*unsmob_score (sid));
2407                 *destination =sc->self_scm ();
2408                 return SCORE_IDENTIFIER;
2409         } else if (Music * mus =unsmob_music (sid)) {
2410                 mus = mus->clone ();
2411                 *destination = mus->self_scm ();
2412                 unsmob_music (*destination)->
2413                         set_property ("origin", make_input (last_input_));
2414                 return dynamic_cast<Event*> (mus)
2415                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2416         } else if (unsmob_duration (sid)) {
2417                 *destination = unsmob_duration (sid)->smobbed_copy ();
2418                 return DURATION_IDENTIFIER;
2419         } else if (unsmob_music_output_def (sid)) {
2420                 Music_output_def *p = unsmob_music_output_def (sid);
2421                 p = p->clone ();
2422
2423                 *destination = p->self_scm ();
2424                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2425         } else if (Text_item::markup_p (sid)) {
2426                 *destination = sid;
2427                 return MARKUP_IDENTIFIER;
2428         }
2429
2430         return -1;
2431 }
2432
2433 Music *
2434 property_op_to_music (SCM op)
2435 {
2436         Music * m = 0;
2437         SCM tag = gh_car (op);
2438         SCM symbol  = gh_cadr (op);
2439         SCM args = gh_cddr (op);
2440         SCM grob_val = SCM_UNDEFINED;
2441         SCM grob_sym = SCM_UNDEFINED;
2442         SCM val = SCM_UNDEFINED;
2443
2444         if (tag == ly_symbol2scm ("assign"))
2445                 {
2446                 m =  MY_MAKE_MUSIC ("PropertySet");
2447                 val = gh_car (args);
2448                 }
2449         else if (tag == ly_symbol2scm ("unset"))
2450                 m =  MY_MAKE_MUSIC ("PropertyUnset");
2451         else if (tag == ly_symbol2scm ("poppush")
2452                  || tag == ly_symbol2scm ("push"))
2453                 {
2454                 m  = MY_MAKE_MUSIC ("OverrideProperty");
2455                 grob_sym = gh_car (args);
2456                 grob_val = gh_cadr (args);
2457                 }
2458         else if (tag == ly_symbol2scm ("pop")) {
2459                 m = MY_MAKE_MUSIC ("RevertProperty");
2460                 grob_sym = gh_car (args);
2461                 }
2462
2463         m->set_property ("symbol", symbol);
2464
2465         if (val != SCM_UNDEFINED)
2466                 m->set_property ("value", val);
2467         if (grob_val != SCM_UNDEFINED)
2468                 m->set_property ("grob-value", grob_val);
2469
2470         if (grob_sym != SCM_UNDEFINED)
2471                 {
2472                 bool itc = internal_type_checking_global_b;
2473                 /* UGH.
2474                 */
2475                 bool autobeam = gh_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2476                 if (autobeam)
2477                         internal_type_checking_global_b = false;
2478                 m->set_property ("grob-property", grob_sym);
2479                 if (autobeam)
2480                         internal_type_checking_global_b = itc;
2481                 }
2482
2483         if (op == ly_symbol2scm ("poppush"))
2484                 m->set_property ("pop-first", SCM_BOOL_T);
2485
2486
2487         return m;
2488 }
2489
2490 Music*
2491 context_spec_music (SCM type, SCM id, Music * m, SCM ops)
2492 {
2493         Music * csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2494
2495         csm->set_property ("element", m->self_scm ());
2496         scm_gc_unprotect_object (m->self_scm ());
2497
2498         csm->set_property ("context-type",
2499                 gh_symbol_p (type) ? type : scm_string_to_symbol (type));
2500         csm->set_property ("property-operations", ops);
2501
2502         if (gh_string_p (id))
2503                 csm->set_property ("context-id", id);
2504         return csm;
2505 }
2506
2507
2508 SCM
2509 get_next_unique_context ()
2510 {
2511         static int new_context_count;
2512
2513         char s[1024];
2514         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2515
2516         return scm_makfrom0str (s);
2517 }
2518