rbutil/mkamsboot/nrv2e_d8.S

   1 /* arm_nrv2e_d8.S -- ARM decompressor for NRV2E
   2
   3    This file is part of the UPX executable compressor.
   4
   5    Copyright (C) 1996-2008 Markus Franz Xaver Johannes Oberhumer
   6    Copyright (C) 1996-2008 Laszlo Molnar
   7    Copyright (C) 2000-2008 John F. Reiser
   8    All Rights Reserved.
   9
  10    UPX and the UCL library are free software; you can redistribute them
  11    and/or modify them under the terms of the GNU General Public License as
  12    published by the Free Software Foundation; either version 2 of
  13    the License, or (at your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful,
  16    but WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18    GNU General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; see the file COPYING.
  22    If not, write to the Free Software Foundation, Inc.,
  23    59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  24
  25    Markus F.X.J. Oberhumer              Laszlo Molnar
  26    <markus@oberhumer.com>               <ml1050@users.sourceforge.net>
  27
  28    John F. Reiser
  29    <jreiser@users.sourceforge.net>
  30 */
  31 #define SAFE 0  /* 1 for src+dst bounds checking: cost 40 bytes */
  32
  33 #define src  r0
  34 #define len  r1  /* overlaps 'cnt' */
  35 #define dst  r2
  36 #define tmp  r3
  37 #define bits r4
  38 #define off  r5
  39 #define wrnk r6  /* 0x500  M2_MAX_OFFSET before "wrinkle" */
  40 #define srclim r7
  41 #if 1==SAFE  /*{*/
  42 #define dstlim r12
  43 #endif  /*}*/
  44
  45 #define cnt  r1  /* overlaps 'len' while reading an offset */
  46
  47 #if 1==SAFE  /*{*/
  48 #define CHECK_SRC  cmp src,srclim; bhs bad_src_n2e
  49 #define CHECK_DST  cmp dst,dstlim; bhs bad_dst_n2e
  50 #else  /*}{*/
  51 #define CHECK_SRC  /*empty*/
  52 #define CHECK_DST  /*empty*/
  53 #endif  /*}*/
  54
  55 #if 0  /*{ DEBUG only: check newly-decompressed against original dst */
  56 #define CHECK_BYTE \
  57    push {wrnk}; \
  58    ldrb  wrnk,[dst]; \
  59    cmp   wrnk,tmp; beq 0f; bkpt; \
  60 0: pop  {wrnk}
  61 #else  /*}{*/
  62 #define CHECK_BYTE  /*empty*/
  63 #endif  /*}*/
  64
  65 /* "mov lr,pc; bxx ..." implements conditional subroutine call */
  66 #define GETBIT  add bits,bits; mov lr,pc; beq get1_n2e
  67
  68 #define getnextb(reg) GETBIT; adc reg,reg
  69 #define   jnextb0     GETBIT; bcc
  70 #define   jnextb1     GETBIT; bcs
  71
  72 #ifndef PURE_THUMB
  73 ucl_nrv2e_decompress_8: .globl ucl_nrv2e_decompress_8  @ ARM mode
  74         .type ucl_nrv2e_decompress_8, %function
  75 /* error = (*)(char const *src, int len_src, char *dst, int *plen_dst)
  76    Actual decompressed length is stored through plen_dst.
  77    For SAFE mode: at call, *plen_dst must be allowed length of output buffer.
  78 */
  79         adr r12,1+.thumb_nrv2e_d8; bx r12  @ enter THUMB mode
  80 #endif
  81         .code 16  @ THUMB mode
  82         .thumb_func
  83
  84 .thumb_nrv2e_d8:
  85 #if 0
  86         push {r2,r3, r4,r5,r6,r7, lr}
  87 #define sp_DST0 0  /* stack offset of original dst */
  88 #endif
  89         add srclim,len,src  @ srclim= eof_src;
  90 #if 1==SAFE  /*{*/
  91         ldr tmp,[r3]  @ len_dst
  92         add tmp,dst
  93         mov dstlim,tmp
  94 #endif  /*}*/
  95         mov bits,#1; neg off,bits  @ off= -1 initial condition
  96         lsl bits,#31  @ 1<<31: refill next time
  97         mov wrnk,#5
  98         lsl wrnk,#8  @ 0x500  @ nrv2e M2_MAX_OFFSET
  99         b top_n2e
 100
 101 #if 1==SAFE  /*{*/
 102 bad_dst_n2e:  # return value will be 2
 103         add src,srclim,#1
 104 bad_src_n2e:  # return value will be 1
 105         add src,#1
 106 #endif  /*}*/
 107 eof_n2e:
 108 #if 0
 109         pop {r3,r4}  @ r3= orig_dst; r4= plen_dst
 110         sub src,srclim  @ 0 if actual src length equals expected length
 111         sub dst,r3  @ actual dst length
 112         str dst,[r4]
 113         pop {r4,r5,r6,r7 /*,pc*/}
 114         pop {r1}; bx r1  @ "pop {,pc}" fails return to ARM mode on ARMv4T
 115 #else
 116         mov  r0, #0
 117         bx   r0    /* Branch to 0x0, switch to ARM mode */
 118 #endif
 119
 120 get1_n2e:  @ In: Carry set [from adding 0x80000000 (1<<31) to itself]
 121           ldrb bits,[src]  @ zero-extend next byte
 122         adc bits,bits  @ double and insert CarryIn as low bit
 123           CHECK_SRC
 124           add src,#1
 125         lsl bits,#24  @ move to top byte, and set CarryOut from old bit 8
 126         mov pc,lr  @ return, stay in current (THUMB) mode
 127
 128 lit_n2e:
 129         CHECK_SRC; ldrb tmp,[src]; add src,#1
 130         CHECK_BYTE
 131         CHECK_DST; strb tmp,[dst]; add dst,#1
 132 top_n2e:
 133         jnextb1 lit_n2e
 134         mov cnt,#1; b getoff_n2e
 135
 136 off_n2e:
 137         sub cnt,#1
 138         getnextb(cnt)
 139 getoff_n2e:
 140         getnextb(cnt)
 141         jnextb0 off_n2e
 142
 143         sub tmp,cnt,#3  @ set Carry
 144         mov len,#0  @ Carry unaffected
 145         blo offprev_n2e  @ cnt was 2; tests Carry only
 146         lsl tmp,#8
 147         CHECK_SRC; ldrb off,[src]; add src,#1  @ low 7+1 bits
 148         orr  off,tmp
 149         mvn  off,off; beq eof_n2e  @ off= ~off
 150         asr  off,#1; bcs lenlast_n2e
 151         b lenmore_n2e
 152
 153 offprev_n2e:
 154         jnextb1 lenlast_n2e
 155 lenmore_n2e:
 156         mov len,#1
 157         jnextb1 lenlast_n2e
 158 len_n2e:
 159         getnextb(len)
 160         jnextb0 len_n2e
 161         add len,#6-2
 162         b gotlen_n2e
 163
 164 lenlast_n2e:
 165         getnextb(len)  @ 0,1,2,3
 166         add len,#2
 167 gotlen_n2e:  @ 'cmn': add the inputs, set condition codes, discard the sum
 168         cmn wrnk,off; bcs near_n2e  @ within M2_MAX_OFFSET
 169         add len,#1  @ too far away, so minimum match length is 3
 170 near_n2e:
 171 #if 1==SAFE  /*{*/
 172         ldr tmp,[sp,#sp_DST0]
 173         sub tmp,dst
 174         sub tmp,off; bhi bad_dst_n2e  @ reaching back too far
 175
 176         add tmp,dst,cnt
 177         cmp tmp,dstlim; bhi bad_dst_n2e  @ too much output
 178 #endif  /*}*/
 179         ldrb tmp,[dst]  @ force cacheline allocate
 180 copy_n2e:
 181         ldrb tmp,[dst,off]
 182         CHECK_BYTE
 183         strb tmp,[dst]; add dst,#1
 184         sub len,#1; bne copy_n2e
 185         b top_n2e
 186
 187 #ifndef PURE_THUMB
 188         .size ucl_nrv2e_decompress_8, .-ucl_nrv2e_decompress_8
 189 #endif
 190
 191 /*
 192 vi:ts=8:et:nowrap
 193  */
 194