apps/plugins/plugin.lds

   1 #include "config.h"
   2
   3 /* These output formats should be in the config-files */
   4
   5 #ifdef CPU_COLDFIRE
   6 OUTPUT_FORMAT(elf32-m68k)
   7 #elif defined(CPU_ARM)
   8 OUTPUT_FORMAT(elf32-littlearm)
   9 #else
  10 OUTPUT_FORMAT(elf32-sh)
  11 #endif
  12
  13 #ifdef DEBUG
  14 #define STUBOFFSET 0x10000
  15 #else
  16 #define STUBOFFSET 0
  17 #endif
  18
  19 #if defined(CPU_PP)
  20 #ifdef CPU_PP502x
  21 #define NOCACHE_BASE    0x10000000
  22 #else
  23 #define NOCACHE_BASE    0x28000000
  24 #endif /* CPU_* */
  25 #define CACHEALIGN_SIZE 16
  26 #endif /* CPU_PP */
  27
  28 #ifndef NOCACHE_BASE
  29 /* Default to no offset if target doesn't define this */
  30 #define NOCACHE_BASE 0x00000000
  31 #endif
  32
  33 #if CONFIG_CPU==DM320 || CONFIG_CPU==S3C2440
  34 #include "cpu.h"
  35 #define DRAMSIZE (MEMORYSIZE * 0x100000) - STUBOFFSET - PLUGIN_BUFFER_SIZE - CODEC_SIZE - LCD_BUFFER_SIZE - TTB_SIZE
  36 #elif CONFIG_CPU==IMX31L
  37 #include "imx31l.h"
  38 /* Reserve 1mb for LCD buffer/TTB as in app.lds */
  39 #define DRAMSIZE (MEMORYSIZE * 0x100000 - 0x100000) - PLUGIN_BUFFER_SIZE - STUBOFFSET - CODEC_SIZE
  40 #elif CONFIG_CPU==AS3525 && MEMORYSIZE <= 2
  41 #define DRAMSIZE (MEMORYSIZE * 0x100000) - PLUGIN_BUFFER_SIZE - STUBOFFSET
  42 #else
  43 #define DRAMSIZE (MEMORYSIZE * 0x100000) - PLUGIN_BUFFER_SIZE - STUBOFFSET - CODEC_SIZE
  44 #endif
  45
  46 #if defined(IRIVER_H100_SERIES) || defined(IRIVER_H300)
  47 #define ARCH_IRIVER
  48 #endif
  49
  50 #if defined(ARCH_IRIVER) || defined(IAUDIO_M3)
  51 #define DRAMORIG 0x31000000
  52 #define IRAMORIG 0x1000c000
  53 #define IRAMSIZE 0xc000
  54 #elif defined(IAUDIO_X5) || defined(IAUDIO_M5)
  55 #define DRAMORIG 0x31000000
  56 #define IRAMORIG 0x10010000
  57 #define IRAMSIZE 0x10000
  58 #elif CONFIG_CPU == PP5022 || CONFIG_CPU == PP5024
  59 /* PP5022/24 have 128KB of IRAM */
  60 #define DRAMORIG 0x00000000
  61 #define IRAMORIG 0x4000c000
  62 #define IRAMSIZE 0x14000
  63 #elif defined(CPU_PP)
  64 /* all other PP's have 96KB of IRAM */
  65 #define DRAMORIG 0x00000000
  66 #define IRAMORIG 0x4000c000
  67 #define IRAMSIZE 0x0c000
  68 #elif CONFIG_CPU == PNX0101
  69 #define DRAMORIG 0xc00000 + STUBOFFSET
  70 #define IRAMORIG 0x407000
  71 #define IRAMSIZE 0x9000
  72 #elif CONFIG_CPU == S3C2440
  73 #define DRAMORIG 0x0 + STUBOFFSET
  74 #define IRAM DRAM
  75 #define IRAMSIZE 0
  76 #elif CONFIG_CPU == IMX31L
  77 #define DRAMORIG 0x0 + STUBOFFSET
  78 #define IRAM DRAM
  79 #define IRAMSIZE 0
  80 #elif CONFIG_CPU==DM320
  81 #define DRAMORIG 0x00900000 + STUBOFFSET
  82 #define IRAMORIG DRAMORIG
  83 #define IRAMSIZE 0x4000
  84 #define IRAM DRAM
  85 #elif defined(CPU_TCC780X) || defined(CPU_TCC77X)
  86 #define DRAMORIG 0x20000000
  87 /*#define IRAMORIG 0x1000c000
  88 #define IRAMSIZE 0xc000*/
  89 #define IRAM DRAM
  90 #define IRAMSIZE 0
  91 #elif CONFIG_CPU==AS3525
  92 #if MEMORYSIZE <= 2
  93 #define IRAMSIZE 0  /* simulates no IRAM since codec is already entirely in IRAM */
  94 #define CODEC_ORIGIN (0x50000 - CODEC_SIZE)
  95 #define PLUGIN_ORIGIN (DRAMORIG + DRAMSIZE)
  96 #else
  97 #define IRAMORIG 0x0
  98 #define IRAMSIZE 0x50000
  99 #endif
 100 #define DRAMORIG 0x30000000
 101
 102 #else
 103 #define DRAMORIG 0x09000000 + STUBOFFSET
 104 #endif
 105
 106 #define PLUGIN_LENGTH PLUGIN_BUFFER_SIZE
 107
 108 #ifndef CODEC_ORIGIN /* targets can specify another origin */
 109 #define CODEC_ORIGIN (DRAMORIG + (DRAMSIZE))
 110 #endif
 111
 112 #ifndef PLUGIN_ORIGIN /* targets can specify another origin */
 113 #define PLUGIN_ORIGIN (CODEC_ORIGIN + CODEC_SIZE)
 114 #endif
 115
 116 #ifdef CODEC
 117 #define THIS_LENGTH CODEC_SIZE
 118 #define THIS_ORIGIN CODEC_ORIGIN
 119 #else
 120 #define THIS_LENGTH PLUGIN_LENGTH
 121 #define THIS_ORIGIN PLUGIN_ORIGIN
 122 #endif
 123
 124 MEMORY
 125 {
 126    PLUGIN_RAM : ORIGIN = THIS_ORIGIN, LENGTH = THIS_LENGTH
 127 #if defined(IRAMSIZE) && IRAMSIZE != 0
 128    PLUGIN_IRAM : ORIGIN = IRAMORIG, LENGTH = IRAMSIZE
 129 #endif
 130 }
 131
 132 SECTIONS
 133 {
 134     .header : {
 135         _plugin_start_addr = .;
 136         plugin_start_addr = .;
 137         KEEP(*(.header))
 138     } > PLUGIN_RAM
 139
 140     .text :
 141     {
 142         *(.text*)
 143 #if defined(IRAMSIZE) && IRAMSIZE == 0
 144         *(.icode)
 145 #endif
 146 #ifdef CPU_ARM
 147         *(.glue_7)
 148         *(.glue_7t)
 149 #endif
 150     } > PLUGIN_RAM
 151
 152     .rodata :
 153     {
 154         *(.rodata*)
 155 #if defined(IRAMSIZE) && IRAMSIZE == 0
 156         *(.irodata)
 157 #endif
 158         . = ALIGN(0x4);
 159     } > PLUGIN_RAM
 160
 161     .data :
 162     {
 163         *(.data*)
 164 #if defined(IRAMSIZE) && IRAMSIZE == 0
 165         *(.idata)
 166 #endif
 167     } > PLUGIN_RAM
 168
 169 #if NOCACHE_BASE != 0
 170     .ncdata . + NOCACHE_BASE :
 171     {
 172         . = ALIGN(CACHEALIGN_SIZE);
 173         *(.ncdata*)
 174         . = ALIGN(CACHEALIGN_SIZE);
 175     } AT> PLUGIN_RAM
 176 #endif
 177
 178 #if defined(IRAMSIZE)
 179     iramcopy = . - NOCACHE_BASE;
 180 #endif
 181
 182     /DISCARD/ :
 183     {
 184         *(.eh_frame)
 185     }
 186
 187 #if defined(IRAMSIZE) && IRAMSIZE != 0
 188     .iram IRAMORIG : AT ( iramcopy)
 189     {
 190         iramstart = .;
 191         *(.icode)
 192         *(.irodata)
 193         *(.idata)
 194         iramend = .;
 195     } > PLUGIN_IRAM
 196
 197
 198     .ibss (NOLOAD) :
 199     {
 200         iedata = .;
 201         *(.ibss)
 202         . = ALIGN(0x4);
 203         iend = .;
 204     } > PLUGIN_IRAM
 205 #endif
 206
 207     .bss (NOLOAD) :
 208     {
 209         plugin_bss_start = .;
 210         *(.bss*)
 211 #if defined(IRAMSIZE) && IRAMSIZE == 0
 212         *(.ibss)
 213 #endif
 214         *(COMMON)
 215         . = ALIGN(0x4);
 216     } > PLUGIN_RAM
 217
 218 #if NOCACHE_BASE != 0
 219     .ncbss . + NOCACHE_BASE (NOLOAD) :
 220     {
 221         . = ALIGN(CACHEALIGN_SIZE);
 222         *(.ncbss*)
 223         . = ALIGN(CACHEALIGN_SIZE);
 224     } AT> PLUGIN_RAM
 225 #endif
 226
 227     /* Restore . */
 228     .pluginend . - NOCACHE_BASE :
 229     {
 230         _plugin_end_addr = .;
 231         plugin_end_addr = .;
 232     }
 233
 234     /* Special trick to avoid a linker error when no other sections are
 235        left after garbage collection (plugin not for this platform) */
 236     .comment 0 :
 237     {
 238         KEEP(*(.comment))
 239     }
 240 }