CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 3.4.3)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # Set up common version variables, as well as general information about
  48 # the build tree (whether the build is from a source package or from a git
  49 # repository).  Also declares a few functions that will be used for generating
  50 # version info files later.
  51 include(gmxBuildTreeInfo)
  52 include(gmxVersionInfo)
  53
  54 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  55     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  56 endif()
  57 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  58     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  59 endif()
  60
  61 include(gmxBuildTypeReference)
  62 include(gmxBuildTypeProfile)
  63 include(gmxBuildTypeTSAN)
  64 include(gmxBuildTypeASAN)
  65 include(gmxBuildTypeMSAN)
  66 include(gmxBuildTypeReleaseWithAssert)
  67
  68 if(NOT CMAKE_BUILD_TYPE)
  69     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
  70     # Set the possible values of build type for cmake-gui
  71     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  72         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
  73 endif()
  74 if(CMAKE_CONFIGURATION_TYPES)
  75     # Add appropriate GROMACS-specific build types for the Visual
  76     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  77     # are already present by default).
  78     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  79     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  80     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  81         "List of configuration types"
  82         FORCE)
  83 endif()
  84 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  85
  86 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  87
  88 include(gmxCTestUtilities)
  89 gmx_ctest_init()
  90
  91 include(gmxCPackUtilities)
  92 gmx_cpack_init()
  93
  94 # Variables that accumulate stuff influencing the installed headers
  95 set(INSTALLED_HEADER_INCLUDE_DIRS "")
  96 set(INSTALLED_HEADER_DEFINITIONS "")
  97
  98 ########################################################################
  99 # Global non-cache variables for implementing the build system
 100 ########################################################################
 101
 102 # These variables collect libraries that GROMACS requires for
 103 # linking. They should be appended to with list(APPEND ${name}
 104 # new-library) calls. They are:
 105 #  - Libraries that are required for libgromacs (only)
 106 set(GMX_EXTRA_LIBRARIES "")
 107 #  - Libraries that are required for all code in the repository
 108 set(GMX_COMMON_LIBRARIES "")
 109 #  - Libraries that all code linked against libgromacs needs
 110 #    (i.e., something that is exposed in installed headers).
 111 set(GMX_PUBLIC_LIBRARIES "")
 112
 113 ########################################################################
 114 # Check and warn if cache generated on a different host is being reused
 115 ########################################################################
 116 if(CMAKE_HOST_UNIX)
 117     execute_process(COMMAND hostname
 118                     OUTPUT_VARIABLE TMP_HOSTNAME
 119                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 120     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 121         message(WARNING "
 122             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 123             is being reused! This could lead to inconsistencies; therefore, it is
 124             recommended to regenerate the cache!")
 125     endif()
 126     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 127             "Hostname of the machine where the cache was generated.")
 128 endif()
 129
 130 ########################################################################
 131 # Detect architecture before setting options so we can alter defaults
 132 ########################################################################
 133 # Detect the architecture the compiler is targetting, detect
 134 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 135 # to use if none is specified, and populate the cache option for CPU
 136 # SIMD.
 137 include(gmxDetectTargetArchitecture)
 138 gmx_detect_target_architecture()
 139
 140 # Permit the user to specify a particular standard library, e.g. compiling
 141 # with "-stdlib=libc++" and linking with "-lc++abi -lc++" to get clang's libcxx.
 142 set(GMX_STDLIB_CXX_FLAGS "" CACHE STRING "Compiler flag for a C++ standard library flavour")
 143 set(GMX_STDLIB_LIBRARIES "" CACHE STRING "Linker libraries for a particular C++ standard library")
 144 mark_as_advanced(GMX_STDLIB_CXX_FLAGS)
 145 mark_as_advanced(GMX_STDLIB_LIBRARIES)
 146
 147 ########################################################################
 148 # Detect CXX11 support and flags
 149 ########################################################################
 150 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 151 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 152 # invalid options with the Intel Compilers, and we have added a line
 153 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 154 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 155 # a semicolon. Since this is also used as a separator in lists inside CMake,
 156 # that string ends up being split into two separate patterns, and the last
 157 # part is just a single word that also matches other messages. We solved this
 158 # by replacing the semicolon with a period that matches any character.
 159 #
 160 # These files should be removed from the source tree when a CMake version that
 161 # includes the features in question becomes required for building GROMACS.
 162 include(CheckCCompilerFlag)
 163 include(CheckCXXCompilerFlag)
 164
 165 # This must come early, since some of our configuration flag tests
 166 # depend on being able to compile C++11 source files.
 167 include(gmxTestCXX11)
 168 gmx_test_cxx11(GMX_CXX11_FLAGS GMX_STDLIB_CXX_FLAGS GMX_STDLIB_LIBRARIES)
 169
 170 # Make sure all C++ code will be compiled in C++11 mode, with the
 171 # expected standard library.
 172 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${GMX_CXX11_FLAGS} ${GMX_STDLIB_CXX_FLAGS}")
 173
 174 ########################################################################
 175 # User input options                                                   #
 176 ########################################################################
 177 include(gmxOptionUtilities)
 178
 179 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 180
 181 # Fujitsu only has SIMD in double precision, so this will be faster
 182 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 183 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 184 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 185 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 186
 187 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 188 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 189 gmx_dependent_option(
 190     GMX_MPI_IN_PLACE
 191     "Enable MPI_IN_PLACE for MPIs that have it defined"
 192     ON
 193     GMX_MPI)
 194 mark_as_advanced(GMX_MPI_IN_PLACE)
 195 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 196 mark_as_advanced(GMX_FAHCORE)
 197
 198 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 199 mark_as_advanced(GMX_COOL_QUOTES)
 200 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 201
 202 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 203
 204 # Decide on GPU settings based on user-settings and GPU/CUDA
 205 # detection.  GCC 4.8 requires CUDA 6.0 (but we choose 6.5 for the
 206 # preliminary C++11 support), icc 15 requires CUDA 7.0, and VS2015
 207 # requires CUDA 8.0
 208 if(MSVC)
 209     set(REQUIRED_CUDA_VERSION 8.0)
 210 elseif(CMAKE_CXX_COMPILER_ID MATCHES "Intel")
 211     set(REQUIRED_CUDA_VERSION 7.0)
 212 else()
 213     set(REQUIRED_CUDA_VERSION 6.5)
 214 endif()
 215 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 216
 217 # OpenCL required version: 1.2 or newer
 218 set(REQUIRED_OPENCL_MIN_VERSION 1.2)
 219
 220 if(NOT GMX_USE_OPENCL)
 221     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 222     include(gmxManageGPU)
 223     set(GMX_USE_CUDA ${GMX_GPU})
 224     if(GMX_GPU)
 225         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 226     else()
 227         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 228     endif()
 229 else()
 230     #Now the OpenCL path (for both AMD and NVIDIA)
 231     if(GMX_GPU)
 232         include(gmxManageOpenCL)
 233         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 234     else()
 235         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 236     endif()
 237 endif()
 238
 239 gmx_option_multichoice(
 240     GMX_SIMD
 241     "SIMD instruction set for CPU kernels and compiler optimization"
 242     "AUTO"
 243     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 244
 245 if(GMX_TARGET_MIC)
 246     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 247 else()
 248     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 249 endif()
 250
 251 gmx_option_multichoice(
 252     GMX_FFT_LIBRARY
 253     "FFT library"
 254     "${GMX_FFT_LIBRARY_DEFAULT}"
 255     fftw3 mkl "fftpack[built-in]")
 256 gmx_dependent_option(
 257     GMX_BUILD_OWN_FFTW
 258     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 259     OFF
 260     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 261 gmx_dependent_option(
 262     GMX_DISABLE_FFTW_MEASURE
 263     "Do not optimize FFTW setups (not needed with SSE)"
 264     OFF
 265     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 266 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 267 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 268
 269 gmx_option_multichoice(
 270     GMX_QMMM_PROGRAM
 271     "QM package for QM/MM"
 272     None
 273     none gaussian mopac gamess orca)
 274
 275 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 276 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 277
 278 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 279
 280 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 281 mark_as_advanced(GMX_BROKEN_CALLOC)
 282
 283 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 284
 285 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 286
 287 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 288
 289 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 290 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 291
 292 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 293 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 294
 295 option(GMX_BUILD_FOR_COVERAGE
 296        "Tune build for better code coverage metrics (e.g., disable asserts)"
 297        OFF)
 298 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 299
 300 option(GMX_DEVELOPER_BUILD
 301     "Enable Developer convenience features: always build unit-tests"
 302     OFF)
 303 mark_as_advanced(GMX_DEVELOPER_BUILD)
 304
 305 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 306 option(GMX_COMPILER_WARNINGS
 307     "Enable a default set of compiler warnings"
 308     ${GMX_COMPILER_WARNINGS_DEFAULT})
 309 mark_as_advanced(GMX_COMPILER_WARNINGS)
 310 # Always turn on compiler warnings with a developer build.
 311 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 312
 313 option(GMX_BUILD_SHARED_EXE
 314     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 315     ON)
 316 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 317
 318 option(GMX_PHYSICAL_VALIDATION
 319        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
 320        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
 321        OFF)
 322 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
 323
 324 ######################################################################
 325 # Detect OpenMP support
 326 ######################################################################
 327 # The OpenMP detection _must_ come before tests for other CFLAGS.
 328 include(gmxManageOpenMP)
 329
 330
 331
 332 ######################################################################
 333 # Compiler tests
 334 # These need to be done early (before further tests).
 335 #####################################################################
 336
 337 include(gmxCFlags)
 338 gmx_c_flags()
 339
 340 # This variable should be used for additional compiler flags which are not
 341 # generated in gmxCFlags nor are SIMD or MPI related.
 342 #
 343 # TODO These variables should be consolidated into
 344 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 345 # things that work in C compilation (e.g. merging from old branches)
 346 # also work for C++ compilation.
 347 set(EXTRA_C_FLAGS "")
 348 set(EXTRA_CXX_FLAGS "")
 349
 350 # Run through a number of tests for buggy compilers and other issues
 351 include(gmxTestCompilerProblems)
 352 gmx_test_compiler_problems()
 353
 354 # Implement double-precision option. This is complicated because we
 355 # need installed headers to use the precision mode of the build that
 356 # produced the library, but cannot use config.h in that case. We also
 357 # want such variables to always have a definition, because #if is more
 358 # robust than #ifdef. So, we put this value on the compiler command
 359 # line in all cases.
 360 #
 361 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 362 # because no installed header needs it
 363 if(GMX_DOUBLE)
 364     set(GMX_DOUBLE_VALUE 1)
 365 else()
 366     set(GMX_DOUBLE_VALUE 0)
 367 endif()
 368 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 369 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 370
 371 if(WIN32)
 372     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 373     add_definitions(-DGMX_HAVE_WINSOCK)
 374 endif()
 375
 376
 377
 378 ########################################################################
 379 # Basic system tests (standard libraries, headers, functions, types)   #
 380 ########################################################################
 381 include(CheckIncludeFiles)
 382 include(CheckIncludeFileCXX)
 383 check_include_files(unistd.h     HAVE_UNISTD_H)
 384 check_include_files(pwd.h        HAVE_PWD_H)
 385 check_include_files(dirent.h     HAVE_DIRENT_H)
 386 check_include_files(time.h       HAVE_TIME_H)
 387 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 388 check_include_files(io.h         HAVE_IO_H)
 389 check_include_files(sched.h      HAVE_SCHED_H)
 390
 391 check_include_files(regex.h      HAVE_POSIX_REGEX)
 392 # TODO: It could be nice to inform the user if no regex support is found,
 393 # as selections won't be fully functional.
 394
 395 include(CheckCXXSymbolExists)
 396 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 397 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 398 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 399 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 400 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 401 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 402 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 403 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 404
 405 # We cannot check for the __builtins as symbols, but check if code compiles
 406 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 407 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 408 if(MSVC)
 409     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 410     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 411 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 412     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 413     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 414 endif()
 415
 416 include(CheckLibraryExists)
 417 find_library(HAVE_LIBM m)
 418 mark_as_advanced(HAVE_LIBM)
 419 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 420 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 421 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
 422
 423 include(TestSchedAffinity)
 424 test_sched_affinity(HAVE_SCHED_AFFINITY)
 425
 426 # Aligned memory allocation. We need to check for both mm_malloc(),
 427 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 428 include(gmxTestMMMalloc)
 429 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 430 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 431 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 432 if(MSVC)
 433     # No need to waste time on this test on platforms where it will never be true
 434     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 435 endif()
 436
 437 include(TestBigEndian)
 438 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 439
 440 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 441
 442 # Management of GROMACS options for specific toolchains should go
 443 # here. Because the initial settings for some of the main options have
 444 # already happened, but things like library detection and MPI compiler
 445 # feature detection have not, the docstrings for any over-rides of
 446 # GROMACS defaults or user settings will make sense. Also, any
 447 # toolchain-related reasons for choosing whether to detect various
 448 # things can be sorted out now, before the detection takes place.
 449 if(GMX_TARGET_FUJITSU_SPARC64)
 450     include(gmxManageFujitsuSparc64)
 451 endif()
 452
 453 ########################################################################
 454 #Process MPI settings
 455 ########################################################################
 456 include(gmxManageMPI)
 457
 458
 459 ########################################################################
 460 #Process shared/static library settings
 461 ########################################################################
 462 include(gmxManageSharedLibraries)
 463
 464
 465 ########################################################################
 466 # Find external packages                                               #
 467 ########################################################################
 468
 469 # Unconditionally find the package, as it is also required for unit
 470 # tests. This exports LIBXML2_FOUND, which we should not use because
 471 # it does not tell us that linking will succeed. Instead, we test that
 472 # next.
 473 #if(DEFINED LIBXML2_LIBRARIES)
 474 #  set(LibXml2_FIND_QUIETLY TRUE)
 475 #endif()
 476 #find_package(LibXml2)
 477 #include(gmxTestLibXml2)
 478 #gmx_test_libxml2(HAVE_LIBXML2)
 479 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 480 #set(PKG_XML "")
 481 #mark_as_advanced(GMX_XML)
 482 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 483 #if(GMX_XML AND NOT HAVE_LIBXML2)
 484 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 485 #endif()
 486 #if(GMX_XML)
 487 #    include_directories(${LIBXML2_INCLUDE_DIR})
 488 #    set(PKG_XML libxml-2.0)
 489 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 490 #endif()
 491
 492 gmx_option_trivalue(
 493     GMX_HWLOC
 494     "Use hwloc portable hardware locality library"
 495     "AUTO")
 496
 497 if (GMX_HWLOC)
 498     # Find quietly the second time.
 499     if(DEFINED HWLOC_LIBRARIES)
 500         set(Hwloc_FIND_QUIETLY TRUE)
 501     endif()
 502     find_package(Hwloc 1.5)
 503
 504     if (HWLOC_FOUND)
 505         if (HWLOC_LIBRARIES MATCHES ".a$")
 506             set(_STATIC_HWLOC TRUE)
 507         endif()
 508
 509         gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 510         if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED)
 511             message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 512             set(GMX_USE_HWLOC OFF)
 513         else()
 514             set(GMX_USE_HWLOC ON)
 515         endif()
 516
 517         if (GMX_USE_HWLOC)
 518             include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 519             list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 520         endif()
 521     elseif(GMX_HWLOC_FORCE)
 522         message(FATAL_ERROR "Hwloc package support required, but not found.")
 523     endif()
 524 endif()
 525
 526 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 527 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 528 if(GMX_EXTERNAL_TINYXML2)
 529     # Find an external TinyXML-2 library.
 530     find_package(TinyXML-2 3.0.0)
 531     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 532     if(NOT HAVE_TINYXML2)
 533         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 534     endif()
 535 endif()
 536
 537 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 538 mark_as_advanced(GMX_EXTRAE)
 539
 540 if (GMX_EXTRAE)
 541   find_package(EXTRAE)
 542   if(EXTRAE_FOUND)
 543     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 544     set(HAVE_EXTRAE 1)
 545   else()
 546     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 547   endif()
 548 endif()
 549
 550 option(GMX_X11 "Use X window system" OFF)
 551 if (GMX_X11)
 552     find_package(X11)
 553     # X11 includes/libraries are only set in the ngmx subdirectory!
 554     if(NOT X11_FOUND)
 555         message(FATAL_ERROR
 556                 "X11 include files and/or libraries were not found. "
 557                 "Set GMX_X11=OFF to compile without X11 support. "
 558                 "gmx view will not be available.")
 559     endif()
 560     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 561 endif()
 562
 563 include(ThreadMPI)
 564 # Enable core threading facilities
 565 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 566 if(GMX_THREAD_MPI)
 567     # enable MPI functions
 568     tmpi_enable()
 569     set(MPI_IN_PLACE_EXISTS 1)
 570 endif()
 571 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 572 if (TMPI_ATOMICS_DISABLED)
 573    add_definitions(-DTMPI_ATOMICS_DISABLED)
 574 endif()
 575
 576 include(gmxManageTNG)
 577
 578 include(gmxManageLmfit)
 579
 580 if(GMX_GPU)
 581     # now that we have detected the dependencies, do the second configure pass
 582     gmx_gpu_setup()
 583     if (GMX_CLANG_CUDA)
 584         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_CUDA_CLANG_LINK_LIBS})
 585         link_directories("${GMX_CUDA_CLANG_LINK_DIRS}")
 586     endif()
 587 endif()
 588
 589 if(CYGWIN)
 590     set(GMX_CYGWIN 1)
 591 endif()
 592
 593 if(WIN32)
 594     set(GMX_NATIVE_WINDOWS 1)
 595     # This makes windows.h not declare min/max as macros that would break
 596     # C++ code using std::min/std::max.
 597     add_definitions(-DNOMINMAX)
 598 endif()
 599
 600 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 601     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 602         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 603     endif()
 604     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 605         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 606     endif()
 607 endif()
 608
 609 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 610 mark_as_advanced(GMX_BUILD_UNITTESTS)
 611 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 612
 613 ########################################################################
 614 # Our own GROMACS tests
 615 ########################################################################
 616
 617 add_definitions( -DHAVE_CONFIG_H )
 618 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 619 # TODO required at high level because both libgromacs and progs/mdrun
 620 # require it, both for thread-MPI and its atomics and mutexes.
 621 include_directories(BEFORE SYSTEM ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 622 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 623 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 624
 625 include(gmxTestInlineASM)
 626 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 627
 628 include(gmxSetBuildInformation)
 629 gmx_set_build_information()
 630
 631 gmx_option_multichoice(
 632     GMX_USE_RDTSCP
 633     "Use low-latency RDTSCP instruction for CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments)"
 634     "AUTO"
 635     OFF ON AUTO DETECT)
 636 mark_as_advanced(GMX_USE_RDTSCP)
 637
 638 macro(gmx_check_rdtscp)
 639     if (CPU_DETECTION_FEATURES MATCHES "rdtscp")
 640         set(HAVE_RDTSCP 1)
 641         set(RDTSCP_DETECTION_MESSAGE " - detected on the build host")
 642     else()
 643         set(RDTSCP_DETECTION_MESSAGE " - not detected on the build host")
 644     endif()
 645 endmacro()
 646
 647 set(HAVE_RDTSCP 0)
 648 if (GMX_USE_RDTSCP STREQUAL "ON")
 649     set(HAVE_RDTSCP 1)
 650 elseif(GMX_USE_RDTSCP STREQUAL "DETECT")
 651     gmx_check_rdtscp()
 652 elseif(GMX_USE_RDTSCP STREQUAL "AUTO")
 653     # If the user specified automated SIMD selection, that the choice
 654     # is made based on detection on the build host. If so, then RDTSCP
 655     # should be chosen the same way.
 656     #
 657     # If the user specified an AVX SIMD level (e.g. when
 658     # cross-compiling GROMACS) then they will get our best guess, ie
 659     # that in practice AVX mostly correlates with rdtscp (and anyway
 660     # is only relevant in rather old x86 hardware).
 661     if (GMX_SIMD STREQUAL "AUTO")
 662         gmx_check_rdtscp()
 663     elseif (GMX_SIMD MATCHES "AVX")
 664         set(HAVE_RDTSCP 1)
 665     endif()
 666 endif()
 667 gmx_check_if_changed(HAVE_RDTSCP_CHANGED HAVE_RDTSCP)
 668 if (HAVE_RDTSCP_CHANGED)
 669     if (HAVE_RDTSCP)
 670         message(STATUS "Enabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 671     else()
 672         message(STATUS "Disabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 673     endif()
 674 endif()
 675
 676 include(gmxTestLargeFiles)
 677 gmx_test_large_files(GMX_LARGEFILES)
 678
 679 include(gmxTestSignal)
 680 gmx_test_sigusr1(HAVE_SIGUSR1)
 681
 682 include(gmxTestPipes)
 683 gmx_test_pipes(HAVE_PIPES)
 684
 685 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 686
 687 include(gmxTestXDR)
 688 gmx_test_xdr(GMX_SYSTEM_XDR)
 689 if(NOT GMX_SYSTEM_XDR)
 690     set(GMX_INTERNAL_XDR 1)
 691 endif()
 692
 693
 694 ##################################################
 695 # Process SIMD instruction settings
 696 ##################################################
 697 # This checks what flags to add in order to
 698 # support the SIMD instructions we need, it sets
 699 # correct defines for the SIMD instructions supported,
 700 # and adds advanced options to control accuracy
 701 # for SIMD math operations.
 702 include(gmxManageSimd)
 703 gmx_manage_simd()
 704
 705 include(gmxManageCycleCounters)
 706 gmx_manage_cycle_counters()
 707
 708 # Process QM/MM Settings
 709 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 710     set(GMX_QMMM_GAUSSIAN 1)
 711 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 712     set(GMX_QMMM_MOPAC 1)
 713 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 714     set(GMX_QMMM_GAMESS 1)
 715 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 716     set(GMX_QMMM_ORCA 1)
 717 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 718     # nothing to do
 719 else()
 720     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 721 endif()
 722
 723
 724 ##################################################
 725 # Process FFT library settings
 726 ##################################################
 727 include(gmxManageFFTLibraries)
 728
 729
 730 include(gmxManageLinearAlgebraLibraries)
 731
 732 include(gmxManagePluginSupport)
 733
 734 if (GMX_USE_PLUGINS)
 735     if(NOT GMX_VMD_PLUGIN_PATH)
 736         find_package(VMD)
 737     endif()
 738 endif()
 739
 740 # Link real-time library for POSIX timers. The check for clock_gettime
 741 # confirms the linkability of rt.
 742 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 743     list(APPEND GMX_EXTRA_LIBRARIES rt)
 744 endif()
 745
 746 # Math and thread libraries must often come after all others when linking...
 747 if (HAVE_LIBM)
 748     list(APPEND GMX_PUBLIC_LIBRARIES m)
 749 endif()
 750
 751 option(GMX_NACL "Configure for Native Client builds" OFF)
 752 if (GMX_NACL)
 753   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 754   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 755   # TODO: Is this still necessary with the check for its presence?
 756   set(GMX_USE_NICE 0)
 757   set(GMX_NO_RENAME 1)
 758 endif()
 759 mark_as_advanced(GMX_NACL)
 760
 761 if(GMX_FAHCORE)
 762   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 763       "Path to swindirect.h")
 764   include_directories(${COREWRAP_INCLUDE_DIR})
 765 endif()
 766
 767 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 768 # produce warnings if that fails.
 769 set(build_help_default AUTO)
 770 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 771     set(build_help_default OFF)
 772 endif()
 773 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 774 mark_as_advanced(GMX_BUILD_HELP)
 775 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 776     message(FATAL_ERROR
 777         "Rebuilding shell completions or man pages is not supported for "
 778         "in-source builds from a source distribution. "
 779         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 780 endif()
 781
 782 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 783 # these are set after everything else
 784 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 785     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 786     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 787     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 788     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 789 else()
 790     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 791     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 792     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 793     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 794     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 795     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 796     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 797     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 798     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 799 endif()
 800
 801 if(NOT GMX_OPENMP)
 802     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 803     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 804     unset(OpenMP_C_FLAGS CACHE)
 805     unset(OpenMP_CXX_FLAGS CACHE)
 806 else()
 807     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 808     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 809 endif()
 810
 811 ########################################################################
 812 # Specify install locations
 813 ########################################################################
 814 # Use GNUInstallDirs to set paths on multiarch systems.
 815 include(GNUInstallDirs)
 816
 817 # Customization for the installation tree paths.
 818 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 819     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 820 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 821     "Data installation directory under share/ (default: gromacs)")
 822 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 823
 824 # These variables are used internally to provide a central location for
 825 # customizing the install locations.
 826 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 827 set(BIN_INSTALL_DIR       bin)
 828 # This variable also gets written into config.h for use in finding the data
 829 # directories.
 830 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 831 set(MAN_INSTALL_DIR       share/man)
 832 # If the nesting level wrt. the installation root is changed,
 833 # gromacs-config.cmake.cmakein needs to be adapted.
 834 set(CMAKE_INSTALL_DIR     share/cmake)
 835 # TODO: Make GMXRC adapt if this is changed
 836 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 837 set(OCL_INSTALL_DIR       ${DATA_INSTALL_DIR}/opencl)
 838 set(INCL_INSTALL_DIR      include)
 839
 840 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 841
 842 # Binary and library suffix options
 843 include(gmxManageSuffixes)
 844
 845 ################################################################
 846 # Shared library load path settings
 847 ################################################################
 848 if(NOT GMX_BUILD_SHARED_EXE)
 849     # No rpath
 850     set(CMAKE_SKIP_RPATH TRUE)
 851     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 852     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 853 else()
 854     # The build folder always has bin/ and lib/; if we are also going to
 855     # install to lib/, then the installation RPATH works also in the build
 856     # tree.  This makes installation slightly faster (no need to rewrite the
 857     # RPATHs), and makes the binaries in the build tree relocatable.
 858     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 859         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 860         if(POLICY CMP0068)
 861             cmake_policy(SET CMP0068 NEW) # From CMake-3.9
 862             set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
 863         endif()
 864     endif()
 865     # Set the RPATH as relative to the executable location to make the
 866     # binaries relocatable.
 867     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 868         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 869         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
 870     else()
 871         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 872     endif()
 873     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 874     set(CMAKE_MACOSX_RPATH 1)
 875 endif()
 876
 877 #COPYING file: Only necessary for binary distributions.
 878 #Simpler to always install.
 879 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 880
 881 if (GMX_BUILD_FOR_COVERAGE)
 882     # Code heavy with asserts makes conditional coverage close to useless metric,
 883     # as by design most of the false branches are impossible to trigger in
 884     # correctly functioning code.  And the benefit of testing those that could
 885     # be triggered by using an API against its specification isn't usually
 886     # worth the effort.
 887     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 888 endif()
 889
 890 if (BUILD_TESTING)
 891     include(tests/CheckTarget.cmake)
 892 endif()
 893
 894 if (NOT GMX_BUILD_MDRUN_ONLY)
 895     add_subdirectory(docs)
 896     add_subdirectory(share)
 897     add_subdirectory(scripts)
 898 endif()
 899 add_subdirectory(src)
 900
 901 if (BUILD_TESTING)
 902     add_subdirectory(tests)
 903 endif()
 904
 905 gmx_cpack_write_config()
 906
 907 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 908 # Don't bother the user after the first configure pass.
 909 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 910     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 911 endif()
 912 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 913
 914 #######################
 915 ## uninstall target
 916 #######################
 917 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 918                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 919                   IMMEDIATE @ONLY)
 920 ###########################
 921 ADD_CUSTOM_TARGET(uninstall
 922                   "${CMAKE_COMMAND}" -P
 923                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 924 ###########################
 925 set_directory_properties(PROPERTIES
 926             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")