m4/locale-tr.m4

   1 # locale-tr.m4
   2 # serial 16
   3 dnl Copyright (C) 2003, 2005-2024 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 dnl From Bruno Haible.
   9
  10 dnl Determine the name of a turkish locale with UTF-8 encoding.
  11 AC_DEFUN_ONCE([gt_LOCALE_TR_UTF8],
  12 [
  13   AC_REQUIRE([AC_CANONICAL_HOST])
  14   AC_REQUIRE([AM_LANGINFO_CODESET])
  15   AC_CACHE_CHECK([for a turkish Unicode locale], [gt_cv_locale_tr_utf8], [
  16     AC_LANG_CONFTEST([AC_LANG_SOURCE([[
  17 #include <locale.h>
  18 #include <time.h>
  19 #if HAVE_LANGINFO_CODESET
  20 # include <langinfo.h>
  21 #endif
  22 #include <stdlib.h>
  23 #include <string.h>
  24 #include <wctype.h>
  25 struct tm t;
  26 char buf[16];
  27 int main () {
  28   /* On BeOS, locales are not implemented in libc.  Rather, libintl
  29      imitates locale dependent behaviour by looking at the environment
  30      variables, and all locales use the UTF-8 encoding.  But BeOS does not
  31      implement the Turkish upper-/lowercase mappings.  Therefore, let this
  32      program return 1 on BeOS.  */
  33   /* Check whether the given locale name is recognized by the system.  */
  34 #if defined _WIN32 && !defined __CYGWIN__
  35   /* On native Windows, setlocale(category, "") looks at the system settings,
  36      not at the environment variables.  Also, when an encoding suffix such
  37      as ".65001" or ".54936" is specified, it succeeds but sets the LC_CTYPE
  38      category of the locale to "C".  */
  39   if (setlocale (LC_ALL, getenv ("LC_ALL")) == NULL
  40       || strcmp (setlocale (LC_CTYPE, NULL), "C") == 0)
  41     return 1;
  42 #else
  43   if (setlocale (LC_ALL, "") == NULL) return 1;
  44 #endif
  45   /* Check whether nl_langinfo(CODESET) is nonempty and not "ASCII" or "646".
  46      On Mac OS X 10.3.5 (Darwin 7.5) in the tr_TR locale, nl_langinfo(CODESET)
  47      is empty, and the behaviour of Tcl 8.4 in this locale is not useful.
  48      On OpenBSD 4.0, when an unsupported locale is specified, setlocale()
  49      succeeds but then nl_langinfo(CODESET) is "646". In this situation,
  50      some unit tests fail.  */
  51 #if HAVE_LANGINFO_CODESET
  52   {
  53     const char *cs = nl_langinfo (CODESET);
  54     if (cs[0] == '\0' || strcmp (cs, "ASCII") == 0 || strcmp (cs, "646") == 0)
  55       return 1;
  56   }
  57 #endif
  58 #ifdef __CYGWIN__
  59   /* On Cygwin, avoid locale names without encoding suffix, because the
  60      locale_charset() function relies on the encoding suffix.  Note that
  61      LC_ALL is set on the command line.  */
  62   if (strchr (getenv ("LC_ALL"), '.') == NULL) return 1;
  63 #endif
  64   /* Check whether in the abbreviation of the eighth month, the second
  65      character (should be U+011F: LATIN SMALL LETTER G WITH BREVE) is
  66      two bytes long, with UTF-8 encoding.  */
  67   t.tm_year = 1992 - 1900; t.tm_mon = 8 - 1; t.tm_mday = 19;
  68   if (strftime (buf, sizeof (buf), "%b", &t) < 4
  69       || buf[1] != (char) 0xc4 || buf[2] != (char) 0x9f)
  70     return 1;
  71   /* Check whether the upper-/lowercase mappings are as expected for
  72      Turkish.  */
  73   if (towupper ('i') != 0x0130 || towlower (0x0130) != 'i'
  74       || towupper(0x0131) != 'I' || towlower ('I') != 0x0131)
  75     return 1;
  76   return 0;
  77 }
  78       ]])])
  79     if AC_TRY_EVAL([ac_link]) && test -s conftest$ac_exeext; then
  80       case "$host_os" in
  81         # Handle native Windows specially, because there setlocale() interprets
  82         # "ar" or "ara" as "Arabic" or "Arabic_Saudi Arabia.1256",
  83         # "en" or "eng" as "English" or "English_United States.1252",
  84         # "fr" or "fra" as "French" or "French_France.1252",
  85         # "ge"(!) or "deu"(!) as "German" or "German_Germany.1252",
  86         # "ja" or "jpn" as "Japanese" or "Japanese_Japan.932",
  87         # and similar.
  88         mingw* | windows*)
  89           # Test for the hypothetical native Windows locale name.
  90           if (LC_ALL=Turkish_Turkey.65001 LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  91             gt_cv_locale_tr_utf8=Turkish_Turkey.65001
  92           else
  93             # None found.
  94             gt_cv_locale_tr_utf8=none
  95           fi
  96           ;;
  97         *)
  98           # Setting LC_ALL is not enough. Need to set LC_TIME to empty, because
  99           # otherwise on Mac OS X 10.3.5 the LC_TIME=C from the beginning of the
 100           # configure script would override the LC_ALL setting. Likewise for
 101           # LC_CTYPE, which is also set at the beginning of the configure script.
 102           # Test for the usual locale name.
 103           if (LC_ALL=tr_TR LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
 104             gt_cv_locale_tr_utf8=tr_TR
 105           else
 106             # Test for the locale name with explicit encoding suffix.
 107             if (LC_ALL=tr_TR.UTF-8 LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
 108               gt_cv_locale_tr_utf8=tr_TR.UTF-8
 109             else
 110               # Test for the Solaris 10 locale name.
 111               if (LC_ALL=tr.UTF-8 LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
 112                 gt_cv_locale_tr_utf8=tr.UTF-8
 113               else
 114                 # None found.
 115                 gt_cv_locale_tr_utf8=none
 116               fi
 117             fi
 118           fi
 119           ;;
 120       esac
 121     else
 122       gt_cv_locale_tr_utf8=none
 123     fi
 124     rm -fr conftest*
 125   ])
 126   LOCALE_TR_UTF8=$gt_cv_locale_tr_utf8
 127   case $LOCALE_TR_UTF8 in #(
 128     '' | *[[[:space:]\"\$\'*@<:@]]*)
 129       dnl This locale name might cause trouble with sh or make.
 130       AC_MSG_WARN([invalid locale "$LOCALE_TR_UTF8"; assuming "none"])
 131       LOCALE_TR_UTF8=none;;
 132   esac
 133   AC_SUBST([LOCALE_TR_UTF8])
 134 ])