rbutil/rbutilqt/rbutilqt.pro

   1 unix:!mac {
   2     CCACHE = $$system(which ccache)
   3     !isEmpty(CCACHE) {
   4         message("using ccache")
   5         QMAKE_CXX = ccache g++
   6         QMAKE_CC = ccache gcc
   7     }
   8 }
   9
  10 OBJECTS_DIR = build/o
  11 UI_DIR = build/ui
  12 MOC_DIR = build/moc
  13 RCC_DIR = build/rcc
  14
  15 # add a custom rule for pre-building librbspeex
  16 !mac {
  17 rbspeex.commands = @$(MAKE) -C ../../tools/rbspeex librbspeex.a
  18 }
  19 mac {
  20 rbspeex.commands = @$(MAKE) -C ../../tools/rbspeex librbspeex-universal
  21 }
  22 QMAKE_EXTRA_TARGETS += rbspeex
  23 PRE_TARGETDEPS += rbspeex
  24
  25 # rule for creating ctags file
  26 tags.commands = ctags -R --c++-kinds=+p --fields=+iaS --extra=+q $(SOURCES)
  27 tags.depends = $(SOURCES)
  28 QMAKE_EXTRA_TARGETS += tags
  29
  30 # add a custom rule for making the translations
  31 lrelease.commands = $$[QT_INSTALL_BINS]/lrelease -silent rbutilqt.pro
  32 QMAKE_EXTRA_TARGETS += lrelease
  33 !dbg {
  34     PRE_TARGETDEPS += lrelease
  35 }
  36
  37
  38 SOURCES += rbutilqt.cpp \
  39            main.cpp \
  40  install.cpp \
  41  httpget.cpp \
  42  configure.cpp \
  43  zip/zip.cpp \
  44  zip/unzip.cpp \
  45  installzip.cpp \
  46  installbootloader.cpp \
  47  progressloggergui.cpp \
  48  installtalkwindow.cpp \
  49  talkfile.cpp \
  50  autodetection.cpp \
  51  ../ipodpatcher/ipodpatcher.c \
  52  ../sansapatcher/sansapatcher.c \
  53  irivertools/irivertools.cpp \
  54  irivertools/md5sum.cpp  \
  55  browsedirtree.cpp \
  56  installthemes.cpp \
  57  uninstall.cpp \
  58  uninstallwindow.cpp \
  59  utils.cpp \
  60  browseof.cpp \
  61  preview.cpp \
  62  encoders.cpp \
  63  encodersgui.cpp \
  64  tts.cpp \
  65  ttsgui.cpp \
  66  ../../tools/wavtrim.c \
  67  ../../tools/voicefont.c \
  68  voicefile.cpp \
  69  createvoicewindow.cpp \
  70  rbsettings.cpp \
  71  rbunzip.cpp \
  72  rbzip.cpp \
  73  sysinfo.cpp \
  74  detect.cpp
  75
  76 HEADERS += rbutilqt.h \
  77  install.h \
  78  httpget.h \
  79  configure.h \
  80  zip/zip.h \
  81  zip/unzip.h \
  82  zip/zipentry_p.h \
  83  zip/unzip_p.h \
  84  zip/zip_p.h \
  85  version.h \
  86  installzip.h \
  87  installbootloader.h \
  88  installtalkwindow.h \
  89  talkfile.h \
  90  autodetection.h \
  91  progressloggerinterface.h \
  92  progressloggergui.h \
  93  ../ipodpatcher/ipodpatcher.h \
  94  ../ipodpatcher/ipodio.h \
  95  ../ipodpatcher/parttypes.h \
  96  ../sansapatcher/sansapatcher.h \
  97  ../sansapatcher/sansaio.h \
  98  irivertools/irivertools.h \
  99  irivertools/md5sum.h \
 100  irivertools/h100sums.h \
 101  irivertools/h120sums.h \
 102  irivertools/h300sums.h \
 103  irivertools/checksums.h \
 104  browsedirtree.h \
 105  installthemes.h \
 106  uninstall.h \
 107  uninstallwindow.h \
 108  utils.h \
 109  browseof.h \
 110  preview.h \
 111  encoders.h \
 112  encodersgui.h \
 113  tts.h \
 114  ttsgui.h \
 115  ../../tools/wavtrim.h \
 116  ../../tools/voicefont.h \
 117  voicefile.h \
 118  createvoicewindow.h \
 119  rbsettings.h \
 120  rbunzip.h \
 121  rbzip.h \
 122  sysinfo.h \
 123  detect.h
 124
 125 # Needed by QT on Win
 126 INCLUDEPATH = . irivertools zip zlib ../ipodpatcher ../sansapatcher ../../tools/rbspeex ../../tools
 127
 128 LIBS += -L../../tools/rbspeex -lrbspeex
 129
 130 TEMPLATE = app
 131 dbg {
 132     CONFIG += debug thread qt warn_on
 133     DEFINES -= QT_NO_DEBUG_OUTPUT
 134     message("debug")
 135 }
 136 !dbg {
 137     CONFIG += release thread qt
 138     DEFINES += QT_NO_DEBUG_OUTPUT
 139     message("release")
 140 }
 141
 142 TARGET = rbutilqt
 143
 144 FORMS += rbutilqtfrm.ui \
 145  aboutbox.ui \
 146  installfrm.ui \
 147  progressloggerfrm.ui \
 148  configurefrm.ui \
 149  browsedirtreefrm.ui \
 150  installtalkfrm.ui \
 151  installthemesfrm.ui \
 152  uninstallfrm.ui \
 153  browseoffrm.ui \
 154  previewfrm.ui \
 155  rbspeexcfgfrm.ui \
 156  encexescfgfrm.ui \
 157  ttsexescfgfrm.ui \
 158  sapicfgfrm.ui \
 159  createvoicefrm.ui \
 160  sysinfofrm.ui
 161
 162 RESOURCES += rbutilqt.qrc
 163 win32 {
 164     RESOURCES += rbutilqt-win.qrc
 165 }
 166 !dbg {
 167     RESOURCES += rbutilqt-lang.qrc
 168 }
 169
 170 TRANSLATIONS += rbutil_de.ts \
 171  rbutil_fi.ts \
 172  rbutil_fr.ts \
 173  rbutil_nl.ts \
 174  rbutil_tr.ts \
 175  rbutil_zh_CN.ts \
 176  rbutil_zh_TW.ts
 177 QT += network
 178 DEFINES += RBUTIL _LARGEFILE64_SOURCE
 179
 180 win32 {
 181     SOURCES +=  ../ipodpatcher/ipodio-win32.c
 182     SOURCES +=  ../sansapatcher/sansaio-win32.c
 183     RC_FILE = rbutilqt.rc
 184     LIBS += -lsetupapi -lnetapi32
 185 }
 186
 187 unix {
 188     SOURCES +=  ../ipodpatcher/ipodio-posix.c
 189     SOURCES +=  ../sansapatcher/sansaio-posix.c
 190 }
 191 unix:!static {
 192     LIBS += -lusb
 193 }
 194 unix:static {
 195     # force statically linking of libusb. Libraries that are appended
 196     # later will get linked dynamically again.
 197     LIBS += -Wl,-Bstatic -lusb -Wl,-Bdynamic
 198 }
 199
 200 macx {
 201     QMAKE_MAC_SDK=/Developer/SDKs/MacOSX10.4u.sdk
 202     QMAKE_LFLAGS_PPC=-mmacosx-version-min=10.4 -arch ppc
 203     QMAKE_LFLAGS_X86=-mmacosx-version-min=10.4 -arch i386
 204     CONFIG+=x86 ppc
 205     LIBS += -L/usr/local/lib -framework IOKit
 206     INCLUDEPATH += /usr/local/include
 207     QMAKE_INFO_PLIST = Info.plist
 208     RC_FILE = icons/rbutilqt.icns
 209
 210     # rule for creating a dmg file
 211     dmg.commands = hdiutil create -ov -srcfolder rbutilqt.app/ rbutil.dmg
 212     QMAKE_EXTRA_TARGETS += dmg
 213 }
 214
 215 static {
 216     QTPLUGIN += qtaccessiblewidgets
 217     LIBS += -L$$(QT_BUILD_TREE)/plugins/accessible -lqtaccessiblewidgets
 218     LIBS += -L.
 219     DEFINES += STATIC
 220     message("using static plugin")
 221 }
 222
 223 unix {
 224     target.path = /usr/local/bin
 225     INSTALLS += target
 226 }
 227