rbutil/rbutilqt/rbutilqt.pro

   1
   2 # ccache
   3 unix:!mac:!noccache {
   4     CCACHE = $$system(which ccache)
   5     !isEmpty(CCACHE) {
   6         message("using ccache")
   7         QMAKE_CXX = ccache g++
   8         QMAKE_CC = ccache gcc
   9     }
  10 }
  11
  12 MYBUILDDIR = $$OUT_PWD/build/
  13 OBJECTS_DIR = $$MYBUILDDIR/o
  14 UI_DIR = $$MYBUILDDIR/ui
  15 MOC_DIR = $$MYBUILDDIR/moc
  16 RCC_DIR = $$MYBUILDDIR/rcc
  17
  18
  19 # check version of Qt installation
  20 VER = $$find(QT_VERSION, ^4\.[3-9]+.*)
  21 isEmpty(VER) {
  22     !isEmpty(QT_VERSION) error("Qt found:" $$[QT_VERSION])
  23     error("Qt >= 4.3 required!")
  24 }
  25 message("Qt version used:" $$VER)
  26
  27 RBBASE_DIR = $$_PRO_FILE_PWD_
  28 RBBASE_DIR = $$replace(RBBASE_DIR,/rbutil/rbutilqt,)
  29
  30 message("Rockbox Base dir: "$$RBBASE_DIR)
  31
  32 # check for system speex. Add a custom rule for pre-building librbspeex if not found.
  33 LIBSPEEX = $$system(pkg-config --silence-errors --libs speex)
  34 !static:!isEmpty(LIBSPEEX) {
  35     # newer versions of speex are split up into libspeex and libspeexdsp.
  36     # avoid checking twice if libspeex is missing.
  37     LIBSPEEX += $$system(pkg-config --silence-errors --libs speexdsp)
  38     LIBS += $$LIBSPEEX
  39 }
  40 # custom rules for rockbox-specific libs
  41 !mac {
  42 rbspeex.commands = @$(MAKE) TARGET_DIR=$$MYBUILDDIR -C $$RBBASE_DIR/tools/rbspeex librbspeex.a
  43 libucl.commands = @$(MAKE) TARGET_DIR=$$MYBUILDDIR -C $$RBBASE_DIR/tools/ucl/src libucl.a
  44 libmkamsboot.commands = @$(MAKE) TARGET_DIR=$$MYBUILDDIR -C $$RBBASE_DIR/rbutil/mkamsboot libmkamsboot.a
  45 libmktccboot.commands = @$(MAKE) TARGET_DIR=$$MYBUILDDIR -C $$RBBASE_DIR/rbutil/mktccboot libmktccboot.a
  46 }
  47 mac {
  48 rbspeex.commands = @$(MAKE) TARGET_DIR=$$MYBUILDDIR -C $$RBBASE_DIR/tools/rbspeex librbspeex-universal
  49 libucl.commands = @$(MAKE) TARGET_DIR=$$MYBUILDDIR -C $$RBBASE_DIR/tools/ucl/src libucl-universal
  50 libmkamsboot.commands = @$(MAKE) TARGET_DIR=$$MYBUILDDIR -C $$RBBASE_DIR/rbutil/mkamsboot libmkamsboot-universal
  51 libmktccboot.commands = @$(MAKE) TARGET_DIR=$$MYBUILDDIR -C $$RBBASE_DIR/rbutil/mktccboot libmktccboot-universal
  52 }
  53 QMAKE_EXTRA_TARGETS += rbspeex libucl libmkamsboot libmktccboot
  54 PRE_TARGETDEPS += rbspeex libucl libmkamsboot libmktccboot
  55
  56 # rule for creating ctags file
  57 tags.commands = ctags -R --c++-kinds=+p --fields=+iaS --extra=+q $(SOURCES)
  58 tags.depends = $(SOURCES)
  59 QMAKE_EXTRA_TARGETS += tags
  60
  61 # add a custom rule for making the translations
  62 lrelease.commands = $$[QT_INSTALL_BINS]/lrelease -silent $$_PRO_FILE_
  63 QMAKE_EXTRA_TARGETS += lrelease
  64 !dbg {
  65     PRE_TARGETDEPS += lrelease
  66 }
  67
  68 SOURCES += rbutilqt.cpp \
  69  main.cpp \
  70  install.cpp \
  71  base/httpget.cpp \
  72  configure.cpp \
  73  zip/zip.cpp \
  74  zip/unzip.cpp \
  75  base/zipinstaller.cpp \
  76  progressloggergui.cpp \
  77  installtalkwindow.cpp \
  78  base/talkfile.cpp \
  79  base/talkgenerator.cpp \
  80  base/autodetection.cpp \
  81  ../ipodpatcher/ipodpatcher.c \
  82  ../sansapatcher/sansapatcher.c \
  83  ../chinachippatcher/chinachip.c \
  84  browsedirtree.cpp \
  85  themesinstallwindow.cpp \
  86  base/uninstall.cpp \
  87  uninstallwindow.cpp \
  88  base/utils.cpp \
  89  preview.cpp \
  90  base/encoders.cpp \
  91  encttscfggui.cpp \
  92  base/encttssettings.cpp \
  93  base/ttsbase.cpp \
  94  base/ttsexes.cpp \
  95  base/ttssapi.cpp \
  96  base/ttsfestival.cpp \
  97  ../../tools/wavtrim.c \
  98  ../../tools/voicefont.c \
  99  base/voicefile.cpp \
 100  createvoicewindow.cpp \
 101  base/rbsettings.cpp \
 102  base/rbunzip.cpp \
 103  base/rbzip.cpp \
 104  base/system.cpp \
 105  sysinfo.cpp \
 106  systrace.cpp \
 107  base/bootloaderinstallbase.cpp \
 108  base/bootloaderinstallmi4.cpp \
 109  base/bootloaderinstallhex.cpp \
 110  base/bootloaderinstallipod.cpp \
 111  base/bootloaderinstallsansa.cpp \
 112  base/bootloaderinstallfile.cpp \
 113  base/bootloaderinstallchinachip.cpp \
 114  base/bootloaderinstallams.cpp \
 115  base/bootloaderinstalltcc.cpp \
 116  ../../tools/mkboot.c \
 117  ../../tools/iriver.c \
 118
 119 HEADERS += rbutilqt.h \
 120  install.h \
 121  base/httpget.h \
 122  configure.h \
 123  zip/zip.h \
 124  zip/unzip.h \
 125  zip/zipentry_p.h \
 126  zip/unzip_p.h \
 127  zip/zip_p.h \
 128  version.h \
 129  base/zipinstaller.h \
 130  installtalkwindow.h \
 131  base/talkfile.h \
 132  base/talkgenerator.h \
 133  base/autodetection.h \
 134  base/progressloggerinterface.h \
 135  progressloggergui.h \
 136  ../ipodpatcher/ipodpatcher.h \
 137  ../ipodpatcher/ipodio.h \
 138  ../ipodpatcher/parttypes.h \
 139  ../sansapatcher/sansapatcher.h \
 140  ../sansapatcher/sansaio.h \
 141  ../chinachippatcher/chinachip.h \
 142  irivertools/h100sums.h \
 143  irivertools/h120sums.h \
 144  irivertools/h300sums.h \
 145  browsedirtree.h \
 146  themesinstallwindow.h \
 147  base/uninstall.h \
 148  uninstallwindow.h \
 149  base/utils.h \
 150  preview.h \
 151  base/encoders.h \
 152  encttscfggui.h \
 153  base/encttssettings.h \
 154  base/ttsbase.h \
 155  base/ttsexes.h \
 156  base/ttsfestival.h \
 157  base/ttssapi.h \
 158  ../../tools/wavtrim.h \
 159  ../../tools/voicefont.h \
 160  base/voicefile.h \
 161  createvoicewindow.h \
 162  base/rbsettings.h \
 163  base/rbunzip.h \
 164  base/rbzip.h \
 165  sysinfo.h \
 166  base/system.h \
 167  systrace.h \
 168  base/bootloaderinstallbase.h \
 169  base/bootloaderinstallmi4.h \
 170  base/bootloaderinstallhex.h \
 171  base/bootloaderinstallipod.h \
 172  base/bootloaderinstallsansa.h \
 173  base/bootloaderinstallfile.h \
 174  base/bootloaderinstallchinachip.h \
 175  base/bootloaderinstallams.h \
 176  base/bootloaderinstalltcc.h \
 177  ../../tools/mkboot.h \
 178  ../../tools/iriver.h \
 179
 180 # Needed by QT on Win
 181 INCLUDEPATH = $$_PRO_FILE_PWD_ $$_PRO_FILE_PWD_/irivertools $$_PRO_FILE_PWD_/zip $$_PRO_FILE_PWD_/zlib $$_PRO_FILE_PWD_/base
 182 INCLUDEPATH += $$RBBASE_DIR/rbutil/ipodpatcher $$RBBASE_DIR/rbutil/sansapatcher $$RBBASE_DIR/tools/rbspeex $$RBBASE_DIR/tools
 183
 184 DEPENDPATH = $$INCLUDEPATH
 185
 186 LIBS += -L$$OUT_PWD -L$$MYBUILDDIR -lrbspeex -lmkamsboot -lmktccboot -lucl
 187
 188 TEMPLATE = app
 189 dbg {
 190     CONFIG += debug thread qt warn_on
 191     DEFINES -= QT_NO_DEBUG_OUTPUT
 192     message("debug")
 193 }
 194 !dbg {
 195     CONFIG += release thread qt
 196     DEFINES -= QT_NO_DEBUG_OUTPUT
 197     DEFINES += NODEBUG
 198     message("release")
 199 }
 200
 201 TARGET = rbutilqt
 202
 203 FORMS += rbutilqtfrm.ui \
 204  aboutbox.ui \
 205  installfrm.ui \
 206  progressloggerfrm.ui \
 207  configurefrm.ui \
 208  browsedirtreefrm.ui \
 209  installtalkfrm.ui \
 210  themesinstallfrm.ui \
 211  uninstallfrm.ui \
 212  previewfrm.ui \
 213  createvoicefrm.ui \
 214  sysinfofrm.ui \
 215  systracefrm.ui
 216
 217 RESOURCES += $$_PRO_FILE_PWD_/rbutilqt.qrc
 218 win32 {
 219     RESOURCES += $$_PRO_FILE_PWD_/rbutilqt-win.qrc
 220 }
 221 !dbg {
 222     RESOURCES += $$_PRO_FILE_PWD_/rbutilqt-lang.qrc
 223 }
 224
 225 TRANSLATIONS += lang/rbutil_cs.ts \
 226  lang/rbutil_de.ts \
 227  lang/rbutil_fi.ts \
 228  lang/rbutil_fr.ts \
 229  lang/rbutil_gr.ts \
 230  lang/rbutil_he.ts \
 231  lang/rbutil_ja.ts \
 232  lang/rbutil_nl.ts \
 233  lang/rbutil_pt.ts \
 234  lang/rbutil_pt_BR.ts \
 235  lang/rbutil_tr.ts \
 236  lang/rbutil_zh_CN.ts \
 237  lang/rbutil_zh_TW.ts \
 238
 239
 240 QT += network
 241 DEFINES += RBUTIL _LARGEFILE64_SOURCE
 242
 243 win32 {
 244     SOURCES +=  ../ipodpatcher/ipodio-win32.c
 245     SOURCES +=  ../ipodpatcher/ipodio-win32-scsi.c
 246     SOURCES +=  ../sansapatcher/sansaio-win32.c
 247     RC_FILE = rbutilqt.rc
 248     LIBS += -lsetupapi -lnetapi32
 249 }
 250
 251 unix {
 252     SOURCES +=  ../ipodpatcher/ipodio-posix.c
 253     SOURCES +=  ../sansapatcher/sansaio-posix.c
 254 }
 255 unix:!static:!libusb1 {
 256     LIBS += -lusb
 257 }
 258 unix:!static:libusb1 {
 259     DEFINES += LIBUSB1
 260     LIBS += -lusb-1.0
 261 }
 262
 263 unix:static {
 264     # force statically linking of libusb. Libraries that are appended
 265     # later will get linked dynamically again.
 266     LIBS += -Wl,-Bstatic -lusb -Wl,-Bdynamic
 267 }
 268
 269 macx {
 270     QMAKE_MAC_SDK=/Developer/SDKs/MacOSX10.4u.sdk
 271     QMAKE_LFLAGS_PPC=-mmacosx-version-min=10.4 -arch ppc
 272     QMAKE_LFLAGS_X86=-mmacosx-version-min=10.4 -arch i386
 273     CONFIG+=x86 ppc
 274     LIBS += -L/usr/local/lib -framework IOKit
 275     INCLUDEPATH += /usr/local/include
 276     QMAKE_INFO_PLIST = Info.plist
 277     RC_FILE = icons/rbutilqt.icns
 278
 279     # rule for creating a dmg file
 280     dmg.commands = hdiutil create -ov -srcfolder rbutilqt.app/ rbutil.dmg
 281     QMAKE_EXTRA_TARGETS += dmg
 282 }
 283
 284 static {
 285     QTPLUGIN += qtaccessiblewidgets
 286     LIBS += -L$$(QT_BUILD_TREE)/plugins/accessible -lqtaccessiblewidgets
 287     LIBS += -L.
 288     DEFINES += STATIC
 289     message("using static plugin")
 290 }
 291
 292 unix {
 293     target.path = /usr/local/bin
 294     INSTALLS += target
 295 }
 296
 297
 298