utils/themeeditor/themeeditor.pro

   1 # Enabling profiling
   2 QMAKE_CXXFLAGS_DEBUG += -pg
   3 QMAKE_LFLAGS_DEBUG += -pg
   4
   5 # build in a separate folder.
   6 MYBUILDDIR = $$OUT_PWD/build/
   7 OBJECTS_DIR = $$MYBUILDDIR/o
   8 UI_DIR = $$MYBUILDDIR/ui
   9 MOC_DIR = $$MYBUILDDIR/moc
  10 RCC_DIR = $$MYBUILDDIR/rcc
  11 RBBASE_DIR = $$_PRO_FILE_PWD_
  12 RBBASE_DIR = $$replace(RBBASE_DIR,/utils/themeeditor,)
  13
  14 # Include directories
  15 INCLUDEPATH += gui
  16 INCLUDEPATH += models
  17 INCLUDEPATH += graphics
  18
  19 # Stuff for the parse lib
  20 libskin_parser.commands = @$(MAKE) \
  21     TARGET_DIR=$$MYBUILDDIR \
  22     CC=\"$$QMAKE_CC\" \
  23     BUILDDIR=$$OBJECTS_DIR \
  24     -C \
  25     $$RBBASE_DIR/lib/skin_parser \
  26     libskin_parser.a
  27 QMAKE_EXTRA_TARGETS += libskin_parser
  28 PRE_TARGETDEPS += libskin_parser
  29 INCLUDEPATH += $$RBBASE_DIR/lib/skin_parser
  30 LIBS += -L$$MYBUILDDIR \
  31     -lskin_parser
  32 DEPENDPATH = $$INCLUDEPATH
  33 HEADERS += models/parsetreemodel.h \
  34     models/parsetreenode.h \
  35     gui/editorwindow.h \
  36     gui/skinhighlighter.h \
  37     gui/skindocument.h \
  38     gui/preferencesdialog.h \
  39     gui/codeeditor.h \
  40     models/projectmodel.h \
  41     gui/tabcontent.h \
  42     gui/configdocument.h \
  43     gui/skinviewer.h \
  44     graphics/rbscreen.h \
  45     graphics/rbviewport.h \
  46     graphics/rbrenderinfo.h \
  47     graphics/rbimage.h \
  48     graphics/rbfont.h \
  49     gui/devicestate.h \
  50     graphics/rbalbumart.h \
  51     graphics/rbprogressbar.h \
  52     gui/findreplacedialog.h \
  53     graphics/rbtext.h \
  54     graphics/rbfontcache.h \
  55     graphics/rbtextcache.h \
  56     gui/skintimer.h
  57 SOURCES += main.cpp \
  58     models/parsetreemodel.cpp \
  59     models/parsetreenode.cpp \
  60     gui/editorwindow.cpp \
  61     gui/skinhighlighter.cpp \
  62     gui/skindocument.cpp \
  63     gui/preferencesdialog.cpp \
  64     gui/codeeditor.cpp \
  65     models/projectmodel.cpp \
  66     gui/configdocument.cpp \
  67     gui/skinviewer.cpp \
  68     graphics/rbscreen.cpp \
  69     graphics/rbviewport.cpp \
  70     graphics/rbrenderinfo.cpp \
  71     graphics/rbimage.cpp \
  72     graphics/rbfont.cpp \
  73     gui/devicestate.cpp \
  74     graphics/rbalbumart.cpp \
  75     graphics/rbprogressbar.cpp \
  76     gui/findreplacedialog.cpp \
  77     graphics/rbtext.cpp \
  78     graphics/rbfontcache.cpp \
  79     graphics/rbtextcache.cpp \
  80     gui/skintimer.cpp
  81 OTHER_FILES += README \
  82     resources/windowicon.png \
  83     resources/appicon.xcf \
  84     resources/COPYING \
  85     resources/document-save.png \
  86     resources/document-open.png \
  87     resources/document-new.png \
  88     resources/deviceoptions \
  89     resources/render/statusbar.png \
  90     resources/render/scenebg.png \
  91     resources/play.xcf \
  92     resources/play.png \
  93     resources/rwnd.png \
  94     resources/pause.xcf \
  95     resources/pause.png \
  96     resources/ffwd.xcf \
  97     resources/ffwd.png
  98 FORMS += gui/editorwindow.ui \
  99     gui/preferencesdialog.ui \
 100     gui/configdocument.ui \
 101     gui/skinviewer.ui \
 102     gui/findreplacedialog.ui \
 103     gui/skintimer.ui
 104 RESOURCES += resources.qrc
 105 win32:RC_FILE = themeeditor.rc
 106 macx {
 107     QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.4u.sdk
 108     QMAKE_LFLAGS_PPC = -mmacosx-version-min=10.4 \
 109         -arch \
 110         ppc
 111     QMAKE_LFLAGS_X86 = -mmacosx-version-min=10.4 \
 112         -arch \
 113         i386
 114     CONFIG += x86 \
 115         ppc
 116     QMAKE_INFO_PLIST = Info.plist
 117     RC_FILE = resources/windowicon.icns
 118 }