m4/cbrtl.m4

   1 # cbrtl.m4 serial 6
   2 dnl Copyright (C) 2012-2017 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_CBRTL],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_cbrtl_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11   AC_REQUIRE([gl_LONG_DOUBLE_VS_DOUBLE])
  12   AC_REQUIRE([gl_FUNC_CBRT])
  13
  14   dnl Persuade glibc <math.h> to declare cbrtl().
  15   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  16
  17   dnl Test whether cbrtl() exists. Assume that cbrtl(), if it exists, is
  18   dnl defined in the same library as cbrt().
  19   save_LIBS="$LIBS"
  20   LIBS="$LIBS $CBRT_LIBM"
  21   AC_CHECK_FUNCS([cbrtl])
  22   LIBS="$save_LIBS"
  23   if test $ac_cv_func_cbrtl = yes; then
  24     CBRTL_LIBM="$CBRT_LIBM"
  25     dnl Also check whether it's declared.
  26     dnl IRIX 6.5 has cbrtl() in libm but doesn't declare it in <math.h>.
  27     AC_CHECK_DECL([cbrtl], , [HAVE_DECL_CBRTL=0], [[#include <math.h>]])
  28
  29     save_LIBS="$LIBS"
  30     LIBS="$LIBS $CBRTL_LIBM"
  31     gl_FUNC_CBRTL_WORKS
  32     LIBS="$save_LIBS"
  33     case "$gl_cv_func_cbrtl_works" in
  34       *yes) ;;
  35       *) REPLACE_CBRTL=1 ;;
  36     esac
  37
  38     m4_ifdef([gl_FUNC_CBRTL_IEEE], [
  39       if test $gl_cbrtl_required = ieee && test $REPLACE_CBRTL = 0; then
  40         AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  41         AC_CACHE_CHECK([whether cbrtl works according to ISO C 99 with IEC 60559],
  42           [gl_cv_func_cbrtl_ieee],
  43           [
  44             save_LIBS="$LIBS"
  45             LIBS="$LIBS $CBRTL_LIBM"
  46             AC_RUN_IFELSE(
  47               [AC_LANG_SOURCE([[
  48 #ifndef __NO_MATH_INLINES
  49 # define __NO_MATH_INLINES 1 /* for glibc */
  50 #endif
  51 #include <math.h>
  52 ]gl_LONG_DOUBLE_MINUS_ZERO_CODE[
  53 ]gl_LONG_DOUBLE_SIGNBIT_CODE[
  54 static long double dummy (long double x) { return 0; }
  55 int main (int argc, char *argv[])
  56 {
  57   extern
  58   #ifdef __cplusplus
  59   "C"
  60   #endif
  61   long double cbrtl (long double);
  62   long double (*my_cbrtl) (long double) = argc ? cbrtl : dummy;
  63   long double f;
  64   /* Test cbrtl(-0.0).
  65      This test fails on IRIX 6.5.  */
  66   f = my_cbrtl (minus_zerol);
  67   if (!(f == 0.0L) || (signbitl (minus_zerol) && !signbitl (f)))
  68     return 1;
  69   return 0;
  70 }
  71               ]])],
  72               [gl_cv_func_cbrtl_ieee=yes],
  73               [gl_cv_func_cbrtl_ieee=no],
  74               [case "$host_os" in
  75                          # Guess yes on glibc systems.
  76                  *-gnu*) gl_cv_func_cbrtl_ieee="guessing yes" ;;
  77                          # Guess yes on native Windows.
  78                  mingw*) gl_cv_func_cbrtl_ieee="guessing yes" ;;
  79                          # If we don't know, assume the worst.
  80                  *)      gl_cv_func_cbrtl_ieee="guessing no" ;;
  81                esac
  82               ])
  83             LIBS="$save_LIBS"
  84           ])
  85         case "$gl_cv_func_cbrtl_ieee" in
  86           *yes) ;;
  87           *) REPLACE_CBRTL=1 ;;
  88         esac
  89       fi
  90     ])
  91   else
  92     HAVE_CBRTL=0
  93     HAVE_DECL_CBRTL=0
  94   fi
  95   if test $HAVE_CBRTL = 0 || test $REPLACE_CBRTL = 1; then
  96     dnl Find libraries needed to link lib/cbrtl.c.
  97     if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
  98       CBRTL_LIBM="$CBRT_LIBM"
  99     else
 100       AC_REQUIRE([gl_FUNC_FREXPL])
 101       AC_REQUIRE([gl_FUNC_LDEXPL])
 102       CBRTL_LIBM=
 103       dnl Append $FREXPL_LIBM to CBRTL_LIBM, avoiding gratuitous duplicates.
 104       case " $CBRTL_LIBM " in
 105         *" $FREXPL_LIBM "*) ;;
 106         *) CBRTL_LIBM="$CBRTL_LIBM $FREXPL_LIBM" ;;
 107       esac
 108       dnl Append $LDEXPL_LIBM to CBRTL_LIBM, avoiding gratuitous duplicates.
 109       case " $CBRTL_LIBM " in
 110         *" $LDEXPL_LIBM "*) ;;
 111         *) CBRTL_LIBM="$CBRTL_LIBM $LDEXPL_LIBM" ;;
 112       esac
 113     fi
 114   fi
 115   AC_SUBST([CBRTL_LIBM])
 116 ])
 117
 118 dnl Test whether cbrtl() works.
 119 dnl On OpenBSD 5.1/SPARC, cbrtl(16.0L) is = 1.2599...
 120 AC_DEFUN([gl_FUNC_CBRTL_WORKS],
 121 [
 122   AC_REQUIRE([AC_PROG_CC])
 123   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
 124   AC_CACHE_CHECK([whether cbrtl works], [gl_cv_func_cbrtl_works],
 125     [
 126       AC_RUN_IFELSE(
 127         [AC_LANG_SOURCE([[
 128 #include <math.h>
 129 extern
 130 #ifdef __cplusplus
 131 "C"
 132 #endif
 133 long double cbrtl (long double);
 134 volatile long double x;
 135 long double y;
 136 int main ()
 137 {
 138   x = 16.0L;
 139   y = cbrtl (x);
 140   if (y < 2.0L)
 141     return 1;
 142   return 0;
 143 }
 144 ]])],
 145         [gl_cv_func_cbrtl_works=yes],
 146         [gl_cv_func_cbrtl_works=no],
 147         [case "$host_os" in
 148            openbsd*) gl_cv_func_cbrtl_works="guessing no";;
 149                      # Guess yes on native Windows.
 150            mingw*)   gl_cv_func_cbrtl_works="guessing yes";;
 151            *)        gl_cv_func_cbrtl_works="guessing yes";;
 152          esac
 153         ])
 154     ])
 155 ])