mf/feta-orator.mf

   1 % feta-orator.mf
   2 % part of LilyPond's pretty-but-neat music font
   3
   4 fet_begingroup("orator")
   5
   6 height#:=designsize;
   7 thick#:=height#/4;
   8 thin#:=thick#/4;
   9 hair#:=thin#/2;
  10 kuulleke#:=thin#;
  11
  12 define_pixels(height,thick,thin,hair);
  13 foot_top#:=2thin#;
  14 foot_width#:=2thick#+thin#;
  15 define_pixels(foot_top,foot_width);
  16 define_pixels(kuulleke);
  17
  18 def draw_foot(expr xpos) =
  19         begingroup;
  20         clearxy;
  21         penpos1(thick,0);
  22         z1=(xpos,foot_top);
  23         penpos2(foot_width,0);
  24         z2=(x1,0);
  25         penpos3(hair,-90);
  26         z3r=z2r;
  27         penpos4(hair,90);
  28         z4l=z2l;
  29         z5=(x1,hair/2);
  30         fill z1..{right}z1r{down}..{right}z3l..z3r{left}..z5..{left}z4l..z4r{right}..{up}z1l{right}..z1..cycle;
  31         endgroup;
  32 enddef;
  33
  34 fet_beginchar("Numeral 0", "0", "zero")
  35         set_char_box(0, 3thick#, 0, height#);
  36         penpos1(thin,90);
  37         z1r=(w/2,h);
  38         penpos2(thick,0);
  39         z2r=(w,h/2);
  40         penpos3(thin,-90);
  41         z3r=(w/2,0);
  42         penpos4(thick,180);
  43         z4r=(0,h/2);
  44         fill z1r..z2r..z3r..z4r..cycle;
  45         unfill z1l..tension1.2..z2l..tension1.2..z3l..tension1.2..z4l..tension1.2..cycle;
  46 fet_endchar;
  47
  48 fet_beginchar("Numeral 1", "1", "one")
  49         set_char_box(0, 5/2thick#+thin#, 0, height#);
  50         penpos1(thick,0);
  51         z1=(thick+thick/2,height);
  52         penpos2(hair,45);
  53         z2=z1l+(1/4sqrt(2)*hair)*(1,-1);
  54         penpos3(hair,-45);
  55         z3=z1r+(1/4sqrt(2)*hair)*(-1,-1);
  56         x4=x1; y4=y1-kuulleke;
  57
  58         penpos5(thick,0);
  59         z5=(x1,foot_top);
  60
  61         z6=(0,h/2);
  62         save alpha; alpha=angle(z1l-z6);
  63         penpos7(thin,alpha-90);
  64         z7l=z6;
  65         penpos8(thin/cosd(alpha),-90);
  66         z8l=z1l;
  67         penpos9(hair,alpha-90);
  68         z9r=z8r+(hair/cosd(alpha))*(0,-1);
  69         fill z2r{(1,-1)}..z4..{(1,1)}z3l..z3r{down}..{down}z5r{left}..z5..{left}z5l{up}..{up}z2l..cycle;
  70 %       fill z7l{dir(alpha)}..{dir(alpha)}z2l{down}..z9r{up}..z9l{dir(180+alpha)}..{dir(180+alpha)}z7r..cycle;
  71         fill z7l{dir(alpha)}..{dir(alpha)}z1l..z2r..z9r{up}..z9l{dir(180+alpha)}..{dir(180+alpha)}z7r..cycle;
  72         penlabels(7,8,9);
  73
  74         draw_foot(x1);
  75 fet_endchar;
  76
  77 fet_beginchar("Numeral 4", "4", "four")
  78         set_char_box(0, 5/2thick#+3thin#, 0, height#);
  79         penpos1(3/2thick,0);
  80         z1r=(w-3thin,height);
  81         z2=(thin,1/4height+thin);
  82         penpos3(hair,45);
  83         z3=z1l+(1/4sqrt(2)*hair)*(1,-1);
  84         penpos4(hair,-45);
  85         z4=z1r+(1/4sqrt(2)*hair)*(-1,-1);
  86         x5=x1; y5=y1-kuulleke;
  87         save alpha; alpha=angle(z4r-z2);
  88         penpos6(thin,-90);
  89         z6l=z2;
  90         penpos7(thin,-90);
  91         y7=y6; x7=w-1/2thin;
  92         penpos8(thin,-alpha);
  93         z8r=z2;
  94         fill z3r{(1,-1)}..z5..{(1,1)}z4l..z4r{dir(180+alpha)}..{dir(180+alpha)}z8r{right}..{right}z7l..z7r{left}..{left}z6r..z8l{dir(alpha)}..{up}z3l..cycle;
  95         penlabels(1,2,3,4,5,6,7);
  96
  97         clearxy;
  98         penpos1(thick/cosd(alpha),alpha);
  99         % ugh, must be just > foot_width/2!
 100         z1r=(w-3thin,height-(thin+hair)/cosd(alpha));
 101         penpos2(hair,alpha+45);
 102         z2=z1l+(1/4sqrt(2)*hair)*dir(alpha-45);
 103         penpos3(hair,alpha-45);
 104         z3=z1r+(1/4sqrt(2)*hair)*dir(alpha-135);
 105         z4=z1+kuulleke*dir(alpha-90);
 106
 107         % ugh
 108         % the angle alpha may just let the hair penposes 3 and 4
 109         % stick-out to the right of the vertical...
 110 %       penpos5(thick,0);
 111 %       z5=(x1,foot_top);
 112         penpos5(whatever,0);
 113         x5r-x5l=x3r-x2l; x5r=x3r; y5=foot_top;
 114
 115         fill z2r{dir(alpha-45)}..z4..{dir(alpha+45)}z3l..z3r{down}..{down}z5r{left}..z5..{left}z5l{up}..{up}z2l..cycle;
 116         penlabels(1,2,3,4,5);
 117
 118         draw_foot(x5);
 119 fet_endchar;
 120
 121 fet_endgroup("orator")