m4/remainder.m4

   1 # remainder.m4 serial 6
   2 dnl Copyright (C) 2012-2018 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_REMAINDER],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_remainder_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11
  12   dnl Test whether remainder() is declared. On IRIX 5.3 it is not declared.
  13   AC_CHECK_DECL([remainder], , [HAVE_DECL_REMAINDER=0], [[#include <math.h>]])
  14
  15   REMAINDER_LIBM=
  16   AC_CACHE_CHECK([whether remainder() can be used without linking with libm],
  17     [gl_cv_func_remainder_no_libm],
  18     [
  19       AC_LINK_IFELSE(
  20         [AC_LANG_PROGRAM(
  21            [[#ifndef __NO_MATH_INLINES
  22              # define __NO_MATH_INLINES 1 /* for glibc */
  23              #endif
  24              #include <math.h>
  25              double x;
  26              double y;]],
  27            [[return remainder (x, y) > 1;]])],
  28         [gl_cv_func_remainder_no_libm=yes],
  29         [gl_cv_func_remainder_no_libm=no])
  30     ])
  31   if test $gl_cv_func_remainder_no_libm = no; then
  32     AC_CACHE_CHECK([whether remainder() can be used with libm],
  33       [gl_cv_func_remainder_in_libm],
  34       [
  35         save_LIBS="$LIBS"
  36         LIBS="$LIBS -lm"
  37         AC_LINK_IFELSE(
  38           [AC_LANG_PROGRAM(
  39              [[#ifndef __NO_MATH_INLINES
  40                # define __NO_MATH_INLINES 1 /* for glibc */
  41                #endif
  42                #include <math.h>
  43                double x;
  44                double y;]],
  45              [[return remainder (x, y) > 1;]])],
  46           [gl_cv_func_remainder_in_libm=yes],
  47           [gl_cv_func_remainder_in_libm=no])
  48         LIBS="$save_LIBS"
  49       ])
  50     if test $gl_cv_func_remainder_in_libm = yes; then
  51       REMAINDER_LIBM=-lm
  52     fi
  53   fi
  54   if test $gl_cv_func_remainder_no_libm = yes \
  55      || test $gl_cv_func_remainder_in_libm = yes; then
  56     :
  57     m4_ifdef([gl_FUNC_REMAINDER_IEEE], [
  58       if test $gl_remainder_required = ieee && test $REPLACE_REMAINDER = 0; then
  59         AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  60         AC_CACHE_CHECK([whether remainder works according to ISO C 99 with IEC 60559],
  61           [gl_cv_func_remainder_ieee],
  62           [
  63             save_LIBS="$LIBS"
  64             LIBS="$LIBS $REMAINDER_LIBM"
  65             AC_RUN_IFELSE(
  66               [AC_LANG_SOURCE([[
  67 #ifndef __NO_MATH_INLINES
  68 # define __NO_MATH_INLINES 1 /* for glibc */
  69 #endif
  70 #include <math.h>
  71 /* Compare two numbers with ==.
  72    This is a separate function because IRIX 6.5 "cc -O" miscompiles an
  73    'x == x' test.  */
  74 static int
  75 numeric_equal (double x, double y)
  76 {
  77   return x == y;
  78 }
  79 static double dummy (double x, double y) { return 0; }
  80 int main (int argc, char *argv[])
  81 {
  82   double (*my_remainder) (double, double) = argc ? remainder : dummy;
  83   double f;
  84   /* Test remainder(...,0.0).
  85      This test fails on OSF/1 5.1.  */
  86   f = my_remainder (2.0, 0.0);
  87   if (numeric_equal (f, f))
  88     return 1;
  89   return 0;
  90 }
  91               ]])],
  92               [gl_cv_func_remainder_ieee=yes],
  93               [gl_cv_func_remainder_ieee=no],
  94               [case "$host_os" in
  95                                 # Guess yes on glibc systems.
  96                  *-gnu* | gnu*) gl_cv_func_remainder_ieee="guessing yes" ;;
  97                                 # Guess yes on native Windows.
  98                  mingw*)        gl_cv_func_remainder_ieee="guessing yes" ;;
  99                                 # If we don't know, assume the worst.
 100                  *)             gl_cv_func_remainder_ieee="guessing no" ;;
 101                esac
 102               ])
 103             LIBS="$save_LIBS"
 104           ])
 105         case "$gl_cv_func_remainder_ieee" in
 106           *yes) ;;
 107           *) REPLACE_REMAINDER=1 ;;
 108         esac
 109       fi
 110     ])
 111   else
 112     HAVE_REMAINDER=0
 113   fi
 114   if test $HAVE_REMAINDER = 0 || test $REPLACE_REMAINDER = 1; then
 115     dnl Find libraries needed to link lib/remainder.c.
 116     AC_REQUIRE([gl_FUNC_FABS])
 117     AC_REQUIRE([gl_FUNC_FMOD])
 118     AC_REQUIRE([gl_FUNC_ISNAND])
 119     REMAINDER_LIBM=
 120     dnl Append $FABS_LIBM to REMAINDER_LIBM, avoiding gratuitous duplicates.
 121     case " $REMAINDER_LIBM " in
 122       *" $FABS_LIBM "*) ;;
 123       *) REMAINDER_LIBM="$REMAINDER_LIBM $FABS_LIBM" ;;
 124     esac
 125     dnl Append $FMOD_LIBM to REMAINDER_LIBM, avoiding gratuitous duplicates.
 126     case " $REMAINDER_LIBM " in
 127       *" $FMOD_LIBM "*) ;;
 128       *) REMAINDER_LIBM="$REMAINDER_LIBM $FMOD_LIBM" ;;
 129     esac
 130     dnl Append $ISNAND_LIBM to REMAINDER_LIBM, avoiding gratuitous duplicates.
 131     case " $REMAINDER_LIBM " in
 132       *" $ISNAND_LIBM "*) ;;
 133       *) REMAINDER_LIBM="$REMAINDER_LIBM $ISNAND_LIBM" ;;
 134     esac
 135   fi
 136   AC_SUBST([REMAINDER_LIBM])
 137 ])