m4/readline.m4

   1 # readline.m4
   2 # serial 11
   3 dnl Copyright (C) 2005-2006, 2009-2024 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 dnl Written by Simon Josefsson, with help from Bruno Haible and Oskar
   9 dnl Liljeblad.
  10
  11 AC_DEFUN([gl_FUNC_READLINE],
  12 [
  13   dnl Prerequisites of AC_LIB_LINKFLAGS_BODY.
  14   AC_REQUIRE([AC_LIB_PREPARE_PREFIX])
  15   AC_REQUIRE([AC_LIB_RPATH])
  16
  17   dnl Search for libreadline and define LIBREADLINE, LTLIBREADLINE and
  18   dnl INCREADLINE accordingly.
  19   AC_LIB_LINKFLAGS_BODY([readline])
  20
  21   dnl Add $INCREADLINE to CPPFLAGS before performing the following checks,
  22   dnl because if the user has installed libreadline and not disabled its use
  23   dnl via --without-libreadline-prefix, he wants to use it. The AC_LINK_IFELSE
  24   dnl will then succeed.
  25   gl_saved_CPPFLAGS="$CPPFLAGS"
  26   AC_LIB_APPENDTOVAR([CPPFLAGS], [$INCREADLINE])
  27
  28   AC_CACHE_CHECK([for readline], [gl_cv_lib_readline], [
  29     gl_cv_lib_readline=no
  30     gl_saved_LIBS="$LIBS"
  31     dnl On some systems, -lreadline doesn't link without an additional
  32     dnl -lncurses or -ltermcap.
  33     dnl Try -lncurses before -ltermcap, because libtermcap is insecure
  34     dnl by design and obsolete since 1994. Try -lcurses last, because
  35     dnl libcurses is unusable on some old Unices.
  36     for extra_lib in "" ncurses termcap curses; do
  37       LIBS="$gl_saved_LIBS $LIBREADLINE"
  38       if test -n "$extra_lib"; then
  39         LIBS="$LIBS -l$extra_lib"
  40       fi
  41       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
  42 #include <readline/readline.h>]],
  43           [[readline((char*)0);]])],
  44         [if test -n "$extra_lib"; then
  45            gl_cv_lib_readline="yes, requires -l$extra_lib"
  46          else
  47            gl_cv_lib_readline="yes"
  48          fi
  49         ])
  50       if test "$gl_cv_lib_readline" != no; then
  51         break
  52       fi
  53     done
  54     LIBS="$gl_saved_LIBS"
  55   ])
  56
  57   if test "$gl_cv_lib_readline" != no; then
  58     AC_DEFINE([HAVE_READLINE], [1], [Define if you have the readline library.])
  59     extra_lib=`echo "$gl_cv_lib_readline" | sed -n -e 's/yes, requires //p'`
  60     if test -n "$extra_lib"; then
  61       LIBREADLINE="$LIBREADLINE $extra_lib"
  62       LTLIBREADLINE="$LTLIBREADLINE $extra_lib"
  63     fi
  64     AC_MSG_CHECKING([how to link with libreadline])
  65     AC_MSG_RESULT([$LIBREADLINE])
  66   else
  67     dnl If $LIBREADLINE didn't lead to a usable library, we don't
  68     dnl need $INCREADLINE either.
  69     CPPFLAGS="$gl_saved_CPPFLAGS"
  70     LIBREADLINE=
  71     LTLIBREADLINE=
  72   fi
  73   AC_SUBST([LIBREADLINE])
  74   AC_SUBST([LTLIBREADLINE])
  75
  76   AC_CHECK_HEADERS([readline/readline.h readline/history.h])
  77 ])
  78
  79 # Prerequisites of lib/readline.c.
  80 AC_DEFUN([gl_PREREQ_READLINE], [
  81   :
  82 ])