utils/themeeditor/themeeditor.pro

   1 #Setting the binary name
   2 TARGET = rbthemeeditor
   3
   4 # Adding network support
   5 QT += network
   6
   7 # Enabling profiling
   8 QMAKE_CXXFLAGS_DEBUG += -pg
   9 QMAKE_LFLAGS_DEBUG += -pg
  10
  11 # Adding zlib dependency for QuaZip
  12 LIBS += -lz
  13 INCLUDEPATH += zlib
  14
  15 # build in a separate folder.
  16 MYBUILDDIR = $$OUT_PWD/build/
  17 OBJECTS_DIR = $$MYBUILDDIR/o
  18 UI_DIR = $$MYBUILDDIR/ui
  19 MOC_DIR = $$MYBUILDDIR/moc
  20 RCC_DIR = $$MYBUILDDIR/rcc
  21 RBBASE_DIR = $$_PRO_FILE_PWD_
  22 RBBASE_DIR = $$replace(RBBASE_DIR,/utils/themeeditor,)
  23
  24 # Include directories
  25 INCLUDEPATH += gui
  26 INCLUDEPATH += models
  27 INCLUDEPATH += graphics
  28 INCLUDEPATH += quazip
  29 INCLUDEPATH += qtfindreplacedialog
  30 DEFINES += FINDREPLACE_NOLIB
  31 cross {
  32     message("Crossbuilding for W32 binary")
  33
  34     # retrieve ar binary for w32 cross compile. This might be specific to
  35     # Fedora mingw32 packages of Qt. Using member() here is needed because at
  36     # least the F13 packages add ar options to the variable.
  37     CROSSOPTIONS += AR=$$member(QMAKE_LIB)
  38
  39     # make sure we use the correct subsystem to prevent a console window coming up.
  40     LIBS += -Wl,-subsystem,windows
  41 }
  42
  43 # Stuff for the parse lib
  44 libskin_parser.commands = @$(MAKE) \
  45     TARGET_DIR=$$MYBUILDDIR \
  46     CC=\"$$QMAKE_CC\" \
  47     $$CROSSOPTIONS \
  48     BUILDDIR=$$OBJECTS_DIR \
  49     -C \
  50     $$RBBASE_DIR/lib/skin_parser \
  51     libskin_parser.a
  52 QMAKE_EXTRA_TARGETS += libskin_parser
  53 PRE_TARGETDEPS += libskin_parser
  54 INCLUDEPATH += $$RBBASE_DIR/lib/skin_parser
  55 LIBS += -L$$MYBUILDDIR \
  56     -lskin_parser
  57 DEPENDPATH = $$INCLUDEPATH
  58 HEADERS += models/parsetreemodel.h \
  59     models/parsetreenode.h \
  60     gui/editorwindow.h \
  61     gui/skinhighlighter.h \
  62     gui/skindocument.h \
  63     gui/preferencesdialog.h \
  64     gui/codeeditor.h \
  65     models/projectmodel.h \
  66     gui/tabcontent.h \
  67     gui/configdocument.h \
  68     gui/skinviewer.h \
  69     graphics/rbscreen.h \
  70     graphics/rbviewport.h \
  71     graphics/rbrenderinfo.h \
  72     graphics/rbimage.h \
  73     graphics/rbfont.h \
  74     gui/devicestate.h \
  75     graphics/rbalbumart.h \
  76     graphics/rbprogressbar.h \
  77     graphics/rbtext.h \
  78     graphics/rbfontcache.h \
  79     graphics/rbtextcache.h \
  80     gui/skintimer.h \
  81     graphics/rbtoucharea.h \
  82     gui/newprojectdialog.h \
  83     models/targetdata.h \
  84     quazip/zip.h \
  85     quazip/unzip.h \
  86     quazip/quazipnewinfo.h \
  87     quazip/quazipfileinfo.h \
  88     quazip/quazipfile.h \
  89     quazip/quazip.h \
  90     quazip/ioapi.h \
  91     quazip/crypt.h \
  92     zlib/zlib.h \
  93     zlib/zconf.h \
  94     gui/fontdownloader.h \
  95     qtfindreplacedialog/varianteditor.h \
  96     qtfindreplacedialog/findreplace_global.h \
  97     qtfindreplacedialog/findreplaceform.h \
  98     qtfindreplacedialog/findreplacedialog.h \
  99     qtfindreplacedialog/findform.h \
 100     qtfindreplacedialog/finddialog.h \
 101     gui/projectexporter.h \
 102     gui/targetdownloader.h
 103 SOURCES += main.cpp \
 104     models/parsetreemodel.cpp \
 105     models/parsetreenode.cpp \
 106     gui/editorwindow.cpp \
 107     gui/skinhighlighter.cpp \
 108     gui/skindocument.cpp \
 109     gui/preferencesdialog.cpp \
 110     gui/codeeditor.cpp \
 111     models/projectmodel.cpp \
 112     gui/configdocument.cpp \
 113     gui/skinviewer.cpp \
 114     graphics/rbscreen.cpp \
 115     graphics/rbviewport.cpp \
 116     graphics/rbrenderinfo.cpp \
 117     graphics/rbimage.cpp \
 118     graphics/rbfont.cpp \
 119     gui/devicestate.cpp \
 120     graphics/rbalbumart.cpp \
 121     graphics/rbprogressbar.cpp \
 122     graphics/rbtext.cpp \
 123     graphics/rbfontcache.cpp \
 124     graphics/rbtextcache.cpp \
 125     gui/skintimer.cpp \
 126     graphics/rbtoucharea.cpp \
 127     gui/newprojectdialog.cpp \
 128     models/targetdata.cpp \
 129     quazip/zip.c \
 130     quazip/unzip.c \
 131     quazip/quazipnewinfo.cpp \
 132     quazip/quazipfile.cpp \
 133     quazip/quazip.cpp \
 134     quazip/ioapi.c \
 135     gui/fontdownloader.cpp \
 136     qtfindreplacedialog/varianteditor.cpp \
 137     qtfindreplacedialog/findreplaceform.cpp \
 138     qtfindreplacedialog/findreplacedialog.cpp \
 139     qtfindreplacedialog/findform.cpp \
 140     qtfindreplacedialog/finddialog.cpp \
 141     gui/projectexporter.cpp \
 142     gui/targetdownloader.cpp
 143 OTHER_FILES += README \
 144     resources/windowicon.png \
 145     resources/appicon.xcf \
 146     resources/COPYING \
 147     resources/document-save.png \
 148     resources/document-open.png \
 149     resources/document-new.png \
 150     resources/deviceoptions \
 151     resources/render/statusbar.png \
 152     resources/render/scenebg.png \
 153     resources/play.xcf \
 154     resources/play.png \
 155     resources/rwnd.png \
 156     resources/pause.xcf \
 157     resources/pause.png \
 158     resources/ffwd.xcf \
 159     resources/ffwd.png \
 160     resources/lines.xcf \
 161     resources/lines.png \
 162     resources/cursor.xcf \
 163     resources/cursor.png \
 164     resources/targetdb \
 165     quazip/README.ROCKBOX \
 166     quazip/LICENSE.GPL \
 167     qtfindreplacedialog/dialogs.pro
 168 FORMS += gui/editorwindow.ui \
 169     gui/preferencesdialog.ui \
 170     gui/configdocument.ui \
 171     gui/skinviewer.ui \
 172     gui/skintimer.ui \
 173     gui/newprojectdialog.ui \
 174     gui/fontdownloader.ui \
 175     qtfindreplacedialog/findreplaceform.ui \
 176     qtfindreplacedialog/findreplacedialog.ui \
 177     gui/projectexporter.ui \
 178     gui/targetdownloader.ui
 179 RESOURCES += resources.qrc
 180 win32:RC_FILE = themeeditor.rc
 181 macx {
 182     QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.4u.sdk
 183     QMAKE_LFLAGS_PPC = -mmacosx-version-min=10.4 \
 184         -arch \
 185         ppc
 186     QMAKE_LFLAGS_X86 = -mmacosx-version-min=10.4 \
 187         -arch \
 188         i386
 189     CONFIG += x86 \
 190         ppc
 191     QMAKE_INFO_PLIST = Info.plist
 192     RC_FILE = resources/windowicon.icns
 193 }