src/testutils/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2011,2012,2013,2014,2015 by the GROMACS development team.
   5 # Copyright (c) 2016,2017,2018,2019,2020, by the GROMACS development team, led by
   6 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   7 # and including many others, as listed in the AUTHORS file in the
   8 # top-level source directory and at http://www.gromacs.org.
   9 #
  10 # GROMACS is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU Lesser General Public License
  12 # as published by the Free Software Foundation; either version 2.1
  13 # of the License, or (at your option) any later version.
  14 #
  15 # GROMACS is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 # Lesser General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU Lesser General Public
  21 # License along with GROMACS; if not, see
  22 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  23 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  24 #
  25 # If you want to redistribute modifications to GROMACS, please
  26 # consider that scientific software is very special. Version
  27 # control is crucial - bugs must be traceable. We will be happy to
  28 # consider code for inclusion in the official distribution, but
  29 # derived work must not be called official GROMACS. Details are found
  30 # in the README & COPYING files - if they are missing, get the
  31 # official version at http://www.gromacs.org.
  32 #
  33 # To help us fund GROMACS development, we humbly ask that you cite
  34 # the research papers on the package. Check out http://www.gromacs.org.
  35
  36 if (NOT GMX_BUILD_UNITTESTS)
  37     gmx_add_missing_tests_notice("Unit tests have not been run. You need to set GMX_BUILD_UNITTESTS=ON if you want to build and run them.")
  38     return()
  39 endif()
  40
  41 if (GMX_GPU_CUDA)
  42     # Work around FindCUDA that prevents using target_link_libraries()
  43     # with keywords otherwise...
  44     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
  45     if (NOT GMX_CLANG_CUDA)
  46         gmx_cuda_add_library(testutils)
  47     else()
  48         set_source_files_properties(test_device.cpp PROPERTIES CUDA_SOURCE_PROPERTY_FORMAT OBJ)
  49         gmx_compile_cuda_file_with_clang(test_device.cpp)
  50         add_library(testutils STATIC ${TESTUTILS_SOURCES})
  51         target_link_libraries(testutils PRIVATE ${GMX_CUDA_CLANG_LINK_LIBS})
  52     endif()
  53     target_link_libraries(testutils PRIVATE ${CUDA_CUFFT_LIBRARIES})
  54 else()
  55     add_library(testutils STATIC ${UNITTEST_TARGET_OPTIONS})
  56 endif()
  57
  58 # Module interface / provided facilities
  59 target_include_directories(testutils PUBLIC include)
  60
  61 # Executable targets for tests based on `testutils` acquire the source for
  62 # their entry point from unittest_main.cpp when linking to the `testutils` target.
  63 target_sources(testutils INTERFACE unittest_main.cpp)
  64
  65
  66 target_sources(testutils PRIVATE
  67                cmdlinetest.cpp
  68                conftest.cpp
  69                filematchers.cpp
  70                interactivetest.cpp
  71                loggertest.cpp
  72                mpi_printer.cpp
  73                mpitest.cpp
  74                refdata.cpp
  75                refdata_xml.cpp
  76                simulationdatabase.cpp
  77                stdiohelper.cpp
  78                stringtest.cpp
  79                testasserts.cpp
  80                testfilemanager.cpp
  81                testfileredirector.cpp
  82                test_device.cpp
  83                test_hardware_environment.cpp
  84                testinit.cpp
  85                testmatchers.cpp
  86                testoptions.cpp
  87                textblockmatchers.cpp
  88                tprfilegenerator.cpp
  89                xvgtest.cpp
  90                )
  91
  92
  93 if(HAVE_TINYXML2)
  94     target_include_directories(testutils SYSTEM PRIVATE ${TinyXML2_INCLUDE_DIR})
  95     target_link_libraries(testutils PRIVATE ${TinyXML2_LIBRARIES})
  96 else()
  97     target_include_directories(testutils SYSTEM BEFORE PRIVATE ${CMAKE_SOURCE_DIR}/src/external/tinyxml2)
  98     target_sources(testutils PRIVATE ${CMAKE_SOURCE_DIR}/src/external/tinyxml2/tinyxml2.cpp)
  99 endif()
 100
 101 target_include_directories(testutils PRIVATE ${CMAKE_CURRENT_SOURCE_DIR})
 102
 103 if (GMX_GPU_SYCL)
 104     set_source_files_properties(test_device.cpp
 105       PROPERTIES COMPILE_FLAGS "${SYCL_CXX_FLAGS}")
 106 endif()
 107
 108 gmx_target_compile_options(testutils)
 109 target_compile_definitions(testutils PRIVATE HAVE_CONFIG_H)
 110 target_include_directories(testutils SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 111 target_link_libraries(testutils PRIVATE libgromacs ${GMX_COMMON_LIBRARIES} gmock)
 112 target_link_libraries(testutils PUBLIC common)
 113
 114 # GROMACS module dependencies.
 115 # Note that testutils conveys transitive dependencies on some modules.
 116 # TODO: Explicitly link specific modules with minimal exposure.
 117 target_link_libraries(testutils PUBLIC legacy_modules)
 118
 119 # TODO Use gmx_add_missing_tests_notice() instead of the messages below.
 120 set(GMX_CAN_RUN_MPI_TESTS 1)
 121 if (GMX_MPI)
 122     set(_an_mpi_variable_had_content 0)
 123     foreach(VARNAME MPIEXEC MPIEXEC_NUMPROC_FLAG MPIEXEC_PREFLAGS MPIEXEC_POSTFLAGS)
 124         # These variables need a valid value for the test to run
 125         # and pass, but conceivably any of them might be valid
 126         # with arbitrary (including empty) content. They can't be
 127         # valid if they've been populated with the CMake
 128         # find_package magic suffix/value "NOTFOUND", though.
 129         if (${VARNAME} MATCHES ".*NOTFOUND")
 130             message(STATUS "CMake variable ${VARNAME} was not detected to be a valid value. To test GROMACS correctly, check the advice in the install guide.")
 131             set(GMX_CAN_RUN_MPI_TESTS 0)
 132         endif()
 133         if (NOT VARNAME STREQUAL MPIEXEC AND ${VARNAME})
 134             set(_an_mpi_variable_had_content 1)
 135         endif()
 136     endforeach()
 137     if(_an_mpi_variable_had_content AND NOT MPIEXEC)
 138         message(STATUS "CMake variable MPIEXEC must have a valid value if one of the other related MPIEXEC variables does. To test GROMACS correctly, check the advice in the install guide.")
 139         set(GMX_CAN_RUN_MPI_TESTS 0)
 140     endif()
 141 elseif (NOT GMX_THREAD_MPI)
 142     set(GMX_CAN_RUN_MPI_TESTS 0)
 143 endif()
 144
 145 set(GMX_CAN_RUN_MPI_TESTS ${GMX_CAN_RUN_MPI_TESTS} PARENT_SCOPE)
 146
 147 add_subdirectory(tests)