krdc/CMakeLists.txt

   1 project(krdc)
   2
   3 add_subdirectory(config)
   4
   5 include_directories(
   6     ${CMAKE_CURRENT_SOURCE_DIR}/rdp/
   7     ${CMAKE_CURRENT_SOURCE_DIR}/vnc/
   8     ${CMAKE_CURRENT_SOURCE_DIR}/nx/
   9     ${CMAKE_CURRENT_SOURCE_DIR}/zeroconf/
  10     ${CMAKE_CURRENT_SOURCE_DIR}/test/
  11 )
  12
  13 if(Q_WS_X11)
  14     set(HAVE_RDESKTOP true) # TODO: implement cmake check?
  15 endif(Q_WS_X11)
  16
  17 if(HAVE_RDESKTOP)
  18     add_definitions(-DBUILD_RDP)
  19     set(krdc_rdp_SRCS
  20         rdp/rdphostpreferences.cpp
  21         rdp/rdpview.cpp
  22     )
  23
  24     kde4_add_ui_files(krdc_rdp_SRCS
  25         rdp/rdppreferences.ui
  26     )
  27 endif(HAVE_RDESKTOP)
  28
  29 if(DNSSD_FOUND)
  30     add_definitions(-DBUILD_ZEROCONF)
  31     set(krdc_zeroconf_SRCS
  32         zeroconf/zeroconfpage.cpp
  33     )
  34 endif(DNSSD_FOUND)
  35
  36 if(LIBVNCSERVER_FOUND)
  37     add_definitions(-DBUILD_VNC)
  38
  39     include_directories(${LIBVNCCLIENT_INCLUDE_DIR})
  40
  41     set(krdc_vnc_SRCS
  42         vnc/vnchostpreferences.cpp
  43         vnc/vncclientthread.cpp
  44         vnc/vncview.cpp
  45     )
  46
  47     kde4_add_ui_files(krdc_vnc_SRCS
  48         vnc/vncpreferences.ui
  49     )
  50 endif(LIBVNCSERVER_FOUND)
  51
  52 if(LIBNXCL_FOUND)
  53     add_definitions(-DBUILD_NX)
  54
  55     include_directories(${LIBNXCL_INCLUDE_DIR})
  56
  57     set(krdc_nx_SRCS
  58         nx/nxhostpreferences.cpp
  59         nx/nxview.cpp
  60         nx/nxclientthread.cpp
  61     )
  62
  63     kde4_add_ui_files(krdc_nx_SRCS
  64         nx/nxpreferences.ui
  65     )
  66 endif(LIBNXCL_FOUND)
  67
  68 if(NOT NDEBUG)
  69     set(BUILD_TEST true)
  70 endif(NOT NDEBUG)
  71 if(BUILD_TEST)
  72     add_definitions(-DBUILD_TEST)
  73     set(krdc_test_SRCS
  74         test/testview.cpp
  75     )
  76 endif(BUILD_TEST)
  77
  78 set(krdc_SRCS ${krdc_zeroconf_SRCS} ${krdc_rdp_SRCS} ${krdc_vnc_SRCS} ${krdc_nx_SRCS} ${krdc_test_SRCS}
  79     hostpreferences.cpp
  80     config/hostpreferenceslist.cpp
  81     config/preferencesdialog.cpp
  82     floatingtoolbar.cpp
  83     bookmarkmanager.cpp
  84     remotedesktopsitem.cpp
  85     remotedesktopsmodel.cpp
  86     systemtrayicon.cpp
  87     remoteview.cpp
  88     mainwindow.cpp
  89     main.cpp
  90 )
  91
  92 kde4_add_ui_files(krdc_SRCS
  93     config/general.ui
  94 )
  95
  96 kde4_add_kcfg_files(krdc_SRCS config/settings.kcfgc)
  97
  98 kde4_add_executable(krdc ${krdc_SRCS})
  99
 100 target_link_libraries(krdc ${KDE4_KFILE_LIBS} ${KDE4_KNOTIFYCONFIG_LIBS})
 101
 102 if(LIBVNCSERVER_FOUND)
 103     target_link_libraries(krdc ${LIBVNCCLIENT_LIBRARIES})
 104
 105     if(JPEG_FOUND)
 106         target_link_libraries(krdc ${JPEG_LIBRARIES})
 107     endif(JPEG_FOUND)
 108 endif(LIBVNCSERVER_FOUND)
 109
 110 if(DNSSD_FOUND)
 111    target_link_libraries(krdc ${KDE4_KDNSSD_LIBS})
 112 endif(DNSSD_FOUND)
 113
 114 if(LIBNXCL_FOUND)
 115    target_link_libraries(krdc ${LIBNXCL_LIBRARIES})
 116 endif(LIBNXCL_FOUND)
 117
 118 install(TARGETS krdc ${INSTALL_TARGETS_DEFAULT_ARGS})
 119 install(FILES krdcui.rc DESTINATION ${DATA_INSTALL_DIR}/krdc)
 120 install(FILES krdc.desktop DESTINATION ${XDG_APPS_INSTALL_DIR})
 121 install(FILES vnc.protocol rdp.protocol DESTINATION ${SERVICES_INSTALL_DIR})
 122 install(FILES smb2rdc.desktop DESTINATION ${SERVICES_INSTALL_DIR}/ServiceMenus)
 123 install(FILES pointcursor.png pointcursormask.png DESTINATION ${DATA_INSTALL_DIR}/krdc/pics)
 124
 125 if(LIBNXCL_FOUND)
 126    install(FILES nx/default.dsa.key DESTINATION ${DATA_INSTALL_DIR}/krdc)
 127 endif(LIBNXCL_FOUND)
 128