utils/wpseditor/gui/gui.pro

   1 TEMPLATE = app
   2 TARGET =
   3 DEPENDPATH += . build src ui
   4 INCLUDEPATH += . src/QPropertyEditor ../libwps/src
   5 DESTDIR = bin
   6 OBJECTS_DIR = build
   7 MOC_DIR = build
   8 UI_DIR = build
   9 QMAKE_LIBDIR += lib
  10 QT = gui core
  11 CONFIG += qt warn_on console debug_and_release
  12 libwps.commands += $(MAKE) -C ../libwps shared
  13 QMAKE_EXTRA_TARGETS += libwps
  14 PRE_TARGETDEPS += libwps
  15 HEADERS += ../libwps/src/api.h \
  16  ../libwps/src/defs.h \
  17  src/slider.h \
  18  src/qtrackstate.h \
  19  src/qwpsstate.h \
  20  src/qwpseditorwindow.h \
  21  src/utils.h \
  22  src/qwpsdrawer.h
  23 FORMS += ui/mainwindow.ui ui/slider.ui
  24 SOURCES += src/main.cpp \
  25  src/slider.cpp \
  26  src/qtrackstate.cpp \
  27  src/qwpsstate.cpp \
  28  src/qwpseditorwindow.cpp \
  29  src/utils.cpp \
  30  src/qwpsdrawer.cpp \
  31  src/qwpsdrawer_static.cpp
  32 LIBS += -Lbin
  33 CONFIG(debug, debug|release) {
  34  LIBS +=  -lQPropertyEditord
  35  TARGET =  wpseditord
  36 }
  37 CONFIG(release, debug|release) {
  38  LIBS +=  -lQPropertyEditor
  39  TARGET =  wpseditor
  40 }