rbutil/rbutilqt/rbutilqt.pro

   1
   2 # ccache
   3 unix:!mac:!noccache {
   4     CCACHE = $$system(which ccache)
   5     !isEmpty(CCACHE) {
   6         message("using ccache")
   7         QMAKE_CXX = ccache g++
   8         QMAKE_CC = ccache gcc
   9     }
  10 }
  11
  12 MYBUILDDIR = $$OUT_PWD/build/
  13 OBJECTS_DIR = $$MYBUILDDIR/o
  14 UI_DIR = $$MYBUILDDIR/ui
  15 MOC_DIR = $$MYBUILDDIR/moc
  16 RCC_DIR = $$MYBUILDDIR/rcc
  17
  18
  19 # check version of Qt installation
  20 VER = $$find(QT_VERSION, ^4\.[3-9]+.*)
  21 isEmpty(VER) {
  22     !isEmpty(QT_VERSION) error("Qt found:" $$[QT_VERSION])
  23     error("Qt >= 4.3 required!")
  24 }
  25 message("Qt version used:" $$VER)
  26
  27 RBBASE_DIR = $$_PRO_FILE_PWD_
  28 RBBASE_DIR = $$replace(RBBASE_DIR,/rbutil/rbutilqt,)
  29
  30 message("Rockbox Base dir: "$$RBBASE_DIR)
  31
  32 # check for system speex. Add a custom rule for pre-building librbspeex if not found.
  33 LIBSPEEX = $$system(pkg-config --silence-errors --libs speex)
  34 !static:!isEmpty(LIBSPEEX) {
  35     # newer versions of speex are split up into libspeex and libspeexdsp.
  36     # avoid checking twice if libspeex is missing.
  37     LIBSPEEX += $$system(pkg-config --silence-errors --libs speexdsp)
  38     LIBS += $$LIBSPEEX
  39 }
  40 # custom rules for rockbox-specific libs
  41 !mac {
  42     RBLIBPOSTFIX = .a
  43 }
  44 mac {
  45     RBLIBPOSTFIX = -universal
  46 }
  47 rbspeex.commands = @$(MAKE) TARGET_DIR=$$MYBUILDDIR -C $$RBBASE_DIR/tools/rbspeex librbspeex$$RBLIBPOSTFIX CC=\"$$QMAKE_CC\"
  48 libucl.commands = @$(MAKE) TARGET_DIR=$$MYBUILDDIR -C $$RBBASE_DIR/tools/ucl/src libucl$$RBLIBPOSTFIX CC=\"$$QMAKE_CC\"
  49 libmkamsboot.commands = @$(MAKE) TARGET_DIR=$$MYBUILDDIR -C $$RBBASE_DIR/rbutil/mkamsboot libmkamsboot$$RBLIBPOSTFIX CC=\"$$QMAKE_CC\"
  50 libmktccboot.commands = @$(MAKE) TARGET_DIR=$$MYBUILDDIR -C $$RBBASE_DIR/rbutil/mktccboot libmktccboot$$RBLIBPOSTFIX CC=\"$$QMAKE_CC\"
  51 QMAKE_EXTRA_TARGETS += rbspeex libucl libmkamsboot libmktccboot
  52 PRE_TARGETDEPS += rbspeex libucl libmkamsboot libmktccboot
  53
  54 # rule for creating ctags file
  55 tags.commands = ctags -R --c++-kinds=+p --fields=+iaS --extra=+q $(SOURCES)
  56 tags.depends = $(SOURCES)
  57 QMAKE_EXTRA_TARGETS += tags
  58
  59 # add a custom rule for making the translations
  60 lrelease.commands = $$[QT_INSTALL_BINS]/lrelease -silent $$_PRO_FILE_
  61 QMAKE_EXTRA_TARGETS += lrelease
  62 !dbg {
  63     PRE_TARGETDEPS += lrelease
  64 }
  65
  66 SOURCES += rbutilqt.cpp \
  67  main.cpp \
  68  install.cpp \
  69  base/httpget.cpp \
  70  configure.cpp \
  71  zip/zip.cpp \
  72  zip/unzip.cpp \
  73  base/zipinstaller.cpp \
  74  progressloggergui.cpp \
  75  installtalkwindow.cpp \
  76  base/talkfile.cpp \
  77  base/talkgenerator.cpp \
  78  base/autodetection.cpp \
  79  ../ipodpatcher/ipodpatcher.c \
  80  ../sansapatcher/sansapatcher.c \
  81  ../chinachippatcher/chinachip.c \
  82  browsedirtree.cpp \
  83  themesinstallwindow.cpp \
  84  base/uninstall.cpp \
  85  uninstallwindow.cpp \
  86  base/utils.cpp \
  87  preview.cpp \
  88  base/encoders.cpp \
  89  encttscfggui.cpp \
  90  base/encttssettings.cpp \
  91  base/ttsbase.cpp \
  92  base/ttsexes.cpp \
  93  base/ttssapi.cpp \
  94  base/ttsfestival.cpp \
  95  ../../tools/wavtrim.c \
  96  ../../tools/voicefont.c \
  97  base/voicefile.cpp \
  98  createvoicewindow.cpp \
  99  base/rbsettings.cpp \
 100  base/rbunzip.cpp \
 101  base/rbzip.cpp \
 102  base/system.cpp \
 103  sysinfo.cpp \
 104  systrace.cpp \
 105  base/bootloaderinstallbase.cpp \
 106  base/bootloaderinstallmi4.cpp \
 107  base/bootloaderinstallhex.cpp \
 108  base/bootloaderinstallipod.cpp \
 109  base/bootloaderinstallsansa.cpp \
 110  base/bootloaderinstallfile.cpp \
 111  base/bootloaderinstallchinachip.cpp \
 112  base/bootloaderinstallams.cpp \
 113  base/bootloaderinstalltcc.cpp \
 114  ../../tools/mkboot.c \
 115  ../../tools/iriver.c \
 116
 117 HEADERS += rbutilqt.h \
 118  install.h \
 119  base/httpget.h \
 120  configure.h \
 121  zip/zip.h \
 122  zip/unzip.h \
 123  zip/zipentry_p.h \
 124  zip/unzip_p.h \
 125  zip/zip_p.h \
 126  version.h \
 127  base/zipinstaller.h \
 128  installtalkwindow.h \
 129  base/talkfile.h \
 130  base/talkgenerator.h \
 131  base/autodetection.h \
 132  base/progressloggerinterface.h \
 133  progressloggergui.h \
 134  ../ipodpatcher/ipodpatcher.h \
 135  ../ipodpatcher/ipodio.h \
 136  ../ipodpatcher/parttypes.h \
 137  ../sansapatcher/sansapatcher.h \
 138  ../sansapatcher/sansaio.h \
 139  ../chinachippatcher/chinachip.h \
 140  irivertools/h100sums.h \
 141  irivertools/h120sums.h \
 142  irivertools/h300sums.h \
 143  browsedirtree.h \
 144  themesinstallwindow.h \
 145  base/uninstall.h \
 146  uninstallwindow.h \
 147  base/utils.h \
 148  preview.h \
 149  base/encoders.h \
 150  encttscfggui.h \
 151  base/encttssettings.h \
 152  base/ttsbase.h \
 153  base/ttsexes.h \
 154  base/ttsfestival.h \
 155  base/ttssapi.h \
 156  ../../tools/wavtrim.h \
 157  ../../tools/voicefont.h \
 158  base/voicefile.h \
 159  createvoicewindow.h \
 160  base/rbsettings.h \
 161  base/rbunzip.h \
 162  base/rbzip.h \
 163  sysinfo.h \
 164  base/system.h \
 165  systrace.h \
 166  base/bootloaderinstallbase.h \
 167  base/bootloaderinstallmi4.h \
 168  base/bootloaderinstallhex.h \
 169  base/bootloaderinstallipod.h \
 170  base/bootloaderinstallsansa.h \
 171  base/bootloaderinstallfile.h \
 172  base/bootloaderinstallchinachip.h \
 173  base/bootloaderinstallams.h \
 174  base/bootloaderinstalltcc.h \
 175  ../../tools/mkboot.h \
 176  ../../tools/iriver.h \
 177
 178 # Needed by QT on Win
 179 INCLUDEPATH = $$_PRO_FILE_PWD_ $$_PRO_FILE_PWD_/irivertools $$_PRO_FILE_PWD_/zip $$_PRO_FILE_PWD_/zlib $$_PRO_FILE_PWD_/base
 180 INCLUDEPATH += $$RBBASE_DIR/rbutil/ipodpatcher $$RBBASE_DIR/rbutil/sansapatcher $$RBBASE_DIR/tools/rbspeex $$RBBASE_DIR/tools
 181
 182 DEPENDPATH = $$INCLUDEPATH
 183
 184 LIBS += -L$$OUT_PWD -L$$MYBUILDDIR -lrbspeex -lmkamsboot -lmktccboot -lucl
 185
 186 TEMPLATE = app
 187 dbg {
 188     CONFIG += debug thread qt warn_on
 189     DEFINES -= QT_NO_DEBUG_OUTPUT
 190     message("debug")
 191 }
 192 !dbg {
 193     CONFIG += release thread qt
 194     DEFINES -= QT_NO_DEBUG_OUTPUT
 195     DEFINES += NODEBUG
 196     message("release")
 197 }
 198
 199 TARGET = rbutilqt
 200
 201 FORMS += rbutilqtfrm.ui \
 202  aboutbox.ui \
 203  installfrm.ui \
 204  progressloggerfrm.ui \
 205  configurefrm.ui \
 206  browsedirtreefrm.ui \
 207  installtalkfrm.ui \
 208  themesinstallfrm.ui \
 209  uninstallfrm.ui \
 210  previewfrm.ui \
 211  createvoicefrm.ui \
 212  sysinfofrm.ui \
 213  systracefrm.ui
 214
 215 RESOURCES += $$_PRO_FILE_PWD_/rbutilqt.qrc
 216 win32 {
 217     RESOURCES += $$_PRO_FILE_PWD_/rbutilqt-win.qrc
 218 }
 219 !dbg {
 220     RESOURCES += $$_PRO_FILE_PWD_/rbutilqt-lang.qrc
 221 }
 222
 223 TRANSLATIONS += lang/rbutil_cs.ts \
 224  lang/rbutil_de.ts \
 225  lang/rbutil_fi.ts \
 226  lang/rbutil_fr.ts \
 227  lang/rbutil_gr.ts \
 228  lang/rbutil_he.ts \
 229  lang/rbutil_ja.ts \
 230  lang/rbutil_nl.ts \
 231  lang/rbutil_pt.ts \
 232  lang/rbutil_pt_BR.ts \
 233  lang/rbutil_tr.ts \
 234  lang/rbutil_zh_CN.ts \
 235  lang/rbutil_zh_TW.ts \
 236
 237
 238 QT += network
 239 DEFINES += RBUTIL _LARGEFILE64_SOURCE
 240
 241 win32 {
 242     SOURCES +=  ../ipodpatcher/ipodio-win32.c
 243     SOURCES +=  ../ipodpatcher/ipodio-win32-scsi.c
 244     SOURCES +=  ../sansapatcher/sansaio-win32.c
 245     RC_FILE = rbutilqt.rc
 246     LIBS += -lsetupapi -lnetapi32
 247 }
 248
 249 unix {
 250     SOURCES +=  ../ipodpatcher/ipodio-posix.c
 251     SOURCES +=  ../sansapatcher/sansaio-posix.c
 252 }
 253 unix:!static:!libusb1 {
 254     LIBS += -lusb
 255 }
 256 unix:!static:libusb1 {
 257     DEFINES += LIBUSB1
 258     LIBS += -lusb-1.0
 259 }
 260
 261 unix:static {
 262     # force statically linking of libusb. Libraries that are appended
 263     # later will get linked dynamically again.
 264     LIBS += -Wl,-Bstatic -lusb -Wl,-Bdynamic
 265 }
 266
 267 macx {
 268     QMAKE_MAC_SDK=/Developer/SDKs/MacOSX10.4u.sdk
 269     QMAKE_LFLAGS_PPC=-mmacosx-version-min=10.4 -arch ppc
 270     QMAKE_LFLAGS_X86=-mmacosx-version-min=10.4 -arch i386
 271     CONFIG+=x86 ppc
 272     LIBS += -L/usr/local/lib -framework IOKit -lz
 273     INCLUDEPATH += /usr/local/include
 274     QMAKE_INFO_PLIST = Info.plist
 275     RC_FILE = icons/rbutilqt.icns
 276
 277     # rule for creating a dmg file
 278     dmg.commands = hdiutil create -ov -srcfolder rbutilqt.app/ rbutil.dmg
 279     QMAKE_EXTRA_TARGETS += dmg
 280 }
 281
 282 static {
 283     QTPLUGIN += qtaccessiblewidgets
 284     LIBS += -L$$(QT_BUILD_TREE)/plugins/accessible -lqtaccessiblewidgets
 285     LIBS += -L.
 286     DEFINES += STATIC
 287     message("using static plugin")
 288 }
 289
 290 unix {
 291     target.path = /usr/local/bin
 292     INSTALLS += target
 293 }
 294
 295
 296