lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c)  1997--2003 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Four shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 Similar problem for
  23
  24  * \markup identifier.
  25  * \markup { }
  26
  27
  28 2.  \repeat
  29         \repeat .. \alternative
  30
  31
  32     \repeat { \repeat .. \alternative }
  33
  34 or
  35
  36     \repeat { \repeat } \alternative
  37
  38 )
  39
  40 --hwn
  41
  42  */
  43
  44 /*
  45
  46 TODO:
  47
  48 * The rules for who is protecting what are very shady. Uniformise
  49   this.
  50
  51 * There are too many lexical modes?
  52
  53 */
  54
  55 #include <ctype.h>
  56 #include <stdlib.h>
  57 #include <stdio.h>
  58
  59
  60 #include "scm-option.hh"
  61 #include "context-def.hh"
  62 #include "lily-guile.hh"
  63 #include "misc.hh"
  64 #include "my-lily-lexer.hh"
  65 #include "paper-def.hh"
  66 #include "midi-def.hh"
  67 #include "main.hh"
  68 #include "file-path.hh"
  69 #include "warn.hh"
  70 #include "dimensions.hh"
  71 #include "my-lily-parser.hh"
  72 #include "score.hh"
  73 #include "input-file-results.hh"
  74 #include "input.hh"
  75 #include "lilypond-input-version.hh"
  76 #include "scm-hash.hh"
  77 #include "auto-change-iterator.hh"
  78 #include "ly-modules.hh"
  79 #include "music-sequence.hh"
  80 #include "input-smob.hh"
  81 #include "event.hh"
  82 #include "text-item.hh"
  83 #include "music-list.hh"
  84
  85 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  86
  87 Music *property_op_to_music (SCM op);
  88 Music *context_spec_music (SCM type, SCM id, Music * m, SCM ops_);
  89 SCM get_next_unique_context ();
  90
  91 #define YYERROR_VERBOSE 1
  92
  93 My_lily_parser* my_lily_parser;
  94 #define YYPARSE_PARAM my_lily_parser
  95 #define YYLEX_PARAM my_lily_parser
  96 #define THIS\
  97         ((My_lily_parser *) my_lily_parser)
  98
  99 #define yyerror THIS->parser_error
 100
 101 /*
 102   Add symbols to the  TAGS field of a music object.
 103 */
 104
 105 void
 106 tag_music (Music*m,  SCM tag, Input ip)
 107 {
 108         SCM tags = m->get_mus_property ("tags");
 109         if (gh_symbol_p (tag))
 110                 tags = scm_cons (tag, tags);
 111         else if (gh_list_p (tag))
 112                 tags = gh_append2 (tag, tags);
 113         else
 114                 ip.warning (_("Tag must be symbol or list of symbols."));
 115
 116         m->set_mus_property ("tags", tags);
 117 }
 118
 119
 120
 121 bool
 122 regular_identifier_b (SCM id)
 123 {
 124   String str = ly_scm2string (id);
 125   char const *s = str.to_str0 () ;
 126
 127   bool v = true;
 128   while (*s && v)
 129    {
 130         v = v && isalpha (*s);
 131         s++;
 132    }
 133   return v;
 134 }
 135
 136 SCM
 137 make_simple_markup (SCM a)
 138 {
 139         static SCM simple;
 140         if (!simple)
 141         simple = scm_c_eval_string ("simple-markup");
 142
 143         return scm_list_n (simple, a, SCM_UNDEFINED);
 144 }
 145
 146
 147 bool
 148 is_duration_b (int t)
 149 {
 150   return t && t == 1 << intlog2 (t);
 151 }
 152
 153 void
 154 set_music_properties (Music *p, SCM a)
 155 {
 156   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 157         {
 158         p->internal_set_mus_property (ly_caar (k), ly_cdar (k));
 159         }
 160 }
 161
 162 SCM
 163 make_chord_step (int step, int alter)
 164 {
 165         if (step == 7)
 166                 alter += FLAT;
 167
 168         while(step < 0)
 169                 step += 7;
 170         Pitch m((step -1) / 7 , (step - 1) % 7, alter);
 171         return m.smobbed_copy ();
 172 }
 173
 174
 175 SCM
 176 make_chord (SCM pitch, SCM dur, SCM modification_list)
 177 {
 178         static SCM chord_ctor;
 179         if (!chord_ctor)
 180                 chord_ctor= scm_c_eval_string ("construct-chord");
 181         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 182         scm_gc_protect_object (ch);
 183         return ch;
 184 }
 185
 186 /*
 187   Todo: actually also use apply iso. call too ...
 188 */
 189 bool
 190 ly_input_procedure_p (SCM x)
 191 {
 192         return gh_procedure_p (x)
 193                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 194 }
 195
 196 Music*
 197 set_property_music (SCM sym, SCM value)
 198 {
 199         Music * p = MY_MAKE_MUSIC("PropertySet");
 200         p->set_mus_property ("symbol", sym);
 201         p->set_mus_property ("value", value);
 202         return p;
 203 }
 204
 205 %}
 206
 207 /* We use SCMs to do strings, because it saves us the trouble of
 208 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 209 of the parse stack onto the heap. */
 210
 211
 212 %union {
 213         String * string;
 214     Music *music;
 215     Score *score;
 216     Music_output_def * outputdef;
 217     SCM scm;
 218     int i;
 219 }
 220 %{
 221
 222 int
 223 yylex (YYSTYPE *s,  void * v)
 224 {
 225         My_lily_parser   *pars = (My_lily_parser*) v;
 226         My_lily_lexer * lex = pars->lexer_;
 227
 228         lex->lexval = (void*) s;
 229         lex->prepare_for_next_token();
 230         return lex->yylex ();
 231 }
 232
 233
 234 %}
 235
 236 %pure_parser
 237
 238
 239 %token ACCEPTS
 240 %token ADDLYRICS
 241 %token NEWADDLYRICS
 242 %token ALIAS
 243 %token ALTERNATIVE
 244 %token APPLY
 245 %token APPLYCONTEXT
 246 %token APPLYOUTPUT
 247 %token AUTOCHANGE
 248 %token BAR
 249 %token BREATHE
 250 %token CHANGE
 251 %token CHORDMODIFIERS
 252 %token CHORDS
 253 %token LESSLESS
 254 %token MOREMORE
 255 %token CLEF
 256 %token COMMANDSPANREQUEST
 257 %token CONSISTS
 258 %token CONSISTSEND
 259 %token CONTEXT
 260 %token DEFAULT
 261 %token DENIES
 262 %token DESCRIPTION
 263 %token EXTENDER
 264 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 265 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 266 %token GRACE
 267 %token ACCIACCATURA
 268 %token APPOGGIATURA
 269 %token GROBDESCRIPTIONS
 270 %token HEADER
 271 %token HYPHEN
 272 %token INVALID
 273 %token KEY
 274 %token LYRICS
 275 %token MARK
 276 %token MIDI
 277 %token MULTI_MEASURE_REST
 278 %token NAME
 279 %token NEWCONTEXT
 280 %token NOTES
 281 %token OCTAVE
 282 %token ONCE
 283 %token OVERRIDE SET REVERT
 284 %token PAPER
 285 %token PARTCOMBINE
 286 %token NEWPARTCOMBINE
 287 %token PARTIAL
 288 %token PITCHNAMES
 289 %token PROPERTY
 290 %token RELATIVE
 291 %token REMOVE
 292 %token REPEAT
 293 %token REST
 294 %token SCM_T
 295 %token SCORE
 296 %token SEQUENTIAL
 297 %token SIMULTANEOUS
 298 %token SKIP
 299 %token SPANREQUEST
 300 %token TAG
 301 %token TEMPO
 302 %token TIMES
 303 %token TIME_T
 304 %token TRANSLATOR
 305 %token TRANSPOSE
 306 %token TYPE
 307 %token UNSET
 308 %token WITH
 309
 310 /* escaped */
 311 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 312 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 313 %token E_BACKSLASH
 314 %token <i> E_UNSIGNED
 315 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 316 %token FIGURE_SPACE
 317
 318 %type <i>       exclamations questions dots optional_rest
 319 %type <i>        bass_mod
 320 %type <scm>     grace_head
 321 %type <scm>     oct_check
 322 %type <scm>     context_mod_list
 323 %type <scm>     lyric_element
 324 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 325 %token <i>      DIGIT
 326 %token <scm>    NOTENAME_PITCH
 327 %token <scm>    TONICNAME_PITCH
 328 %token <scm>    CHORDMODIFIER_PITCH
 329 %token <scm>    DURATION_IDENTIFIER
 330 %token <scm>    FRACTION
 331 %token <id>     IDENTIFIER
 332 %token <scm>    CHORDNAMES
 333 %token <scm>    CHORD_MODIFIER
 334 %token <scm>    SCORE_IDENTIFIER
 335 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 336 %token <scm>    NUMBER_IDENTIFIER
 337 %token <scm>    EVENT_IDENTIFIER
 338 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 339 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 340 %token <scm>    RESTNAME
 341 %token <scm>    STRING
 342 %token <scm>    SCM_T
 343 %token <i>      UNSIGNED
 344 %token <scm>   REAL
 345
 346 %token MARKUP
 347 %token <scm> MARKUP_HEAD_MARKUP0
 348 %token <scm> MARKUP_HEAD_EMPTY
 349 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 350 %token <scm> MARKUP_HEAD_SCM0
 351 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 352 %token <scm> MARKUP_HEAD_SCM0_SCM1
 353 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 354 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 355
 356 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 357 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 358
 359 %type <outputdef> output_def
 360 %type <scm>     lilypond_header lilypond_header_body
 361 %type <music>   open_event close_event
 362 %type <i>       sub_quotes sup_quotes
 363 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 364 %type <music>   Repeated_music
 365 %type <scm>     Alternative_music
 366 %type <i>       tremolo_type
 367 %type <i>       bare_int  bare_unsigned
 368 %type <i>       script_dir
 369 %type <scm>     identifier_init
 370
 371 %type <music> note_chord_element chord_body chord_body_element
 372 %type <scm>  chord_body_elements
 373 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 374
 375 %type <scm>   post_events
 376 %type <music> gen_text_def direction_less_event direction_reqd_event
 377 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 378 %type <scm>    steno_tonic_pitch
 379 %type <scm>     duration_length fraction
 380
 381 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 382
 383 %type <scm>  embedded_scm scalar
 384 %type <music>   Music Sequential_music Simultaneous_music
 385 %type <music>   relative_music re_rhythmed_music part_combined_music
 386 %type <music>   music_property_def context_change
 387 %type <scm> Music_list
 388 %type <scm> property_operation context_mod translator_mod optional_context_mod
 389 %type <outputdef>  music_output_def_body music_output_def_head
 390 %type <music> shorthand_command_req
 391 %type <music>   post_event tagged_post_event
 392 %type <music> command_req verbose_command_req
 393 %type <music> string_number_event
 394 %type <scm>     string bare_number number_expression number_term number_factor
 395 %type <score>   score_block score_body
 396
 397 %type <scm>     translator_spec_block translator_spec_body
 398 %type <music>   tempo_event
 399 %type <scm> notenames_body notenames_block chordmodifiers_block
 400 %type <scm>     script_abbreviation
 401
 402
 403
 404 %left '-' '+'
 405
 406 /* We don't assign precedence to / and *, because we might need varied
 407 prec levels in different prods */
 408
 409 %left UNARY_MINUS
 410
 411 %%
 412
 413 lilypond:       /* empty */
 414         | lilypond toplevel_expression {}
 415         | lilypond assignment  { }
 416         | lilypond error {
 417                 THIS->error_level_  = 1;
 418         }
 419         | lilypond INVALID      {
 420                 THIS->error_level_  = 1;
 421         }
 422         ;
 423
 424 toplevel_expression:
 425         notenames_block                 {
 426                 THIS->lexer_->pitchname_tab_ =  $1;
 427         }
 428         | chordmodifiers_block                  {
 429                 THIS->lexer_->chordmodifier_tab_  = $1;
 430         }
 431         | lilypond_header {
 432                 THIS->input_file_->header_ = $1;
 433         }
 434         | score_block {
 435                 Score * sc = $1;
 436
 437                 SCM head = ly_module_p (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 438
 439                 Path p = split_path (THIS->output_basename_);
 440                 int *c =  &THIS->input_file_->score_count_;
 441                 if (*c)
 442                         {
 443                         p.base += "-" + to_string (*c);
 444                         }
 445
 446                 (*c)++;
 447                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 448
 449                 for (int i=0; i < sc->defs_.size (); i++)
 450                         default_rendering (sc->music_, sc->defs_[i]->self_scm(),head, outname);
 451
 452                 if (sc->defs_.empty ())
 453                 {
 454                    Music_output_def *id =
 455                         unsmob_music_output_def (THIS->lexer_->lookup_identifier
 456                                 ("$defaultpaper"));
 457
 458                    id = id ? id->clone () : new Paper_def;
 459
 460                    default_rendering (sc->music_, id->self_scm(), head, outname);
 461
 462                    scm_gc_unprotect_object (id->self_scm ());
 463                 }
 464                 scm_gc_unprotect_object (sc->self_scm());
 465         }
 466         | output_def {
 467                 SCM id = SCM_EOL;
 468                 if (dynamic_cast<Paper_def*> ($1))
 469                         id = scm_makfrom0str ("$defaultpaper");
 470                 else if (dynamic_cast<Midi_def*> ($1))
 471                         id = scm_makfrom0str ("$defaultmidi");
 472                 THIS->lexer_->set_identifier (id,   $1->self_scm ());
 473                 scm_gc_unprotect_object ($1->self_scm ());
 474         }
 475         ;
 476
 477 embedded_scm:
 478         SCM_T
 479         | SCM_IDENTIFIER
 480         ;
 481
 482
 483 chordmodifiers_block:
 484         CHORDMODIFIERS notenames_body   {  $$ = $2; }
 485         ;
 486
 487 notenames_block:
 488         PITCHNAMES notenames_body   {  $$ = $2; }
 489         ;
 490
 491 notenames_body:
 492         embedded_scm    {
 493           int i = scm_ilength ($1);
 494
 495           SCM tab = scm_make_vector (gh_int2scm (i), SCM_EOL);
 496           for (SCM s = $1; gh_pair_p (s); s = ly_cdr (s)) {
 497                 SCM pt = ly_cdar (s);
 498                 scm_hashq_set_x (tab, ly_caar (s), pt);
 499           }
 500           $$ = tab;
 501         }
 502         ;
 503
 504 lilypond_header_body:
 505         {
 506                 $$ = ly_make_anonymous_module ();
 507                 THIS->lexer_->add_scope ($$);
 508         }
 509         | lilypond_header_body assignment  {
 510
 511         }
 512         ;
 513
 514 lilypond_header:
 515         HEADER '{' lilypond_header_body '}'     {
 516                 $$ = THIS->lexer_-> remove_scope();
 517         }
 518         ;
 519
 520
 521 /*
 522         DECLARATIONS
 523 */
 524 assignment:
 525         STRING {
 526                 THIS->push_spot ();
 527         }
 528         /* cont */ '=' identifier_init  {
 529
 530         /*
 531                 Should find generic way of associating input with objects.
 532         */
 533                 Input ip = THIS->pop_spot ();
 534
 535                 if (! regular_identifier_b ($1))
 536                 {
 537                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 538                 }
 539
 540                 THIS->lexer_->set_identifier ($1, $4);
 541
 542 /*
 543  TODO: devise standard for protection in parser.
 544
 545   The parser stack lives on the C-stack, which means that
 546 all objects can be unprotected as soon as they're here.
 547
 548 */
 549         }
 550         | embedded_scm { }
 551         ;
 552
 553
 554 identifier_init:
 555         score_block {
 556                 $$ = $1->self_scm ();
 557                 scm_gc_unprotect_object ($$);
 558         }
 559         | full_markup {
 560                 $$ = $1;
 561         }
 562         | output_def {
 563                 $$ = $1->self_scm ();
 564                 scm_gc_unprotect_object ($$);
 565         }
 566         | translator_spec_block {
 567                 $$ = $1;
 568         }
 569         | Music  {
 570                 $$ = $1->self_scm ();
 571                 scm_gc_unprotect_object ($$);
 572         }
 573         | post_event {
 574                 $$ = $1->self_scm ();
 575                 scm_gc_unprotect_object ($$);
 576         }
 577         | number_expression {
 578                 $$ = $1;
 579         }
 580         | string {
 581                 $$ = $1;
 582         }
 583         | embedded_scm  {
 584                 $$ = $1;
 585         }
 586         ;
 587
 588 translator_spec_block:
 589         TRANSLATOR '{' translator_spec_body '}'
 590                 {
 591                 $$ = $3;
 592         }
 593         ;
 594
 595 translator_spec_body:
 596         /**/ {
 597                 $$ = Context_def::make_scm ();
 598                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 599         }
 600         | TRANSLATOR_IDENTIFIER {
 601                 $$ = $1;
 602                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 603         }
 604         | translator_spec_body GROBDESCRIPTIONS embedded_scm {
 605                 Context_def*td = unsmob_context_def($$);
 606
 607                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p)) {
 608                         SCM tag = gh_caar (p);
 609                         td->add_context_mod (scm_list_n (ly_symbol2scm ("assign"),
 610                                                         tag, ly_cdar (p), SCM_UNDEFINED));
 611                 }
 612         }
 613         | translator_spec_body context_mod {
 614                 unsmob_context_def ($$)->add_context_mod ($2);
 615         }
 616         ;
 617
 618 /*
 619         SCORE
 620 */
 621 score_block:
 622         SCORE {
 623                 THIS->push_spot ();
 624         }
 625         /*cont*/ '{' score_body '}'     {
 626                 THIS->pop_spot ();
 627                 $$ = $4;
 628
 629         }
 630         ;
 631
 632 score_body:
 633         Music   {
 634                 $$ = new Score;
 635
 636                 $$->set_spot (THIS->here_input ());
 637                 SCM m = $1->self_scm ();
 638                 scm_gc_unprotect_object (m);
 639
 640                 /*
 641                         guh.
 642                 */
 643                 SCM check_funcs = scm_c_eval_string ("toplevel-music-functions");
 644                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 645                         m = gh_call1 (gh_car (check_funcs), m);
 646                 $$->music_ = m;
 647
 648         }
 649         | SCORE_IDENTIFIER {
 650                 $$ = new Score ( *unsmob_score ($1));
 651                 $$->set_spot (THIS->here_input ());
 652         }
 653         | score_body lilypond_header    {
 654                 $$->header_ = $2;
 655         }
 656         | score_body output_def {
 657                 $$->defs_.push ($2);
 658                 scm_gc_unprotect_object ($2->self_scm ());
 659         }
 660         | score_body error {
 661
 662         }
 663         ;
 664
 665
 666 /*
 667         MIDI
 668 */
 669 output_def:
 670         music_output_def_body '}' {
 671                 $$ = $1;
 672                 THIS-> lexer_-> remove_scope ();
 673         }
 674         ;
 675
 676 music_output_def_head:
 677         MIDI    {
 678                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 679
 680
 681                 Midi_def* p =0;
 682                 if (id)
 683                         p = dynamic_cast<Midi_def*> (id->clone ());
 684                 else
 685                         p = new Midi_def;
 686
 687                 $$ = p;
 688                 THIS->lexer_->add_scope (p->scope_);
 689         }
 690         | PAPER         {
 691                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 692                   Paper_def *p = 0;
 693                 if (id)
 694                         p = dynamic_cast<Paper_def*> (id->clone ());
 695                 else
 696                         p = new Paper_def;
 697
 698                 THIS->lexer_->add_scope (p->scope_);
 699                 $$ = p;
 700         }
 701         ;
 702
 703
 704 music_output_def_body:
 705         music_output_def_head '{' {
 706
 707         }
 708         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 709                 Music_output_def * o =  unsmob_music_output_def ($3);
 710                 $$ = o;
 711                 THIS->lexer_->remove_scope ();
 712                 THIS->lexer_->add_scope (o->scope_);
 713         }
 714         | music_output_def_body assignment  {
 715
 716         }
 717         | music_output_def_body translator_spec_block   {
 718                 $$->assign_translator ($2);
 719         }
 720         | music_output_def_body tempo_event  {
 721                 /*
 722                         junk this ? there already is tempo stuff in
 723                         music.
 724                 */
 725                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 726                 Duration *d = unsmob_duration ($2->get_mus_property ("tempo-unit"));
 727                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 728                 if (md)
 729                         md->set_tempo (d->get_length (), m);
 730                 scm_gc_unprotect_object ($2->self_scm ());
 731         }
 732         | music_output_def_body error {
 733
 734         }
 735         ;
 736
 737 tempo_event:
 738         TEMPO steno_duration '=' bare_unsigned  {
 739                 $$ = MY_MAKE_MUSIC("MetronomeChangeEvent");
 740                 $$->set_mus_property ("tempo-unit", $2);
 741                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 742         }
 743         ;
 744
 745 /*
 746 The representation of a  list is the
 747
 748   (LIST . LAST-CONS)
 749
 750  to have  efficient append.
 751 */
 752 Music_list:
 753         /* empty */ {
 754                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 755         }
 756         | Music_list Music {
 757                 SCM s = $$;
 758                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 759                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 760                 if (gh_pair_p (ly_cdr (s)))
 761                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 762                 else
 763                         gh_set_car_x (s, c); /* set first cons */
 764                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 765         }
 766         | Music_list error {
 767         }
 768         ;
 769
 770
 771 Music:
 772         Simple_music
 773         | Composite_music
 774         ;
 775
 776 Alternative_music:
 777         /* empty */ {
 778                 $$ = SCM_EOL;
 779         }
 780         | ALTERNATIVE '{' Music_list '}' {
 781                 $$ = $3;
 782         }
 783         ;
 784
 785 Repeated_music:
 786         REPEAT string bare_unsigned Music Alternative_music
 787         {
 788                 Music *beg = $4;
 789                 int times = $3;
 790                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 791                 if (times < scm_ilength (alts)) {
 792                   unsmob_music (gh_car (alts))
 793                     ->origin ()->warning (
 794                     _("More alternatives than repeats.  Junking excess alternatives."));
 795                   alts = ly_truncate_list (times, alts);
 796                 }
 797
 798
 799                 static SCM proc;
 800                 if (!proc)
 801                         proc = scm_c_eval_string ("make-repeated-music");
 802
 803                 SCM mus = scm_call_1 (proc, $2);
 804                 scm_gc_protect_object (mus); // UGH.
 805                 Music *r =unsmob_music (mus);
 806                 if (beg)
 807                         {
 808                         r-> set_mus_property ("element", beg->self_scm ());
 809                         scm_gc_unprotect_object (beg->self_scm ());
 810                         }
 811                 r->set_mus_property ("repeat-count", gh_int2scm (times >? 1));
 812
 813                 r-> set_mus_property ("elements",alts);
 814                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 815                         /*
 816                         we can not get durations and other stuff correct down the line, so we have to
 817                         add to the duration log here.
 818                         */
 819                         static SCM func;
 820
 821                         if (!func)
 822                                 func = scm_primitive_eval (ly_symbol2scm ("shift-duration-log"));
 823
 824                         int dots = ($3 % 3) ? 0 : 1;
 825                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 826
 827                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 828
 829                         if (seq) {
 830                                 int list_len =scm_ilength (seq->music_list ());
 831                                 if (list_len != 2)
 832                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 833                                 shift -= 1;
 834                                 r->compress (Moment (Rational (1,list_len)));
 835                                 }
 836                         gh_call3 (func, r->self_scm (), gh_int2scm(shift),gh_int2scm(dots));
 837
 838                 }
 839                 r->set_spot (*$4->origin ());
 840
 841                 $$ = r;
 842         }
 843         ;
 844
 845 Sequential_music:
 846         SEQUENTIAL '{' Music_list '}'           {
 847                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 848                 $$->set_mus_property ("elements", ly_car ($3));
 849                 $$->set_spot(THIS->here_input());
 850         }
 851         | '{' Music_list '}'            {
 852                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 853                 $$->set_mus_property ("elements", ly_car ($2));
 854                 $$->set_spot(THIS->here_input());
 855         }
 856         ;
 857
 858 Simultaneous_music:
 859         SIMULTANEOUS '{' Music_list '}'{
 860                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 861                 $$->set_mus_property ("elements", ly_car ($3));
 862                 $$->set_spot(THIS->here_input());
 863
 864         }
 865         | simul_open Music_list simul_close     {
 866                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 867                 $$->set_mus_property ("elements", ly_car ($2));
 868                 $$->set_spot(THIS->here_input());
 869         }
 870         ;
 871
 872 Simple_music:
 873         event_chord             { $$ = $1; }
 874         | APPLYOUTPUT embedded_scm {
 875                 if (!ly_input_procedure_p ($2))
 876                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 877                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 878                 $$->set_mus_property ("procedure", $2);
 879                 $$->set_spot (THIS->here_input());
 880         }
 881         | APPLYCONTEXT embedded_scm {
 882                 if (!ly_input_procedure_p ($2))
 883                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 884                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 885                 $$->set_mus_property ("procedure", $2);
 886                 $$->set_spot (THIS->here_input());
 887         }
 888         | MUSIC_IDENTIFIER {
 889                 $$ = unsmob_music ($1);
 890         }
 891         | music_property_def
 892         | context_change
 893         ;
 894
 895
 896 optional_context_mod:
 897         /**/ { $$ = SCM_EOL; }
 898         | WITH '{' context_mod_list '}'  { $$ = $3; }
 899         ;
 900
 901 grace_head:
 902         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 903         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 904         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 905         ;
 906
 907 context_mod_list:
 908         /* */  { $$ = SCM_EOL; }
 909         | context_mod_list context_mod  {
 910                  $$ = gh_cons ($2, $1);
 911         }
 912         ;
 913
 914 Composite_music:
 915         AUTOCHANGE STRING Music {
 916                 Music*chm = MY_MAKE_MUSIC("AutoChangeMusic");
 917                 chm->set_mus_property ("element", $3->self_scm ());
 918                 chm->set_mus_property ("iterator-ctor", Auto_change_iterator::constructor_proc);
 919
 920                 scm_gc_unprotect_object ($3->self_scm ());
 921                 chm->set_mus_property ("what", scm_string_to_symbol ($2));
 922
 923                 $$ = chm;
 924                 chm->set_spot (*$3->origin ());
 925         }
 926         | grace_head Music {
 927 #if 1
 928         /*
 929                 The other version is for easier debugging  of
 930                 Sequential_music_iterator in combination with grace notes.
 931         */
 932
 933 /*
 934
 935 TODO: should distinguish between both grace types in the
 936 basic music objects too, since the meaning is different.
 937
 938 */
 939
 940                 String start_str = "start" + ly_scm2string ($1) + "Music";
 941                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 942
 943                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 944                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 945
 946                 Music *startm = unsmob_music (start);
 947                 Music *stopm = unsmob_music (stop);
 948
 949                 SCM ms = SCM_EOL;
 950                 if (stopm) {
 951                         stopm = stopm->clone ();
 952                         ms = scm_cons (stopm->self_scm (), ms);
 953                         scm_gc_unprotect_object (stopm->self_scm ());
 954                 }
 955                 ms = scm_cons ($2->self_scm (), ms);
 956                 scm_gc_unprotect_object ($2->self_scm());
 957                 if (startm) {
 958                         startm = startm->clone ();
 959                         ms = scm_cons (startm->self_scm () , ms);
 960                         scm_gc_unprotect_object (startm->self_scm ());
 961                 }
 962
 963
 964                 Music* seq = MY_MAKE_MUSIC("SequentialMusic");
 965                 seq->set_mus_property ("elements", ms);
 966
 967
 968                 $$ = MY_MAKE_MUSIC("GraceMusic");
 969                 $$->set_mus_property ("element", seq->self_scm ());
 970                 scm_gc_unprotect_object (seq->self_scm ());
 971 #else
 972                 $$ = MY_MAKE_MUSIC("GraceMusic");
 973                 $$->set_mus_property ("element", $2->self_scm ());
 974                 scm_gc_unprotect_object ($2->self_scm ());
 975 #endif
 976         }
 977         | CONTEXT string '=' string optional_context_mod Music {
 978                 $$ = context_spec_music ($2, $4, $6, $5);
 979
 980         }
 981         | CONTEXT STRING optional_context_mod Music {
 982                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
 983         }
 984         | NEWCONTEXT string optional_context_mod Music {
 985                 $$ = context_spec_music ($2, get_next_unique_context (),
 986                                          $4, $3);
 987         }
 988
 989         | TIMES {
 990                 THIS->push_spot ();
 991         }
 992         /* CONTINUED */
 993                 fraction Music
 994
 995         {
 996                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 997                 Music *mp = $4;
 998
 999                 $$= MY_MAKE_MUSIC("TimeScaledMusic");
1000                 $$->set_spot (THIS->pop_spot ());
1001
1002                 $$->set_mus_property ("element", mp->self_scm ());
1003                 scm_gc_unprotect_object (mp->self_scm ());
1004                 $$->set_mus_property ("numerator", gh_int2scm (n));
1005                 $$->set_mus_property ("denominator", gh_int2scm (d));
1006                 $$->compress (Moment (Rational (n,d)));
1007
1008         }
1009         | Repeated_music                { $$ = $1; }
1010         | Simultaneous_music            { $$ = $1; }
1011         | Sequential_music              { $$ = $1; }
1012         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1013                 $$ = MY_MAKE_MUSIC("TransposedMusic");
1014                 Music *p = $4;
1015                 Pitch from = *unsmob_pitch ($2);
1016                 Pitch to = *unsmob_pitch ($3);
1017
1018                 p->transpose (interval (from, to));
1019                 $$->set_mus_property ("element", p->self_scm ());
1020                 scm_gc_unprotect_object (p->self_scm ());
1021         }
1022         | APPLY embedded_scm Music  {
1023                 if (!ly_input_procedure_p ($2))
1024                         {
1025                         THIS->parser_error (_ ("\\apply takes function argument"));
1026                         $$ = $3;
1027                         }
1028                 else
1029                         {
1030                         SCM ret = gh_call1 ($2, $3->self_scm ());
1031                         Music *m = unsmob_music (ret);
1032                         if (!m) {
1033                                 THIS->parser_error ("\\apply must return a Music");
1034                                 m = MY_MAKE_MUSIC("Music");
1035                                 }
1036                         $$ = m;
1037                         }
1038         }
1039         | NOTES
1040                 { THIS->lexer_->push_note_state (); }
1041         Music
1042                 { $$ = $3;
1043                   THIS->lexer_->pop_state ();
1044                 }
1045         | FIGURES
1046                 { THIS->lexer_->push_figuredbass_state (); }
1047         Music
1048                 {
1049                   Music * chm = MY_MAKE_MUSIC("UntransposableMusic");
1050                   chm->set_mus_property ("element", $3->self_scm ());
1051                   $$ = chm;
1052                   scm_gc_unprotect_object ($3->self_scm());
1053
1054                   THIS->lexer_->pop_state ();
1055         }
1056         | CHORDS
1057                 { THIS->lexer_->push_chord_state (); }
1058         Music
1059                 {
1060                   Music * chm = MY_MAKE_MUSIC("UnrelativableMusic");
1061                   chm->set_mus_property ("element", $3->self_scm ());
1062                   scm_gc_unprotect_object ($3->self_scm());
1063                   $$ = chm;
1064
1065                   THIS->lexer_->pop_state ();
1066         }
1067         | LYRICS
1068                 { THIS->lexer_->push_lyric_state (); }
1069         Music
1070                 {
1071                   $$ = $3;
1072                   THIS->lexer_->pop_state ();
1073         }
1074         | relative_music        { $$ = $1; }
1075         | re_rhythmed_music     { $$ = $1; }
1076         | part_combined_music   { $$ = $1; }
1077         | TAG embedded_scm Music {
1078                 tag_music ($3, $2, THIS->here_input ());
1079                 $$ = $3;
1080         }
1081         ;
1082
1083 relative_music:
1084         RELATIVE absolute_pitch Music {
1085                 Music * p = $3;
1086                 Pitch pit = *unsmob_pitch ($2);
1087                 $$ = MY_MAKE_MUSIC("RelativeOctaveMusic");
1088
1089                 $$->set_mus_property ("element", p->self_scm ());
1090                 scm_gc_unprotect_object (p->self_scm ());
1091
1092
1093                 Pitch retpitch = p->to_relative_octave (pit);
1094                 if (lily_1_8_relative)
1095                         $$->set_mus_property ("last-pitch", retpitch.smobbed_copy ());
1096         }
1097         ;
1098
1099 re_rhythmed_music:
1100         ADDLYRICS Music Music {
1101         Music*l =MY_MAKE_MUSIC("LyricCombineMusic");
1102           l->set_mus_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1103           scm_gc_unprotect_object ($3->self_scm ());
1104           scm_gc_unprotect_object ($2->self_scm ());
1105           $$ = l;
1106         }
1107         | NEWADDLYRICS string Music {
1108           Music*l =MY_MAKE_MUSIC("NewLyricCombineMusic");
1109           l->set_mus_property ("element", $3->self_scm ());
1110           scm_gc_unprotect_object ($3->self_scm ());
1111           $$ = l;
1112           l->set_mus_property ("associated-context", $2);
1113         }
1114         ;
1115
1116 part_combined_music:
1117         PARTCOMBINE STRING Music Music {
1118                 Music * p= MY_MAKE_MUSIC("PartCombineMusic");
1119                 p->set_mus_property ("what", scm_string_to_symbol ($2));
1120                 p->set_mus_property ("elements", gh_list ($3->self_scm (),$4->self_scm (), SCM_UNDEFINED));
1121
1122                 scm_gc_unprotect_object ($3->self_scm ());
1123                 scm_gc_unprotect_object ($4->self_scm ());
1124
1125                 $$ = p;
1126         }
1127         | NEWPARTCOMBINE Music Music {
1128                 static SCM proc;
1129                 if (!proc)
1130                         proc = scm_c_eval_string ("make-new-part-combine-music");
1131
1132                 SCM res = scm_call_1 (proc, gh_list ($2->self_scm (),
1133                         $3->self_scm (), SCM_UNDEFINED));
1134                 scm_gc_unprotect_object ($3->self_scm ());
1135                 scm_gc_unprotect_object ($2->self_scm ());
1136                 $$ = unsmob_music (res);
1137                 scm_gc_protect_object (res);
1138         }
1139         ;
1140
1141 context_change:
1142         CHANGE STRING '=' STRING  {
1143                 Music*t= MY_MAKE_MUSIC("TranslatorChange");
1144                 t-> set_mus_property ("change-to-type", scm_string_to_symbol ($2));
1145                 t-> set_mus_property ("change-to-id", $4);
1146
1147                 $$ = t;
1148                 $$->set_spot (THIS->here_input ());
1149         }
1150         ;
1151
1152 property_operation:
1153         STRING '='  scalar {
1154                 $$ = scm_list_n (ly_symbol2scm ("assign"),
1155                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1156         }
1157         | STRING UNSET {
1158                 $$ = scm_list_n (ly_symbol2scm ("unset"),
1159                         scm_string_to_symbol ($1), SCM_UNDEFINED);
1160         }
1161         | STRING SET embedded_scm '=' embedded_scm {
1162                 $$ = scm_list_n (ly_symbol2scm ("poppush"),
1163                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1164         }
1165         | STRING OVERRIDE embedded_scm '=' embedded_scm {
1166                 $$ = scm_list_n (ly_symbol2scm ("push"),
1167                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1168         }
1169         | STRING REVERT embedded_scm {
1170                 $$ = scm_list_n (ly_symbol2scm ("pop"),
1171                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1172         }
1173         ;
1174
1175 translator_mod:
1176         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1177         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1178         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1179
1180         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1181         | DENIES { $$ = ly_symbol2scm ("denies"); }
1182
1183         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1184         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1185         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1186         | NAME { $$ = ly_symbol2scm ("context-name"); }
1187         ;
1188
1189 context_mod:
1190         property_operation { $$ = $1; }
1191         | translator_mod STRING {
1192                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
1193         }
1194         ;
1195
1196 music_property_def:
1197         PROPERTY STRING '.' property_operation {
1198                 Music * t = property_op_to_music ($4);
1199                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1200
1201                 csm->set_mus_property ("element", t->self_scm ());
1202                 scm_gc_unprotect_object (t->self_scm ());
1203
1204                 $$ = csm;
1205                 $$->set_spot (THIS->here_input ());
1206
1207                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1208         }
1209         | ONCE music_property_def {
1210                 $$ = $2;
1211                 SCM e = $2->get_mus_property ("element");
1212                 unsmob_music (e)->set_mus_property ("once", SCM_BOOL_T);
1213         }
1214         ;
1215
1216
1217 scalar:
1218         string          { $$ = $1; }
1219         | bare_int      { $$ = gh_int2scm ($1); }
1220         | embedded_scm  { $$ = $1; }
1221         | full_markup {  $$ = $1; }
1222         | DIGIT { $$ = gh_int2scm ($1); }
1223         ;
1224
1225 /*
1226 This is a trick:
1227
1228 Adding pre_events to the simple_element
1229 makes the choice between
1230
1231   string:  STRING
1232
1233 and
1234
1235   simple_element: STRING
1236
1237 a single shift/reduction conflict.
1238
1239 nevertheless, this is not very clean, and we should find a different
1240 solution.
1241
1242 */
1243 pre_events: {
1244                 THIS->push_spot ();
1245         }
1246         ;
1247
1248 event_chord:
1249         pre_events simple_element post_events   {
1250                 SCM elts = $2-> get_mus_property ("elements");
1251
1252                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1253
1254                 $2->set_mus_property ("elements", elts);
1255                 $$ = $2;
1256         }
1257         | command_element
1258         | note_chord_element
1259         ;
1260
1261
1262 note_chord_element:
1263         chord_body optional_notemode_duration post_events
1264         {
1265                 SCM dur = unsmob_duration ($2)->smobbed_copy();
1266                 SCM es = $1->get_mus_property ("elements");
1267                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1268
1269                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1270                   unsmob_music (gh_car(s))->set_mus_property ("duration", dur);
1271                 es = gh_append2 (es, postevs);
1272
1273                 $1-> set_mus_property ("elements", es);
1274                 $$ = $1;
1275         }
1276         ;
1277
1278 chord_open: '<'
1279         ;
1280
1281 chord_close: '>'
1282         ;
1283
1284 simul_open: LESSLESS
1285         ;
1286
1287 simul_close: MOREMORE
1288         ;
1289
1290 chord_body:
1291         chord_open chord_body_elements chord_close
1292         {
1293                 $$ = MY_MAKE_MUSIC("EventChord");
1294                 $$->set_mus_property ("elements",
1295                         scm_reverse_x ($2, SCM_EOL));
1296         }
1297         ;
1298
1299 chord_body_elements:
1300         /* empty */             { $$ = SCM_EOL; }
1301         | chord_body_elements chord_body_element {
1302                 $$ = gh_cons ($2->self_scm(), $1);
1303                 scm_gc_unprotect_object ($2->self_scm());
1304         }
1305         ;
1306
1307 chord_body_element:
1308         pitch exclamations questions post_events
1309         {
1310                 Music * n = MY_MAKE_MUSIC("NoteEvent");
1311                 n->set_mus_property ("pitch", $1);
1312                 if ($3 % 2)
1313                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1314                 if ($2 % 2 || $3 % 2)
1315                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1316
1317                 SCM arts = scm_reverse_x ($4, SCM_EOL);
1318                 n->set_mus_property ("articulations", arts);
1319
1320                 $$ = n;
1321         }
1322         ;
1323
1324 command_element:
1325         command_req {
1326                 $$ = MY_MAKE_MUSIC("EventChord");
1327                 $$->set_mus_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1328                 scm_gc_unprotect_object ($1->self_scm());
1329
1330                 $$-> set_spot (THIS->here_input ());
1331                 $1-> set_spot (THIS->here_input ());
1332         }
1333         | OCTAVE { THIS->push_spot (); }
1334           pitch {
1335                 Music *l = MY_MAKE_MUSIC("RelativeOctaveCheck");
1336                 $$ = l;
1337                 $$->set_spot (THIS->pop_spot ());
1338                 $$->set_mus_property ("pitch", $3);
1339         }
1340         | E_LEFTSQUARE {
1341                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1342                 l->set_mus_property ("span-direction", gh_int2scm (START));
1343                 l->set_spot (THIS->here_input ());
1344
1345                 $$ = MY_MAKE_MUSIC("EventChord");
1346                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1347                 scm_gc_unprotect_object (l->self_scm());
1348                 $$->set_spot (THIS->here_input ());
1349         }
1350         | E_RIGHTSQUARE {
1351                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1352                 l->set_mus_property ("span-direction", gh_int2scm (STOP));
1353                 l->set_spot (THIS->here_input ());
1354
1355                 $$ = MY_MAKE_MUSIC("EventChord");
1356                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1357                 $$->set_spot (THIS->here_input ());
1358                 scm_gc_unprotect_object (l->self_scm());
1359         }
1360         | E_BACKSLASH {
1361                 $$ = MY_MAKE_MUSIC("VoiceSeparator");
1362                 $$->set_spot (THIS->here_input ());
1363         }
1364         | '|'      {
1365
1366                 $$ = MY_MAKE_MUSIC("BarCheck");
1367                 $$->set_spot (THIS->here_input ());
1368         }
1369         | BAR STRING                    {
1370                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1371
1372                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1373                 csm->set_mus_property ("element", t->self_scm ());
1374                 scm_gc_unprotect_object (t->self_scm ());
1375
1376                 $$ = csm;
1377                 $$->set_spot (THIS->here_input ());
1378
1379                 csm->set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1380         }
1381         | PARTIAL duration_length       {
1382                 Moment m = - unsmob_duration ($2)->get_length ();
1383                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1384
1385                 Music * sp = MY_MAKE_MUSIC("ContextSpeccedMusic");
1386                 sp->set_mus_property ("element", p->self_scm ());
1387                 scm_gc_unprotect_object (p->self_scm ());
1388
1389                 $$ =sp ;
1390                 sp-> set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1391         }
1392         | CLEF STRING  {
1393                 static SCM proc ;
1394                 if (!proc)
1395                         proc = scm_c_eval_string ("make-clef-set");
1396
1397                 SCM result = scm_call_1 (proc, $2);
1398                 scm_gc_protect_object (result);
1399                 $$ = unsmob_music (result);
1400         }
1401         | TIME_T fraction  {
1402                 static SCM proc;
1403                 if (!proc)
1404                         proc = scm_c_eval_string ("make-time-signature-set");
1405
1406                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1407                 scm_gc_protect_object (result);
1408                 $$ = unsmob_music (result);
1409         }
1410         | MARK scalar {
1411                 static SCM proc;
1412                 if (!proc)
1413                         proc = scm_c_eval_string ("make-mark-set");
1414
1415                 SCM result = scm_call_1 (proc, $2);
1416                 scm_gc_protect_object (result);
1417                 $$ = unsmob_music (result);
1418         }
1419         ;
1420
1421 command_req:
1422         shorthand_command_req   { $$ = $1; }
1423         | verbose_command_req   { $$ = $1; }
1424         ;
1425
1426 shorthand_command_req:
1427         BREATHE {
1428                 $$ = MY_MAKE_MUSIC("BreathingSignEvent");
1429         }
1430         | E_TILDE {
1431                 $$ = MY_MAKE_MUSIC("PesOrFlexaEvent");
1432         }
1433         ;
1434
1435 verbose_command_req:
1436         MARK DEFAULT  {
1437                 Music * m = MY_MAKE_MUSIC("MarkEvent");
1438                 $$ = m;
1439         }
1440
1441         | SKIP duration_length {
1442                 Music * skip = MY_MAKE_MUSIC("SkipEvent");
1443                 skip->set_mus_property ("duration", $2);
1444
1445                 $$ = skip;
1446         }
1447         | tempo_event {
1448                 $$ = $1;
1449         }
1450         | KEY DEFAULT {
1451                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1452                 $$ = key;
1453         }
1454         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1455
1456                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1457                 if (scm_ilength ($3) > 0)
1458                 {
1459                         key->set_mus_property ("pitch-alist", $3);
1460                         key->set_mus_property ("tonic", Pitch (0,0,0).smobbed_copy());
1461                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1462                 } else {
1463                         THIS->parser_error (_("Second argument must be pitch list."));
1464                 }
1465
1466                 $$ = key;
1467         }
1468         ;
1469
1470 post_events:
1471         /* empty */ {
1472                 $$ = SCM_EOL;
1473         }
1474         | post_events post_event {
1475                 $2->set_spot (THIS->here_input ());
1476                 $$ = gh_cons ($2->self_scm(), $$);
1477                 scm_gc_unprotect_object ($2->self_scm());
1478         }
1479         | post_events tagged_post_event {
1480                 $2 -> set_spot (THIS->here_input ());
1481                 $$ = scm_cons ($2->self_scm(), $$);
1482                 scm_gc_unprotect_object ($2->self_scm());
1483         }
1484         ;
1485
1486
1487 tagged_post_event:
1488         '-' TAG embedded_scm post_event {
1489                 tag_music ($4, $3, THIS->here_input ());
1490                 $$ = $4;
1491         }
1492         ;
1493
1494 post_event:
1495         direction_less_event {
1496                 $$ = $1;
1497         }
1498         | HYPHEN {
1499                 if (!THIS->lexer_->lyric_state_b ())
1500                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1501                 $$ = MY_MAKE_MUSIC("HyphenEvent");
1502         }
1503         | EXTENDER {
1504                 if (!THIS->lexer_->lyric_state_b ())
1505                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1506                 $$ = MY_MAKE_MUSIC("ExtenderEvent");
1507         }
1508         | script_dir direction_reqd_event {
1509                 if ($1)
1510                         $2->set_mus_property ("direction", gh_int2scm ($1));
1511                 $$ = $2;
1512         }
1513         | script_dir direction_less_event {
1514                 if ($1)
1515                         $2->set_mus_property ("direction", gh_int2scm ($1));
1516                 $$ = $2;
1517         }
1518         | string_number_event
1519         ;
1520
1521 string_number_event:
1522         E_UNSIGNED {
1523                 Music * s = MY_MAKE_MUSIC("StringNumberEvent");
1524                 s->set_mus_property ("string-number",  gh_int2scm($1));
1525                 s->set_spot (THIS->here_input ());
1526                 $$ = s;
1527         }
1528         ;
1529
1530
1531 direction_less_event:
1532         '['  {
1533
1534
1535 /*
1536
1537 TODO: should take all these defs out of the parser, adn make use
1538 configurable, i.e.
1539
1540
1541 (set-articulation '~ "trill")
1542
1543 */
1544                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1545                 m->set_spot (THIS->here_input());
1546                 m->set_mus_property ("span-direction" , gh_int2scm (START));
1547                 $$ = m;
1548         }
1549         | ']'  {
1550                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1551                 m->set_spot (THIS->here_input());
1552                 m->set_mus_property ("span-direction" , gh_int2scm (STOP));
1553                 $$ = m;
1554         }
1555         | '~' {
1556                 Music * m = MY_MAKE_MUSIC ("TieEvent");
1557                 m->set_spot (THIS->here_input());
1558                 $$ = m;
1559         }
1560         | close_event {
1561                 $$ = $1;
1562                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1563                         gh_int2scm (START));
1564         }
1565         | open_event {
1566                 $$ = $1;
1567                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1568                         gh_int2scm (STOP));
1569         }
1570         | EVENT_IDENTIFIER      {
1571                 $$ = unsmob_music ($1);
1572         }
1573         | tremolo_type  {
1574                Music * a = MY_MAKE_MUSIC("TremoloEvent");
1575                a->set_spot (THIS->here_input ());
1576                a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1577                $$ = a;
1578         }
1579         ;
1580
1581 direction_reqd_event:
1582         gen_text_def {
1583                 $$ = $1;
1584         }
1585         | script_abbreviation {
1586                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1587                 Music *a = MY_MAKE_MUSIC("ArticulationEvent");
1588                 if (gh_string_p (s))
1589                         a->set_mus_property ("articulation-type", s);
1590                 else THIS->parser_error (_ ("Expecting string as script definition"));
1591                 $$ = a;
1592         }
1593         ;
1594
1595 oct_check:
1596         /**/ { $$ = SCM_EOL; }
1597         | '='  { $$ = gh_int2scm (0); }
1598         | '=' sub_quotes { $$ = gh_int2scm ($2); }
1599         | '=' sup_quotes { $$ = gh_int2scm ($2); }
1600         ;
1601
1602 sup_quotes:
1603         '\'' {
1604                 $$ = 1;
1605         }
1606         | sup_quotes '\'' {
1607                 $$ ++;
1608         }
1609         ;
1610
1611 sub_quotes:
1612         ',' {
1613                 $$ = 1;
1614         }
1615         | sub_quotes ',' {
1616                 $$ ++ ;
1617         }
1618         ;
1619
1620 steno_pitch:
1621         NOTENAME_PITCH  {
1622                 $$ = $1;
1623         }
1624         | NOTENAME_PITCH sup_quotes     {
1625                 Pitch p = *unsmob_pitch ($1);
1626                 p = p.transposed (Pitch ($2,0,0));
1627                 $$ = p.smobbed_copy ();
1628         }
1629         | NOTENAME_PITCH sub_quotes      {
1630                 Pitch p =* unsmob_pitch ($1);
1631                 p = p.transposed (Pitch (-$2,0,0));
1632                 $$ = p.smobbed_copy ();
1633         }
1634         ;
1635
1636 /*
1637 ugh. duplication
1638 */
1639
1640 steno_tonic_pitch:
1641         TONICNAME_PITCH {
1642                 $$ = $1;
1643         }
1644         | TONICNAME_PITCH sup_quotes    {
1645                 Pitch p = *unsmob_pitch ($1);
1646                 p = p.transposed (Pitch ($2,0,0));
1647                 $$ = p.smobbed_copy ();
1648         }
1649         | TONICNAME_PITCH sub_quotes     {
1650                 Pitch p =* unsmob_pitch ($1);
1651
1652                 p = p.transposed (Pitch (-$2,0,0));
1653                 $$ = p.smobbed_copy ();
1654         }
1655         ;
1656
1657 pitch:
1658         steno_pitch {
1659                 $$ = $1;
1660         }
1661         ;
1662
1663 pitch_also_in_chords:
1664         pitch
1665         | steno_tonic_pitch
1666         ;
1667
1668
1669 close_event:
1670         '('     {
1671                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1672                 $$ = s;
1673                 s->set_spot (THIS->here_input());
1674         }
1675         | E_OPEN        {
1676                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1677                 $$ = s;
1678                 s->set_spot (THIS->here_input());
1679         }
1680         | E_SMALLER {
1681                 Music *s =MY_MAKE_MUSIC("CrescendoEvent");
1682                 $$ = s;
1683                 s->set_spot (THIS->here_input());
1684         }
1685         | E_BIGGER {
1686                 Music *s =MY_MAKE_MUSIC("DecrescendoEvent");
1687                 $$ = s;
1688                 s->set_spot (THIS->here_input());
1689         }
1690         ;
1691
1692
1693 open_event:
1694         E_EXCLAMATION   {
1695                 Music *s =  MY_MAKE_MUSIC("CrescendoEvent");
1696                 s->set_spot (THIS->here_input());
1697
1698                 $$ = s;
1699         }
1700         | ')'   {
1701                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1702                 $$ = s;
1703                 s->set_spot (THIS->here_input());
1704
1705         }
1706         | E_CLOSE       {
1707                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1708                 $$ = s;
1709                 s->set_mus_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1710                 s->set_spot (THIS->here_input());
1711         }
1712         ;
1713
1714 gen_text_def:
1715         full_markup {
1716                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1717                 t->set_mus_property ("text", $1);
1718                 t->set_spot (THIS->here_input ());
1719                 $$ = t;
1720         }
1721         | string {
1722                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1723                 t->set_mus_property ("text", make_simple_markup ($1));
1724                 t->set_spot (THIS->here_input ());
1725                 $$ = t;
1726
1727         }
1728         | DIGIT {
1729                 Music * t = MY_MAKE_MUSIC("FingerEvent");
1730                 t->set_mus_property ("digit",  gh_int2scm ($1));
1731                 t->set_spot (THIS->here_input ());
1732                 $$ = t;
1733         }
1734         ;
1735
1736 script_abbreviation:
1737         '^'             {
1738                 $$ = scm_makfrom0str ("Hat");
1739         }
1740         | '+'           {
1741                 $$ = scm_makfrom0str ("Plus");
1742         }
1743         | '-'           {
1744                 $$ = scm_makfrom0str ("Dash");
1745         }
1746         | '|'           {
1747                 $$ = scm_makfrom0str ("Bar");
1748         }
1749         | '>'           {
1750                 $$ = scm_makfrom0str ("Larger");
1751         }
1752         | '.'           {
1753                 $$ = scm_makfrom0str ("Dot");
1754         }
1755         | '_' {
1756                 $$ = scm_makfrom0str ("Underscore");
1757         }
1758         ;
1759
1760 script_dir:
1761         '_'     { $$ = DOWN; }
1762         | '^'   { $$ = UP; }
1763         | '-'   { $$ = CENTER; }
1764         ;
1765
1766
1767 absolute_pitch:
1768         steno_pitch     {
1769                 $$ = $1;
1770         }
1771         ;
1772
1773 duration_length:
1774         multiplied_duration {
1775                 $$ = $1;
1776         }
1777         ;
1778
1779 optional_notemode_duration:
1780         {
1781                 Duration dd = THIS->default_duration_;
1782                 $$ = dd.smobbed_copy ();
1783
1784                 THIS->beam_check ($$);
1785         }
1786         | multiplied_duration   {
1787                 $$ = $1;
1788                 THIS->default_duration_ = *unsmob_duration ($$);
1789
1790                 THIS->beam_check ($$);
1791         }
1792         ;
1793
1794 steno_duration:
1795         bare_unsigned dots              {
1796                 int l = 0;
1797                 if (!is_duration_b ($1))
1798                         THIS->parser_error (_f ("not a duration: %d", $1));
1799                 else
1800                         l =  intlog2 ($1);
1801
1802                 $$ = Duration (l, $2).smobbed_copy ();
1803         }
1804         | DURATION_IDENTIFIER dots      {
1805                 Duration *d =unsmob_duration ($1);
1806                 Duration k (d->duration_log (),d->dot_count () + $2);
1807
1808                 *d = k;
1809                 $$ = $1;
1810         }
1811         ;
1812
1813
1814
1815
1816 multiplied_duration:
1817         steno_duration {
1818                 $$ = $1;
1819         }
1820         | multiplied_duration '*' bare_unsigned {
1821                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1822         }
1823         | multiplied_duration '*' FRACTION {
1824                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1825
1826                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1827         }
1828         ;
1829
1830 fraction:
1831         FRACTION { $$ = $1; }
1832         | UNSIGNED '/' UNSIGNED {
1833                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1834         }
1835         ;
1836
1837 dots:
1838         /* empty */     {
1839                 $$ = 0;
1840         }
1841         | dots '.' {
1842                 $$ ++;
1843         }
1844         ;
1845
1846
1847 tremolo_type:
1848         ':'     {
1849                 $$ =0;
1850         }
1851         | ':' bare_unsigned {
1852                 if (!is_duration_b ($2))
1853                         THIS->parser_error (_f ("not a duration: %d", $2));
1854                 $$ = $2;
1855         }
1856         ;
1857
1858
1859
1860 /*****************************************************************
1861                 BASS FIGURES
1862 *****************************************************************/
1863 bass_number:
1864         DIGIT   {
1865                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1866         }
1867         | UNSIGNED {
1868                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1869         }
1870         | STRING { $$ =  $1; }
1871         ;
1872
1873 bass_mod:
1874         '-'     { $$ = -2; }
1875         | '+'   { $$ = 2; }
1876         | '!'   { $$ = 0; }
1877         ;
1878
1879 bass_figure:
1880         FIGURE_SPACE {
1881                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1882                 $$ = bfr->self_scm();
1883                 scm_gc_unprotect_object ($$);
1884         }
1885         | bass_number  {
1886                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1887                 $$ = bfr->self_scm();
1888
1889                 bfr->set_mus_property ("figure", $1);
1890
1891                 scm_gc_unprotect_object ($$);
1892         }
1893         | bass_figure bass_mod {
1894                 Music *m = unsmob_music ($1);
1895                 if ($2) {
1896                         SCM salter =m->get_mus_property ("alteration");
1897                         int alter = gh_number_p ( salter) ? gh_scm2int (salter) : 0;
1898                         m->set_mus_property ("alteration",
1899                                 gh_int2scm (alter + $2));
1900                 } else {
1901                         m->set_mus_property ("alteration", gh_int2scm (0));
1902                 }
1903         }
1904         ;
1905
1906 br_bass_figure:
1907         '[' bass_figure {
1908                 $$ = $2;
1909                 unsmob_music ($$)->set_mus_property ("bracket-start", SCM_BOOL_T);
1910         }
1911         | bass_figure   {
1912                 $$ = $1;
1913         }
1914         | br_bass_figure ']' {
1915                 $$ = $1;
1916                 unsmob_music ($1)->set_mus_property ("bracket-stop", SCM_BOOL_T);
1917         }
1918         ;
1919
1920 figure_list:
1921         /**/            {
1922                 $$ = SCM_EOL;
1923         }
1924         | figure_list br_bass_figure {
1925                 $$ = scm_cons ($2, $1);
1926         }
1927         ;
1928
1929 figure_spec:
1930         FIGURE_OPEN figure_list FIGURE_CLOSE {
1931                 Music * m = MY_MAKE_MUSIC("EventChord");
1932                 $2 = scm_reverse_x ($2, SCM_EOL);
1933                 m->set_mus_property ("elements",  $2);
1934                 $$ = m->self_scm ();
1935         }
1936         ;
1937
1938
1939 optional_rest:
1940         /**/   { $$ = 0; }
1941         | REST { $$ = 1; }
1942         ;
1943
1944 simple_element:
1945         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
1946
1947                 Input i = THIS->pop_spot ();
1948                 if (!THIS->lexer_->note_state_b ())
1949                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1950
1951                 Music *n = 0;
1952                 if ($6)
1953                         n =  MY_MAKE_MUSIC("RestEvent");
1954                 else
1955                         n =  MY_MAKE_MUSIC("NoteEvent");
1956
1957                 n->set_mus_property ("pitch", $1);
1958                 n->set_mus_property ("duration", $5);
1959
1960                 if (gh_number_p ($4))
1961                 {
1962                         int q = gh_scm2int ($4);
1963                         n->set_mus_property ("absolute-octave", gh_int2scm (q-1));
1964                 }
1965
1966                 if ($3 % 2)
1967                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1968                 if ($2 % 2 || $3 % 2)
1969                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1970
1971                 Music *v = MY_MAKE_MUSIC("EventChord");
1972                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
1973                 scm_gc_unprotect_object (n->self_scm());
1974
1975                 v->set_spot (i);
1976                 n->set_spot (i);
1977                 $$ = v;
1978         }
1979         | figure_spec optional_notemode_duration {
1980                 Music * m = unsmob_music ($1);
1981                 Input i = THIS->pop_spot ();
1982                 m->set_spot (i);
1983                 for (SCM s = m->get_mus_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
1984                 {
1985                         unsmob_music (ly_car (s))->set_mus_property ("duration", $2);
1986                 }
1987                 $$ = m;
1988         }
1989         | RESTNAME optional_notemode_duration           {
1990
1991                 Input i = THIS->pop_spot ();
1992                 Music * ev = 0;
1993                 if (ly_scm2string ($1) =="s") {
1994                         /* Space */
1995                         ev = MY_MAKE_MUSIC("SkipEvent");
1996                   }
1997                 else {
1998                         ev = MY_MAKE_MUSIC("RestEvent");
1999
2000                     }
2001                 ev->set_mus_property ("duration" ,$2);
2002                 ev->set_spot (i);
2003                 Music * velt = MY_MAKE_MUSIC("EventChord");
2004                 velt->set_mus_property ("elements", scm_list_n (ev->self_scm (),SCM_UNDEFINED));
2005                 velt->set_spot (i);
2006
2007                 scm_gc_unprotect_object (ev->self_scm());
2008
2009                 $$ = velt;
2010         }
2011         | MULTI_MEASURE_REST optional_notemode_duration         {
2012                 THIS->pop_spot ();
2013
2014                 static SCM proc ;
2015                 if (!proc)
2016                         proc = scm_c_eval_string ("make-multi-measure-rest");
2017
2018                 SCM mus = scm_call_2 (proc, $2,
2019                         make_input (THIS->here_input()));
2020                 scm_gc_protect_object (mus);
2021                 $$ = unsmob_music (mus);
2022         }
2023
2024         | lyric_element optional_notemode_duration      {
2025                 Input i = THIS->pop_spot ();
2026                 if (!THIS->lexer_->lyric_state_b ())
2027                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2028
2029                 Music * lreq = MY_MAKE_MUSIC("LyricEvent");
2030                 lreq->set_mus_property ("text", $1);
2031                 lreq->set_mus_property ("duration",$2);
2032                 lreq->set_spot (i);
2033                 Music * velt = MY_MAKE_MUSIC("EventChord");
2034                 velt->set_mus_property ("elements", scm_list_n (lreq->self_scm (), SCM_UNDEFINED));
2035
2036                 $$= velt;
2037         }
2038         | new_chord {
2039                 THIS->pop_spot ();
2040
2041                 if (!THIS->lexer_->chord_state_b ())
2042                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2043                 $$ = unsmob_music ($1);
2044         }
2045         ;
2046
2047 lyric_element:
2048         full_markup { $$ = $1; }
2049         | STRING {  $$ = $1 ; }
2050         ;
2051
2052 new_chord:
2053         steno_tonic_pitch optional_notemode_duration   {
2054                 $$ = make_chord ($1, $2, SCM_EOL);
2055         }
2056         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2057                 SCM its = scm_reverse_x ($4, SCM_EOL);
2058                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2059         }
2060         ;
2061
2062 chord_items:
2063         /**/ {
2064                 $$ = SCM_EOL;
2065         }
2066         | chord_items chord_item {
2067                 $$ = gh_cons ($2, $$);
2068         }
2069         ;
2070
2071 chord_separator:
2072         CHORD_COLON {
2073                 $$ = ly_symbol2scm ("chord-colon");
2074         }
2075         | CHORD_CARET {
2076                 $$ = ly_symbol2scm ("chord-caret");
2077         }
2078         | CHORD_SLASH steno_tonic_pitch {
2079                 $$ = scm_list_n (ly_symbol2scm ("chord-slash"), $2, SCM_UNDEFINED);
2080         }
2081         | CHORD_BASS steno_tonic_pitch {
2082                 $$ = scm_list_n (ly_symbol2scm ("chord-bass"), $2, SCM_UNDEFINED);
2083         }
2084         ;
2085
2086 chord_item:
2087         chord_separator {
2088                 $$ = $1;
2089         }
2090         | step_numbers {
2091                 $$ = scm_reverse_x ($1, SCM_EOL);
2092         }
2093         | CHORD_MODIFIER  {
2094                 $$ = $1;
2095         }
2096         ;
2097
2098 step_numbers:
2099         step_number { $$ = gh_cons ($1, SCM_EOL); }
2100         | step_numbers '.' step_number {
2101                 $$ = gh_cons ($3, $$);
2102         }
2103         ;
2104
2105 step_number:
2106         bare_unsigned {
2107                 $$ = make_chord_step ($1, 0);
2108         }
2109         | bare_unsigned '+' {
2110                 $$ = make_chord_step ($1, SHARP);
2111         }
2112         | bare_unsigned CHORD_MINUS {
2113                 $$ = make_chord_step ($1, FLAT);
2114         }
2115         ;
2116
2117 /*
2118         UTILITIES
2119
2120 TODO: should deprecate in favor of Scheme?
2121
2122  */
2123 number_expression:
2124         number_expression '+' number_term {
2125                 $$ = scm_sum ($1, $3);
2126         }
2127         | number_expression '-' number_term {
2128                 $$ = scm_difference ($1, $3);
2129         }
2130         | number_term
2131         ;
2132
2133 number_term:
2134         number_factor {
2135                 $$ = $1;
2136         }
2137         | number_factor '*' number_factor {
2138                 $$ = scm_product ($1, $3);
2139         }
2140         | number_factor '/' number_factor {
2141                 $$ = scm_divide ($1, $3);
2142         }
2143         ;
2144
2145 number_factor:
2146         '-'  number_factor { /* %prec UNARY_MINUS */
2147                 $$ = scm_difference ($2, SCM_UNDEFINED);
2148         }
2149         | bare_number
2150         ;
2151
2152
2153 bare_number:
2154         UNSIGNED        {
2155                 $$ = gh_int2scm ($1);
2156         }
2157         | REAL          {
2158                 $$ = $1;
2159         }
2160         | NUMBER_IDENTIFIER             {
2161                 $$ = $1;
2162         }
2163         | REAL NUMBER_IDENTIFIER        {
2164                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2165         }
2166         | UNSIGNED NUMBER_IDENTIFIER    {
2167                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2168         }
2169         ;
2170
2171
2172 bare_unsigned:
2173         UNSIGNED {
2174                         $$ = $1;
2175         }
2176         | DIGIT {
2177                 $$ = $1;
2178         }
2179         ;
2180
2181 bare_int:
2182         bare_number {
2183                 if (scm_integer_p ($1) == SCM_BOOL_T)
2184                 {
2185                         int k = gh_scm2int ($1);
2186                         $$ = k;
2187                 } else
2188                 {
2189                         THIS->parser_error (_ ("need integer number arg"));
2190                         $$ = 0;
2191                 }
2192         }
2193         | '-' bare_int {
2194                 $$ = -$2;
2195         }
2196         ;
2197
2198
2199 string:
2200         STRING          {
2201                 $$ = $1;
2202         }
2203         | STRING_IDENTIFIER     {
2204                 $$ = $1;
2205         }
2206         | string '+' string {
2207                 $$ = scm_string_append (scm_list_n ($1, $3, SCM_UNDEFINED));
2208         }
2209         ;
2210
2211
2212 exclamations:
2213                 { $$ = 0; }
2214         | exclamations '!'      { $$ ++; }
2215         ;
2216
2217 questions:
2218                 { $$ = 0; }
2219         | questions '?' { $$ ++; }
2220         ;
2221
2222
2223
2224 full_markup:
2225         MARKUP_IDENTIFIER {
2226                 $$ = $1;
2227         }
2228         | MARKUP
2229                 { THIS->lexer_->push_markup_state (); }
2230         markup
2231                 { $$ = $3;
2232                   THIS->lexer_->pop_state ();
2233                 }
2234         ;
2235
2236
2237 /*
2238 This should be done more dynamically if possible.
2239 */
2240 markup:
2241         STRING {
2242                 $$ = make_simple_markup ($1);
2243         }
2244         | MARKUP_HEAD_EMPTY {
2245                 $$ = scm_list_n ($1, SCM_UNDEFINED);
2246         }
2247         | MARKUP_HEAD_MARKUP0 markup {
2248                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2249         }
2250         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2251                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2252         }
2253         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2254                 $$  = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2255         }
2256         | markup_line {
2257                 $$ = $1;
2258         }
2259         | MARKUP_HEAD_LIST0 markup_list {
2260                 $$ = scm_list_n ($1,$2, SCM_UNDEFINED);
2261         }
2262         | MARKUP_HEAD_SCM0 embedded_scm {
2263                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2264         }
2265         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2266                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2267         }
2268         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2269                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2270         }
2271         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2272                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2273         }
2274         | MARKUP_IDENTIFIER {
2275                 $$ = $1;
2276         }
2277
2278         ;
2279
2280 markup_list:
2281         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2282         ;
2283
2284 markup_line:
2285         '{' markup_list_body '}' {
2286                 static SCM line ;
2287                 if (!line)
2288                         line = scm_c_eval_string ("line-markup");
2289
2290                 $$ = scm_list_n (line, scm_reverse_x ($2, SCM_EOL), SCM_UNDEFINED);
2291         }
2292         ;
2293
2294 markup_list_body:
2295         /**/ {  $$ = SCM_EOL; }
2296         | markup_list_body markup {
2297                 $$ = gh_cons ($2, $1) ;
2298         }
2299         ;
2300
2301
2302 %%
2303
2304 void
2305 My_lily_parser::set_yydebug (bool )
2306 {
2307 #if 0
2308         yydebug = 1;
2309 #endif
2310 }
2311
2312 extern My_lily_parser * current_parser;
2313
2314 void
2315 My_lily_parser::do_yyparse ()
2316 {
2317         current_parser = this;;
2318         yyparse ((void*)this);
2319 }
2320
2321
2322 /*
2323 Should make this optional?    It will also complain when you do
2324
2325         [s4]
2326
2327 which is entirely legitimate.
2328
2329 Or we can scrap it. Barchecks should detect wrong durations, and
2330 skipTypesetting speeds it up a lot.
2331 */
2332
2333 void
2334 My_lily_parser::beam_check (SCM dur)
2335 {
2336   Duration *d = unsmob_duration (dur);
2337   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2338     {
2339       Music * m = unsmob_music (last_beam_start_);
2340       m->origin ()->warning (_("Suspect duration found following this beam"));
2341     }
2342   last_beam_start_ = SCM_EOL;
2343 }
2344
2345
2346
2347
2348 /*
2349
2350 It is a little strange to have this function in this file, but
2351 otherwise, we have to import music classes into the lexer.
2352
2353 */
2354 int
2355 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2356 {
2357         if (gh_string_p (sid)) {
2358                 *destination = sid;
2359                 return STRING_IDENTIFIER;
2360         } else if (gh_number_p (sid)) {
2361                 *destination = sid;
2362                 return NUMBER_IDENTIFIER;
2363         } else if (unsmob_context_def (sid)) {
2364                 *destination = unsmob_context_def (sid)->clone_scm();
2365                 return TRANSLATOR_IDENTIFIER;
2366         } else if (unsmob_score (sid)) {
2367                 Score *sc =  new Score (*unsmob_score (sid));
2368                 *destination =sc->self_scm ();
2369                 return SCORE_IDENTIFIER;
2370         } else if (Music * mus =unsmob_music (sid)) {
2371                 *destination = unsmob_music (sid)->clone ()->self_scm();
2372                 unsmob_music (*destination)->
2373                         set_mus_property ("origin", make_input (last_input_));
2374                 return dynamic_cast<Event*> (mus)
2375                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2376         } else if (unsmob_duration (sid)) {
2377                 *destination = unsmob_duration (sid)->smobbed_copy();
2378                 return DURATION_IDENTIFIER;
2379         } else if (unsmob_music_output_def (sid)) {
2380                 Music_output_def *p = unsmob_music_output_def (sid);
2381                 p = p->clone ();
2382
2383                 *destination = p->self_scm();
2384                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2385         } else if (Text_item::markup_p (sid)) {
2386                 *destination = sid;
2387                 return MARKUP_IDENTIFIER;
2388         }
2389
2390         return -1;
2391 }
2392
2393 Music *
2394 property_op_to_music (SCM op)
2395 {
2396         Music * m = 0;
2397         SCM tag = gh_car (op);
2398         SCM symbol  = gh_cadr (op);
2399         SCM args = gh_cddr (op);
2400         SCM grob_val = SCM_UNDEFINED;
2401         SCM grob_sym = SCM_UNDEFINED;
2402         SCM val = SCM_UNDEFINED;
2403
2404         if (tag == ly_symbol2scm ("assign"))
2405                 {
2406                 m =  MY_MAKE_MUSIC("PropertySet");
2407                 val = gh_car (args);
2408                 }
2409         else if (tag == ly_symbol2scm ("unset"))
2410                 m =  MY_MAKE_MUSIC("PropertyUnset");
2411         else if (tag == ly_symbol2scm ("poppush")
2412                  || tag == ly_symbol2scm ("push"))
2413                 {
2414                 m  = MY_MAKE_MUSIC("OverrideProperty");
2415                 grob_sym = gh_car (args);
2416                 grob_val = gh_cadr (args);
2417                 }
2418         else if (tag == ly_symbol2scm ("pop")) {
2419                 m = MY_MAKE_MUSIC("RevertProperty");
2420                 grob_sym = gh_car (args);
2421                 }
2422
2423         m->set_mus_property ("symbol", symbol);
2424
2425         if (val != SCM_UNDEFINED)
2426                 m->set_mus_property ("value", val);
2427         if (grob_val != SCM_UNDEFINED)
2428                 m->set_mus_property ("grob-value", grob_val);
2429
2430         if (grob_sym != SCM_UNDEFINED)
2431                 {
2432                 bool itc = internal_type_checking_global_b;
2433                 /* UGH.
2434                 */
2435                 bool autobeam = gh_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2436                 if (autobeam)
2437                         internal_type_checking_global_b = false;
2438                 m->set_mus_property ("grob-property", grob_sym);
2439                 if (autobeam)
2440                         internal_type_checking_global_b = itc;
2441                 }
2442
2443         if (op == ly_symbol2scm ("poppush"))
2444                 m->set_mus_property ("pop-first", SCM_BOOL_T);
2445
2446
2447         return m;
2448 }
2449
2450 Music*
2451 context_spec_music (SCM type, SCM id, Music * m, SCM ops)
2452 {
2453         Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
2454
2455         csm->set_mus_property ("element", m->self_scm ());
2456         scm_gc_unprotect_object (m->self_scm ());
2457
2458         csm->set_mus_property ("context-type", scm_string_to_symbol (type));
2459         csm->set_mus_property ("property-operations", ops);
2460
2461         if (gh_string_p (id))
2462                 csm->set_mus_property ("context-id", id);
2463         return csm;
2464 }
2465
2466
2467 SCM
2468 get_next_unique_context ()
2469 {
2470         static int new_context_count;
2471
2472         char s[1024];
2473         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2474
2475         return scm_makfrom0str (s);
2476 }