m4/argp.m4

   1 # argp.m4 serial 15
   2 dnl Copyright (C) 2003-2017 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_ARGP],
   8 [
   9   AC_REQUIRE([AC_C_INLINE])
  10   AC_REQUIRE([AC_C_RESTRICT])
  11   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  12
  13   AC_CHECK_DECLS([program_invocation_name], [],
  14                  [AC_DEFINE([GNULIB_PROGRAM_INVOCATION_NAME], [1],
  15                             [Define to 1 to add extern declaration of program_invocation_name to argp.h])],
  16                  [[#include <errno.h>]])
  17   AC_CHECK_DECLS([program_invocation_short_name], [],
  18                  [AC_DEFINE([GNULIB_PROGRAM_INVOCATION_SHORT_NAME], [1],
  19                             [Define to 1 to add extern declaration of program_invocation_short_name to argp.h])],
  20                  [[#include <errno.h>]])
  21
  22   # Check if program_invocation_name and program_invocation_short_name
  23   # are defined elsewhere. It is improbable that only one of them will
  24   # be defined and other not, I prefer to stay on the safe side and to
  25   # test each one separately.
  26   AC_MSG_CHECKING([whether program_invocation_name is defined])
  27   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <argp.h>]],
  28                                   [[program_invocation_name = "test";]])],
  29                  [AC_DEFINE([HAVE_PROGRAM_INVOCATION_NAME], [1],
  30                             [Define if program_invocation_name is defined])
  31                   AC_MSG_RESULT([yes])],
  32                  [AC_MSG_RESULT([no])])
  33
  34   AC_MSG_CHECKING([whether program_invocation_short_name is defined])
  35   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <argp.h>]],
  36                                   [[program_invocation_short_name = "test";]])],
  37                  [AC_DEFINE([HAVE_PROGRAM_INVOCATION_SHORT_NAME], [1],
  38                             [Define if program_invocation_short_name is defined])
  39                   AC_MSG_RESULT([yes])],
  40                  [AC_MSG_RESULT([no])])
  41
  42   AC_CHECK_DECLS_ONCE([clearerr_unlocked])
  43   AC_CHECK_DECLS_ONCE([feof_unlocked])
  44   AC_CHECK_DECLS_ONCE([ferror_unlocked])
  45   AC_CHECK_DECLS_ONCE([fflush_unlocked])
  46   AC_CHECK_DECLS_ONCE([fgets_unlocked])
  47   AC_CHECK_DECLS_ONCE([fputc_unlocked])
  48   AC_CHECK_DECLS_ONCE([fputs_unlocked])
  49   AC_CHECK_DECLS_ONCE([fread_unlocked])
  50   AC_CHECK_DECLS_ONCE([fwrite_unlocked])
  51   AC_CHECK_DECLS_ONCE([getc_unlocked])
  52   AC_CHECK_DECLS_ONCE([getchar_unlocked])
  53   AC_CHECK_DECLS_ONCE([putc_unlocked])
  54   AC_CHECK_DECLS_ONCE([putchar_unlocked])
  55   AC_CHECK_FUNCS_ONCE([flockfile funlockfile])
  56   AC_CHECK_HEADERS_ONCE([features.h linewrap.h])
  57   AC_REQUIRE([AC_FUNC_STRERROR_R])
  58 ])
  59
  60 dnl argp-parse.c depends on GNU getopt internals, therefore use GNU getopt
  61 dnl always.
  62 AC_DEFUN([gl_REPLACE_GETOPT_ALWAYS], [])