utils/themeeditor/themeeditor.pro

   1 #Setting the binary name
   2 TARGET = rbthemeeditor
   3 VERSION = 0.5
   4
   5 CONFIG(debug){
   6     REVISION = $$system(svnversion)
   7     VERSION=$$join(VERSION,,,r)
   8     VERSION=$$join(VERSION,,,$$REVISION)
   9 }
  10
  11 # Adding network support
  12 QT += network
  13
  14 # Enabling profiling
  15 QMAKE_CXXFLAGS_DEBUG += -pg
  16 QMAKE_LFLAGS_DEBUG += -pg
  17
  18 # Adding zlib dependency for QuaZip
  19 LIBS += -lz
  20 INCLUDEPATH += zlib
  21
  22 # build in a separate folder.
  23 MYBUILDDIR = $$OUT_PWD/build/
  24 OBJECTS_DIR = $$MYBUILDDIR/o
  25 UI_DIR = $$MYBUILDDIR/ui
  26 MOC_DIR = $$MYBUILDDIR/moc
  27 RCC_DIR = $$MYBUILDDIR/rcc
  28 RBBASE_DIR = $$_PRO_FILE_PWD_
  29 RBBASE_DIR = $$replace(RBBASE_DIR,/utils/themeeditor,)
  30
  31 # Include directories
  32 INCLUDEPATH += gui
  33 INCLUDEPATH += models
  34 INCLUDEPATH += graphics
  35 INCLUDEPATH += quazip
  36 INCLUDEPATH += qtfindreplacedialog
  37 DEFINES += FINDREPLACE_NOLIB
  38 cross {
  39     message("Crossbuilding for W32 binary")
  40
  41     # retrieve ar binary for w32 cross compile. This might be specific to
  42     # Fedora mingw32 packages of Qt. Using member() here is needed because at
  43     # least the F13 packages add ar options to the variable.
  44     CROSSOPTIONS += AR=$$member(QMAKE_LIB)
  45
  46     # make sure we use the correct subsystem to prevent a console window coming up.
  47     LIBS += -Wl,-subsystem,windows
  48 }
  49
  50 # Stuff for the parse lib
  51 libskin_parser.commands = @$(MAKE) \
  52     TARGET_DIR=$$MYBUILDDIR \
  53     CC=\"$$QMAKE_CC\" \
  54     $$CROSSOPTIONS \
  55     BUILDDIR=$$OBJECTS_DIR \
  56     -C \
  57     $$RBBASE_DIR/lib/skin_parser \
  58     libskin_parser.a
  59 QMAKE_EXTRA_TARGETS += libskin_parser
  60 PRE_TARGETDEPS += libskin_parser
  61 INCLUDEPATH += $$RBBASE_DIR/lib/skin_parser
  62 LIBS += -L$$MYBUILDDIR \
  63     -lskin_parser
  64 DEPENDPATH = $$INCLUDEPATH
  65 HEADERS += models/parsetreemodel.h \
  66     models/parsetreenode.h \
  67     gui/editorwindow.h \
  68     gui/skinhighlighter.h \
  69     gui/skindocument.h \
  70     gui/preferencesdialog.h \
  71     gui/codeeditor.h \
  72     models/projectmodel.h \
  73     gui/tabcontent.h \
  74     gui/configdocument.h \
  75     gui/skinviewer.h \
  76     graphics/rbscreen.h \
  77     graphics/rbviewport.h \
  78     graphics/rbrenderinfo.h \
  79     graphics/rbimage.h \
  80     graphics/rbfont.h \
  81     gui/devicestate.h \
  82     graphics/rbalbumart.h \
  83     graphics/rbprogressbar.h \
  84     graphics/rbtext.h \
  85     graphics/rbfontcache.h \
  86     graphics/rbtextcache.h \
  87     gui/skintimer.h \
  88     graphics/rbtoucharea.h \
  89     gui/newprojectdialog.h \
  90     models/targetdata.h \
  91     quazip/zip.h \
  92     quazip/unzip.h \
  93     quazip/quazipnewinfo.h \
  94     quazip/quazipfileinfo.h \
  95     quazip/quazipfile.h \
  96     quazip/quazip.h \
  97     quazip/ioapi.h \
  98     quazip/crypt.h \
  99     zlib/zlib.h \
 100     zlib/zconf.h \
 101     gui/fontdownloader.h \
 102     qtfindreplacedialog/varianteditor.h \
 103     qtfindreplacedialog/findreplace_global.h \
 104     qtfindreplacedialog/findreplaceform.h \
 105     qtfindreplacedialog/findreplacedialog.h \
 106     qtfindreplacedialog/findform.h \
 107     qtfindreplacedialog/finddialog.h \
 108     gui/projectexporter.h \
 109     gui/targetdownloader.h
 110 SOURCES += main.cpp \
 111     models/parsetreemodel.cpp \
 112     models/parsetreenode.cpp \
 113     gui/editorwindow.cpp \
 114     gui/skinhighlighter.cpp \
 115     gui/skindocument.cpp \
 116     gui/preferencesdialog.cpp \
 117     gui/codeeditor.cpp \
 118     models/projectmodel.cpp \
 119     gui/configdocument.cpp \
 120     gui/skinviewer.cpp \
 121     graphics/rbscreen.cpp \
 122     graphics/rbviewport.cpp \
 123     graphics/rbrenderinfo.cpp \
 124     graphics/rbimage.cpp \
 125     graphics/rbfont.cpp \
 126     gui/devicestate.cpp \
 127     graphics/rbalbumart.cpp \
 128     graphics/rbprogressbar.cpp \
 129     graphics/rbtext.cpp \
 130     graphics/rbfontcache.cpp \
 131     graphics/rbtextcache.cpp \
 132     gui/skintimer.cpp \
 133     graphics/rbtoucharea.cpp \
 134     gui/newprojectdialog.cpp \
 135     models/targetdata.cpp \
 136     quazip/zip.c \
 137     quazip/unzip.c \
 138     quazip/quazipnewinfo.cpp \
 139     quazip/quazipfile.cpp \
 140     quazip/quazip.cpp \
 141     quazip/ioapi.c \
 142     gui/fontdownloader.cpp \
 143     qtfindreplacedialog/varianteditor.cpp \
 144     qtfindreplacedialog/findreplaceform.cpp \
 145     qtfindreplacedialog/findreplacedialog.cpp \
 146     qtfindreplacedialog/findform.cpp \
 147     qtfindreplacedialog/finddialog.cpp \
 148     gui/projectexporter.cpp \
 149     gui/targetdownloader.cpp
 150 OTHER_FILES += README \
 151     resources/windowicon.png \
 152     resources/appicon.xcf \
 153     resources/COPYING \
 154     resources/document-save.png \
 155     resources/document-open.png \
 156     resources/document-new.png \
 157     resources/deviceoptions \
 158     resources/render/statusbar.png \
 159     resources/render/scenebg.png \
 160     resources/play.xcf \
 161     resources/play.png \
 162     resources/rwnd.png \
 163     resources/pause.xcf \
 164     resources/pause.png \
 165     resources/ffwd.xcf \
 166     resources/ffwd.png \
 167     resources/lines.xcf \
 168     resources/lines.png \
 169     resources/cursor.xcf \
 170     resources/cursor.png \
 171     resources/targetdb \
 172     quazip/README.ROCKBOX \
 173     quazip/LICENSE.GPL \
 174     qtfindreplacedialog/dialogs.pro
 175 FORMS += gui/editorwindow.ui \
 176     gui/preferencesdialog.ui \
 177     gui/configdocument.ui \
 178     gui/skinviewer.ui \
 179     gui/skintimer.ui \
 180     gui/newprojectdialog.ui \
 181     gui/fontdownloader.ui \
 182     qtfindreplacedialog/findreplaceform.ui \
 183     qtfindreplacedialog/findreplacedialog.ui \
 184     gui/projectexporter.ui \
 185     gui/targetdownloader.ui
 186 RESOURCES += resources.qrc
 187 win32:RC_FILE = themeeditor.rc
 188 macx {
 189     QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.4u.sdk
 190     QMAKE_LFLAGS_PPC = -mmacosx-version-min=10.4 \
 191         -arch \
 192         ppc
 193     QMAKE_LFLAGS_X86 = -mmacosx-version-min=10.4 \
 194         -arch \
 195         i386
 196     CONFIG += x86 \
 197         ppc
 198     QMAKE_INFO_PLIST = Info.plist
 199     RC_FILE = resources/windowicon.icns
 200 }