modules/uchar-c++-tests

   1 Files:
   2 tests/test-uchar-c++.cc
   3 tests/test-uchar-c++2.cc
   4 tests/signature.h
   5
   6 Status:
   7 c++-test
   8
   9 Depends-on:
  10 ansi-c++-opt
  11
  12 configure.ac:
  13 AC_REQUIRE([gl_ANSI_CXX])
  14 if test "$CXX" != no; then
  15   dnl On FreeBSD 12, 'c++' defines __cplusplus to 201402, although it does not
  16   dnl have the <cuchar> header file from C++11.
  17   AC_CACHE_CHECK([whether the C++ compiler has <cuchar>],
  18     [gl_cv_cxxheader_cuchar],
  19     [AC_LANG_PUSH([C++])
  20      AC_COMPILE_IFELSE(
  21        [AC_LANG_PROGRAM(
  22           [[#include <cuchar>]],
  23           [[]])
  24        ],
  25        [gl_cv_cxxheader_cuchar=yes],
  26        [gl_cv_cxxheader_cuchar=no])
  27      AC_LANG_POP([C++])
  28     ])
  29 else
  30   gl_cv_cxxheader_cuchar=no
  31 fi
  32 AM_CONDITIONAL([CXX_HAVE_CUCHAR], [test $gl_cv_cxxheader_cuchar != no])
  33
  34 Makefile.am:
  35 if ANSICXX
  36 TESTS += test-uchar-c++
  37 check_PROGRAMS += test-uchar-c++
  38 test_uchar_c___SOURCES = test-uchar-c++.cc
  39 if CXX_HAVE_CUCHAR
  40 test_uchar_c___SOURCES += test-uchar-c++2.cc
  41 endif
  42 test_uchar_c___LDADD = $(LDADD) $(LIB_MBRTOWC)
  43 endif