rbutil/rbutilqt/rbutilqt.pro

   1
   2 # ccache
   3 unix:!mac:!noccache {
   4     CCACHE = $$system(which ccache)
   5     !isEmpty(CCACHE) {
   6         message("using ccache")
   7         QMAKE_CXX = ccache g++
   8         QMAKE_CC = ccache gcc
   9     }
  10 }
  11
  12 MYBUILDDIR = $$OUT_PWD/build/
  13 OBJECTS_DIR = $$MYBUILDDIR/o
  14 UI_DIR = $$MYBUILDDIR/ui
  15 MOC_DIR = $$MYBUILDDIR/moc
  16 RCC_DIR = $$MYBUILDDIR/rcc
  17
  18
  19 # check version of Qt installation
  20 VER = $$find(QT_VERSION, ^4\.[3-9]+.*)
  21 isEmpty(VER) {
  22     !isEmpty(QT_VERSION) error("Qt found:" $$[QT_VERSION])
  23     error("Qt >= 4.3 required!")
  24 }
  25 message("Qt version used:" $$VER)
  26
  27 RBBASE_DIR = $$_PRO_FILE_PWD_
  28 RBBASE_DIR = $$replace(RBBASE_DIR,/rbutil/rbutilqt,)
  29
  30 message("Rockbox Base dir: "$$RBBASE_DIR)
  31
  32 # check for system speex. Add a custom rule for pre-building librbspeex if not
  33 # found. Newer versions of speex are split up into libspeex and libspeexdsp,
  34 # and some distributions package them separately. Check for both and fall back
  35 # to librbspeex if not found.
  36 LIBSPEEX = $$system(pkg-config --silence-errors --libs speex speexdsp)
  37 !static:!isEmpty(LIBSPEEX) {
  38     LIBS += $$LIBSPEEX
  39 }
  40 # custom rules for rockbox-specific libs
  41 !mac {
  42     RBLIBPOSTFIX = .a
  43 }
  44 mac {
  45     RBLIBPOSTFIX = -universal
  46 }
  47 rbspeex.commands = @$(MAKE) TARGET_DIR=$$MYBUILDDIR -C $$RBBASE_DIR/tools/rbspeex librbspeex$$RBLIBPOSTFIX CC=\"$$QMAKE_CC\"
  48 libucl.commands = @$(MAKE) TARGET_DIR=$$MYBUILDDIR -C $$RBBASE_DIR/tools/ucl/src libucl$$RBLIBPOSTFIX CC=\"$$QMAKE_CC\"
  49 libmkamsboot.commands = @$(MAKE) TARGET_DIR=$$MYBUILDDIR -C $$RBBASE_DIR/rbutil/mkamsboot libmkamsboot$$RBLIBPOSTFIX CC=\"$$QMAKE_CC\"
  50 libmktccboot.commands = @$(MAKE) TARGET_DIR=$$MYBUILDDIR -C $$RBBASE_DIR/rbutil/mktccboot libmktccboot$$RBLIBPOSTFIX CC=\"$$QMAKE_CC\"
  51 QMAKE_EXTRA_TARGETS += rbspeex libucl libmkamsboot libmktccboot
  52 PRE_TARGETDEPS += rbspeex libucl libmkamsboot libmktccboot
  53
  54 # rule for creating ctags file
  55 tags.commands = ctags -R --c++-kinds=+p --fields=+iaS --extra=+q $(SOURCES)
  56 tags.depends = $(SOURCES)
  57 QMAKE_EXTRA_TARGETS += tags
  58
  59 # add a custom rule for making the translations
  60 lrelease.commands = $$[QT_INSTALL_BINS]/lrelease -silent $$_PRO_FILE_
  61 QMAKE_EXTRA_TARGETS += lrelease
  62 !dbg {
  63     PRE_TARGETDEPS += lrelease
  64 }
  65
  66 SOURCES += rbutilqt.cpp \
  67  main.cpp \
  68  installwindow.cpp \
  69  base/httpget.cpp \
  70  configure.cpp \
  71  zip/zip.cpp \
  72  zip/unzip.cpp \
  73  base/zipinstaller.cpp \
  74  progressloggergui.cpp \
  75  installtalkwindow.cpp \
  76  base/talkfile.cpp \
  77  base/talkgenerator.cpp \
  78  base/autodetection.cpp \
  79  ../ipodpatcher/ipodpatcher.c \
  80  ../sansapatcher/sansapatcher.c \
  81  ../chinachippatcher/chinachip.c \
  82  browsedirtree.cpp \
  83  themesinstallwindow.cpp \
  84  base/uninstall.cpp \
  85  uninstallwindow.cpp \
  86  base/utils.cpp \
  87  preview.cpp \
  88  base/encoders.cpp \
  89  encttscfggui.cpp \
  90  base/encttssettings.cpp \
  91  base/ttsbase.cpp \
  92  base/ttsexes.cpp \
  93  base/ttssapi.cpp \
  94  base/ttsfestival.cpp \
  95  ../../tools/wavtrim.c \
  96  ../../tools/voicefont.c \
  97  base/voicefile.cpp \
  98  createvoicewindow.cpp \
  99  base/rbsettings.cpp \
 100  base/serverinfo.cpp \
 101  base/systeminfo.cpp \
 102  base/rbunzip.cpp \
 103  base/rbzip.cpp \
 104  base/system.cpp \
 105  sysinfo.cpp \
 106  systrace.cpp \
 107  base/bootloaderinstallbase.cpp \
 108  base/bootloaderinstallmi4.cpp \
 109  base/bootloaderinstallhex.cpp \
 110  base/bootloaderinstallipod.cpp \
 111  base/bootloaderinstallsansa.cpp \
 112  base/bootloaderinstallfile.cpp \
 113  base/bootloaderinstallchinachip.cpp \
 114  base/bootloaderinstallams.cpp \
 115  base/bootloaderinstalltcc.cpp \
 116  ../../tools/mkboot.c \
 117  ../../tools/iriver.c \
 118
 119 HEADERS += rbutilqt.h \
 120  installwindow.h \
 121  base/httpget.h \
 122  configure.h \
 123  zip/zip.h \
 124  zip/unzip.h \
 125  zip/zipentry_p.h \
 126  zip/unzip_p.h \
 127  zip/zip_p.h \
 128  version.h \
 129  base/zipinstaller.h \
 130  installtalkwindow.h \
 131  base/talkfile.h \
 132  base/talkgenerator.h \
 133  base/autodetection.h \
 134  base/progressloggerinterface.h \
 135  progressloggergui.h \
 136  ../ipodpatcher/ipodpatcher.h \
 137  ../ipodpatcher/ipodio.h \
 138  ../ipodpatcher/parttypes.h \
 139  ../sansapatcher/sansapatcher.h \
 140  ../sansapatcher/sansaio.h \
 141  ../chinachippatcher/chinachip.h \
 142  irivertools/h100sums.h \
 143  irivertools/h120sums.h \
 144  irivertools/h300sums.h \
 145  browsedirtree.h \
 146  themesinstallwindow.h \
 147  base/uninstall.h \
 148  uninstallwindow.h \
 149  base/utils.h \
 150  preview.h \
 151  base/encoders.h \
 152  encttscfggui.h \
 153  base/encttssettings.h \
 154  base/ttsbase.h \
 155  base/ttsexes.h \
 156  base/ttsfestival.h \
 157  base/ttssapi.h \
 158  ../../tools/wavtrim.h \
 159  ../../tools/voicefont.h \
 160  base/voicefile.h \
 161  createvoicewindow.h \
 162  base/rbsettings.h \
 163  base/serverinfo.h \
 164  base/systeminfo.h \
 165  base/rbunzip.h \
 166  base/rbzip.h \
 167  sysinfo.h \
 168  base/system.h \
 169  systrace.h \
 170  base/bootloaderinstallbase.h \
 171  base/bootloaderinstallmi4.h \
 172  base/bootloaderinstallhex.h \
 173  base/bootloaderinstallipod.h \
 174  base/bootloaderinstallsansa.h \
 175  base/bootloaderinstallfile.h \
 176  base/bootloaderinstallchinachip.h \
 177  base/bootloaderinstallams.h \
 178  base/bootloaderinstalltcc.h \
 179  ../../tools/mkboot.h \
 180  ../../tools/iriver.h \
 181
 182 # Needed by QT on Win
 183 INCLUDEPATH = $$_PRO_FILE_PWD_ $$_PRO_FILE_PWD_/irivertools $$_PRO_FILE_PWD_/zip $$_PRO_FILE_PWD_/zlib $$_PRO_FILE_PWD_/base
 184 INCLUDEPATH += $$RBBASE_DIR/rbutil/ipodpatcher $$RBBASE_DIR/rbutil/sansapatcher $$RBBASE_DIR/tools/rbspeex $$RBBASE_DIR/tools
 185
 186 DEPENDPATH = $$INCLUDEPATH
 187
 188 LIBS += -L$$OUT_PWD -L$$MYBUILDDIR -lrbspeex -lmkamsboot -lmktccboot -lucl
 189
 190 TEMPLATE = app
 191 dbg {
 192     CONFIG += debug thread qt warn_on
 193     DEFINES -= QT_NO_DEBUG_OUTPUT
 194     message("debug")
 195 }
 196 !dbg {
 197     CONFIG += release thread qt
 198     DEFINES -= QT_NO_DEBUG_OUTPUT
 199     DEFINES += NODEBUG
 200     message("release")
 201 }
 202
 203 TARGET = rbutilqt
 204
 205 FORMS += rbutilqtfrm.ui \
 206  aboutbox.ui \
 207  installwindowfrm.ui \
 208  progressloggerfrm.ui \
 209  configurefrm.ui \
 210  browsedirtreefrm.ui \
 211  installtalkfrm.ui \
 212  themesinstallfrm.ui \
 213  uninstallfrm.ui \
 214  previewfrm.ui \
 215  createvoicefrm.ui \
 216  sysinfofrm.ui \
 217  systracefrm.ui
 218
 219 RESOURCES += $$_PRO_FILE_PWD_/rbutilqt.qrc
 220 win32 {
 221     RESOURCES += $$_PRO_FILE_PWD_/rbutilqt-win.qrc
 222 }
 223 !dbg {
 224     RESOURCES += $$_PRO_FILE_PWD_/rbutilqt-lang.qrc
 225 }
 226
 227 TRANSLATIONS += lang/rbutil_cs.ts \
 228  lang/rbutil_de.ts \
 229  lang/rbutil_fi.ts \
 230  lang/rbutil_fr.ts \
 231  lang/rbutil_gr.ts \
 232  lang/rbutil_he.ts \
 233  lang/rbutil_it.ts \
 234  lang/rbutil_ja.ts \
 235  lang/rbutil_nl.ts \
 236  lang/rbutil_pl.ts \
 237  lang/rbutil_pt.ts \
 238  lang/rbutil_pt_BR.ts \
 239  lang/rbutil_ru.ts \
 240  lang/rbutil_tr.ts \
 241  lang/rbutil_zh_CN.ts \
 242  lang/rbutil_zh_TW.ts \
 243
 244
 245 QT += network
 246 DEFINES += RBUTIL _LARGEFILE64_SOURCE
 247
 248 win32 {
 249     SOURCES +=  ../ipodpatcher/ipodio-win32.c
 250     SOURCES +=  ../ipodpatcher/ipodio-win32-scsi.c
 251     SOURCES +=  ../sansapatcher/sansaio-win32.c
 252     RC_FILE = rbutilqt.rc
 253     LIBS += -lsetupapi -lnetapi32
 254 }
 255
 256 unix {
 257     SOURCES +=  ../ipodpatcher/ipodio-posix.c
 258     SOURCES +=  ../sansapatcher/sansaio-posix.c
 259 }
 260 unix:!static:!libusb1 {
 261     LIBS += -lusb
 262 }
 263 unix:!static:libusb1 {
 264     DEFINES += LIBUSB1
 265     LIBS += -lusb-1.0
 266 }
 267
 268 unix:static {
 269     # force statically linking of libusb. Libraries that are appended
 270     # later will get linked dynamically again.
 271     LIBS += -Wl,-Bstatic -lusb -Wl,-Bdynamic
 272 }
 273
 274 macx {
 275     QMAKE_MAC_SDK=/Developer/SDKs/MacOSX10.4u.sdk
 276     QMAKE_LFLAGS_PPC=-mmacosx-version-min=10.4 -arch ppc
 277     QMAKE_LFLAGS_X86=-mmacosx-version-min=10.4 -arch i386
 278     CONFIG+=x86 ppc
 279     LIBS += -L/usr/local/lib -framework IOKit -framework CoreFoundation -lz
 280     INCLUDEPATH += /usr/local/include
 281     QMAKE_INFO_PLIST = Info.plist
 282     RC_FILE = icons/rbutilqt.icns
 283
 284     # rule for creating a dmg file
 285     dmg.commands = hdiutil create -ov -srcfolder rbutilqt.app/ rbutil.dmg
 286     QMAKE_EXTRA_TARGETS += dmg
 287 }
 288
 289 static {
 290     QTPLUGIN += qtaccessiblewidgets
 291     LIBS += -L$$(QT_BUILD_TREE)/plugins/accessible -lqtaccessiblewidgets
 292     LIBS += -L.
 293     DEFINES += STATIC
 294     message("using static plugin")
 295 }
 296
 297 unix {
 298     target.path = /usr/local/bin
 299     INSTALLS += target
 300 }
 301
 302
 303