src/testutils/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2011,2012,2013,2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 if (NOT GMX_BUILD_UNITTESTS)
  36     gmx_add_missing_tests_notice("Unit tests have not been run. You need to set GMX_BUILD_UNITTESTS=ON if you want to build and run them.")
  37     return()
  38 endif()
  39
  40 include_directories(BEFORE SYSTEM ${GMOCK_INCLUDE_DIRS})
  41 set(TESTUTILS_SOURCES
  42     cmdlinetest.cpp
  43     conftest.cpp
  44     filematchers.cpp
  45     interactivetest.cpp
  46     loggertest.cpp
  47     mpi-printer.cpp
  48     mpitest.cpp
  49     refdata.cpp
  50     refdata-xml.cpp
  51     simulationdatabase.cpp
  52     stdiohelper.cpp
  53     stringtest.cpp
  54     testasserts.cpp
  55     testfilemanager.cpp
  56     testfileredirector.cpp
  57     testinit.cpp
  58     testmatchers.cpp
  59     testoptions.cpp
  60     textblockmatchers.cpp
  61     xvgtest.cpp
  62     )
  63
  64 if(NOT HAVE_TINYXML2)
  65     list(APPEND TESTUTILS_SOURCES ../external/tinyxml2/tinyxml2.cpp)
  66 endif()
  67
  68 add_library(testutils STATIC ${UNITTEST_TARGET_OPTIONS} ${TESTUTILS_SOURCES})
  69 set(TESTUTILS_LIBS testutils)
  70 set_property(TARGET testutils APPEND PROPERTY COMPILE_DEFINITIONS "${GMOCK_COMPILE_DEFINITIONS}")
  71 set_property(TARGET testutils APPEND PROPERTY COMPILE_FLAGS "${GMOCK_COMPILE_FLAGS}")
  72 target_link_libraries(testutils libgromacs ${GMX_COMMON_LIBRARIES} ${GMOCK_LIBRARIES})
  73
  74 if(HAVE_TINYXML2)
  75     include_directories(SYSTEM ${TinyXML2_INCLUDE_DIR})
  76     target_link_libraries(testutils ${TinyXML2_LIBRARIES})
  77 else()
  78     include_directories(BEFORE SYSTEM "../external/tinyxml2")
  79 endif()
  80
  81 # TODO Use gmx_add_missing_tests_notice() instead of the messages below.
  82 set(GMX_CAN_RUN_MPI_TESTS 1)
  83 if (GMX_MPI)
  84     set(_an_mpi_variable_had_content 0)
  85     foreach(VARNAME MPIEXEC MPIEXEC_NUMPROC_FLAG MPIEXEC_PREFLAGS MPIEXEC_POSTFLAGS)
  86         # These variables need a valid value for the test to run
  87         # and pass, but conceivably any of them might be valid
  88         # with arbitrary (including empty) content. They can't be
  89         # valid if they've been populated with the CMake
  90         # find_package magic suffix/value "NOTFOUND", though.
  91         if (${VARNAME} MATCHES ".*NOTFOUND")
  92             message(STATUS "CMake variable ${VARNAME} was not detected to be a valid value. To test GROMACS correctly, check the advice in the install guide.")
  93             set(GMX_CAN_RUN_MPI_TESTS 0)
  94         endif()
  95         if (NOT VARNAME STREQUAL MPIEXEC AND ${VARNAME})
  96             set(_an_mpi_variable_had_content 1)
  97         endif()
  98     endforeach()
  99     if(_an_mpi_variable_had_content AND NOT MPIEXEC)
 100         message(STATUS "CMake variable MPIEXEC must have a valid value if one of the other related MPIEXEC variables does. To test GROMACS correctly, check the advice in the install guide.")
 101         set(GMX_CAN_RUN_MPI_TESTS 0)
 102     endif()
 103 elseif (NOT GMX_THREAD_MPI)
 104     set(GMX_CAN_RUN_MPI_TESTS 0)
 105 endif()
 106
 107 set(TESTUTILS_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 108 set(TESTUTILS_DIR ${TESTUTILS_DIR} PARENT_SCOPE)
 109 set(TESTUTILS_LIBS ${TESTUTILS_LIBS} PARENT_SCOPE)
 110 set(GMX_CAN_RUN_MPI_TESTS ${GMX_CAN_RUN_MPI_TESTS} PARENT_SCOPE)
 111
 112 add_subdirectory(tests)