m4/sys_time_h.m4

   1 # sys_time_h.m4
   2 # serial 12
   3 dnl Copyright (C) 2007, 2009-2024 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 # Configure a replacement for <sys/time.h>.
   9
  10 # Written by Paul Eggert and Martin Lambers.
  11
  12 AC_DEFUN_ONCE([gl_SYS_TIME_H],
  13 [
  14   dnl Use AC_REQUIRE here, so that the REPLACE_GETTIMEOFDAY=0 statement
  15   dnl below is expanded once only, before all REPLACE_GETTIMEOFDAY=1
  16   dnl statements that occur in other macros.
  17   AC_REQUIRE([gl_SYS_TIME_H_DEFAULTS])
  18   AC_REQUIRE([AC_C_RESTRICT])
  19   AC_CHECK_HEADERS_ONCE([sys/time.h])
  20   gl_CHECK_NEXT_HEADERS([sys/time.h])
  21
  22   if test $ac_cv_header_sys_time_h != yes; then
  23     HAVE_SYS_TIME_H=0
  24   fi
  25
  26   dnl On native Windows with MSVC, 'struct timeval' is defined in <winsock2.h>
  27   dnl only. So include that header in the list.
  28   gl_PREREQ_SYS_H_WINSOCK2
  29   AC_CACHE_CHECK([for struct timeval], [gl_cv_sys_struct_timeval],
  30     [AC_COMPILE_IFELSE(
  31        [AC_LANG_PROGRAM(
  32           [[#if HAVE_SYS_TIME_H
  33              #include <sys/time.h>
  34             #endif
  35             #include <time.h>
  36             #if HAVE_WINSOCK2_H
  37             # include <winsock2.h>
  38             #endif
  39           ]],
  40           [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
  41        [gl_cv_sys_struct_timeval=yes],
  42        [gl_cv_sys_struct_timeval=no])
  43     ])
  44   if test $gl_cv_sys_struct_timeval != yes; then
  45     HAVE_STRUCT_TIMEVAL=0
  46   else
  47     dnl On native Windows with a 64-bit 'time_t', 'struct timeval' is defined
  48     dnl (in <sys/time.h> and <winsock2.h> for mingw64, in <winsock2.h> only
  49     dnl for MSVC) with a tv_sec field of type 'long' (32-bit!), which is
  50     dnl smaller than the 'time_t' type mandated by POSIX.
  51     dnl On OpenBSD 5.1 amd64, tv_sec is 64 bits and time_t 32 bits, but
  52     dnl that is good enough.
  53     AC_CACHE_CHECK([for wide-enough struct timeval.tv_sec member],
  54       [gl_cv_sys_struct_timeval_tv_sec],
  55       [AC_COMPILE_IFELSE(
  56          [AC_LANG_PROGRAM(
  57             [[#if HAVE_SYS_TIME_H
  58                #include <sys/time.h>
  59               #endif
  60               #include <time.h>
  61               #if HAVE_WINSOCK2_H
  62               # include <winsock2.h>
  63               #endif
  64             ]],
  65             [[static struct timeval x;
  66               typedef int verify_tv_sec_type[
  67                 sizeof (time_t) <= sizeof x.tv_sec ? 1 : -1
  68               ];
  69             ]])],
  70          [gl_cv_sys_struct_timeval_tv_sec=yes],
  71          [gl_cv_sys_struct_timeval_tv_sec=no])
  72       ])
  73     if test $gl_cv_sys_struct_timeval_tv_sec != yes; then
  74       REPLACE_STRUCT_TIMEVAL=1
  75     fi
  76   fi
  77
  78   dnl Check for declarations of anything we want to poison if the
  79   dnl corresponding gnulib module is not in use.
  80   gl_WARN_ON_USE_PREPARE([[
  81 #if HAVE_SYS_TIME_H
  82 # include <sys/time.h>
  83 #endif
  84 #include <time.h>
  85     ]], [gettimeofday])
  86 ])
  87
  88 # gl_SYS_TIME_MODULE_INDICATOR([modulename])
  89 # sets the shell variable that indicates the presence of the given module
  90 # to a C preprocessor expression that will evaluate to 1.
  91 # This macro invocation must not occur in macros that are AC_REQUIREd.
  92 AC_DEFUN([gl_SYS_TIME_MODULE_INDICATOR],
  93 [
  94   dnl Ensure to expand the default settings once only.
  95   gl_SYS_TIME_H_REQUIRE_DEFAULTS
  96   gl_MODULE_INDICATOR_SET_VARIABLE([$1])
  97   dnl Define it also as a C macro, for the benefit of the unit tests.
  98   gl_MODULE_INDICATOR_FOR_TESTS([$1])
  99 ])
 100
 101 # Initializes the default values for AC_SUBSTed shell variables.
 102 # This macro must not be AC_REQUIREd.  It must only be invoked, and only
 103 # outside of macros or in macros that are not AC_REQUIREd.
 104 AC_DEFUN([gl_SYS_TIME_H_REQUIRE_DEFAULTS],
 105 [
 106   m4_defun(GL_MODULE_INDICATOR_PREFIX[_SYS_TIME_H_MODULE_INDICATOR_DEFAULTS], [
 107     gl_MODULE_INDICATOR_INIT_VARIABLE([GNULIB_GETTIMEOFDAY])
 108   ])
 109   m4_require(GL_MODULE_INDICATOR_PREFIX[_SYS_TIME_H_MODULE_INDICATOR_DEFAULTS])
 110   AC_REQUIRE([gl_SYS_TIME_H_DEFAULTS])
 111 ])
 112
 113 AC_DEFUN([gl_SYS_TIME_H_DEFAULTS],
 114 [
 115   dnl Assume POSIX behavior unless another module says otherwise.
 116   HAVE_GETTIMEOFDAY=1;       AC_SUBST([HAVE_GETTIMEOFDAY])
 117   HAVE_STRUCT_TIMEVAL=1;     AC_SUBST([HAVE_STRUCT_TIMEVAL])
 118   HAVE_SYS_TIME_H=1;         AC_SUBST([HAVE_SYS_TIME_H])
 119   REPLACE_GETTIMEOFDAY=0;    AC_SUBST([REPLACE_GETTIMEOFDAY])
 120   REPLACE_STRUCT_TIMEVAL=0;  AC_SUBST([REPLACE_STRUCT_TIMEVAL])
 121 ])