m4/signal_h.m4

   1 # signal_h.m4
   2 # serial 22
   3 dnl Copyright (C) 2007-2024 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 AC_DEFUN_ONCE([gl_SIGNAL_H],
   9 [
  10   AC_REQUIRE([gl_SIGNAL_H_DEFAULTS])
  11   AC_REQUIRE([gl_CHECK_TYPE_SIGSET_T])
  12   gl_NEXT_HEADERS([signal.h])
  13
  14 # AIX declares sig_atomic_t to already include volatile, and C89 compilers
  15 # then choke on 'volatile sig_atomic_t'.  C99 requires that it compile.
  16   AC_CHECK_TYPE([volatile sig_atomic_t], [],
  17     [HAVE_TYPE_VOLATILE_SIG_ATOMIC_T=0], [[
  18 #include <signal.h>
  19     ]])
  20
  21   dnl Ensure the type pid_t gets defined.
  22   AC_REQUIRE([AC_TYPE_PID_T])
  23
  24   AC_REQUIRE([AC_TYPE_UID_T])
  25
  26   dnl Persuade glibc <signal.h> to define sighandler_t.
  27   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  28   AC_CHECK_TYPE([sighandler_t], [], [HAVE_SIGHANDLER_T=0], [[
  29 #include <signal.h>
  30     ]])
  31
  32   dnl Check for declarations of anything we want to poison if the
  33   dnl corresponding gnulib module is not in use.
  34   gl_WARN_ON_USE_PREPARE([[#include <signal.h>
  35     ]], [pthread_sigmask sigaction
  36     sigaddset sigdelset sigemptyset sigfillset sigismember
  37     sigpending sigprocmask])
  38
  39   AC_REQUIRE([AC_C_RESTRICT])
  40 ])
  41
  42 AC_DEFUN([gl_CHECK_TYPE_SIGSET_T],
  43 [
  44   AC_CHECK_TYPES([sigset_t],
  45     [gl_cv_type_sigset_t=yes], [gl_cv_type_sigset_t=no],
  46     [[
  47       #include <signal.h>
  48       /* Mingw defines sigset_t not in <signal.h>, but in <sys/types.h>.  */
  49       #include <sys/types.h>
  50     ]])
  51   if test $gl_cv_type_sigset_t != yes; then
  52     HAVE_SIGSET_T=0
  53   fi
  54 ])
  55
  56 # gl_SIGNAL_MODULE_INDICATOR([modulename])
  57 # sets the shell variable that indicates the presence of the given module
  58 # to a C preprocessor expression that will evaluate to 1.
  59 # This macro invocation must not occur in macros that are AC_REQUIREd.
  60 AC_DEFUN([gl_SIGNAL_MODULE_INDICATOR],
  61 [
  62   dnl Ensure to expand the default settings once only.
  63   gl_SIGNAL_H_REQUIRE_DEFAULTS
  64   gl_MODULE_INDICATOR_SET_VARIABLE([$1])
  65   dnl Define it also as a C macro, for the benefit of the unit tests.
  66   gl_MODULE_INDICATOR_FOR_TESTS([$1])
  67 ])
  68
  69 # Initializes the default values for AC_SUBSTed shell variables.
  70 # This macro must not be AC_REQUIREd.  It must only be invoked, and only
  71 # outside of macros or in macros that are not AC_REQUIREd.
  72 AC_DEFUN([gl_SIGNAL_H_REQUIRE_DEFAULTS],
  73 [
  74   m4_defun(GL_MODULE_INDICATOR_PREFIX[_SIGNAL_H_MODULE_INDICATOR_DEFAULTS], [
  75     gl_MODULE_INDICATOR_INIT_VARIABLE([GNULIB_PTHREAD_SIGMASK])
  76     gl_MODULE_INDICATOR_INIT_VARIABLE([GNULIB_RAISE])
  77     gl_MODULE_INDICATOR_INIT_VARIABLE([GNULIB_SIGNAL_H_SIGPIPE])
  78     gl_MODULE_INDICATOR_INIT_VARIABLE([GNULIB_SIGPROCMASK])
  79     gl_MODULE_INDICATOR_INIT_VARIABLE([GNULIB_SIGACTION])
  80   ])
  81   m4_require(GL_MODULE_INDICATOR_PREFIX[_SIGNAL_H_MODULE_INDICATOR_DEFAULTS])
  82   AC_REQUIRE([gl_SIGNAL_H_DEFAULTS])
  83 ])
  84
  85 AC_DEFUN([gl_SIGNAL_H_DEFAULTS],
  86 [
  87   dnl Assume proper GNU behavior unless another module says otherwise.
  88   HAVE_POSIX_SIGNALBLOCKING=1; AC_SUBST([HAVE_POSIX_SIGNALBLOCKING])
  89   HAVE_PTHREAD_SIGMASK=1;      AC_SUBST([HAVE_PTHREAD_SIGMASK])
  90   HAVE_RAISE=1;                AC_SUBST([HAVE_RAISE])
  91   HAVE_SIGSET_T=1;             AC_SUBST([HAVE_SIGSET_T])
  92   HAVE_SIGINFO_T=1;            AC_SUBST([HAVE_SIGINFO_T])
  93   HAVE_SIGACTION=1;            AC_SUBST([HAVE_SIGACTION])
  94   HAVE_STRUCT_SIGACTION_SA_SIGACTION=1;
  95                                AC_SUBST([HAVE_STRUCT_SIGACTION_SA_SIGACTION])
  96   HAVE_TYPE_VOLATILE_SIG_ATOMIC_T=1;
  97                                AC_SUBST([HAVE_TYPE_VOLATILE_SIG_ATOMIC_T])
  98   HAVE_SIGHANDLER_T=1;         AC_SUBST([HAVE_SIGHANDLER_T])
  99   REPLACE_PTHREAD_SIGMASK=0;   AC_SUBST([REPLACE_PTHREAD_SIGMASK])
 100   REPLACE_RAISE=0;             AC_SUBST([REPLACE_RAISE])
 101 ])