m4/javaexec.m4

   1 # javaexec.m4
   2 # serial 11
   3 dnl Copyright (C) 2001-2003, 2006, 2009-2024 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 # Prerequisites of javaexec.sh.
   9 # gt_JAVAEXEC or gt_JAVAEXEC(testclass, its-directory)
  10 # Sets HAVE_JAVAEXEC to nonempty if javaexec.sh will work.
  11
  12 AC_DEFUN([gt_JAVAEXEC],
  13 [
  14   AC_MSG_CHECKING([for Java virtual machine])
  15   AC_EGREP_CPP([yes], [
  16 #if defined _WIN32 || defined __CYGWIN__ || defined __EMX__ || defined __DJGPP__
  17   yes
  18 #endif
  19 ], CLASSPATH_SEPARATOR=';', CLASSPATH_SEPARATOR=':')
  20   CONF_JAVA=
  21   HAVE_JAVA_ENVVAR=
  22   HAVE_JAVA=
  23   HAVE_JRE=
  24   HAVE_JAVAEXEC=1
  25   if test -n "$JAVA"; then
  26     HAVE_JAVA_ENVVAR=1
  27     CONF_JAVA="$JAVA"
  28   else
  29     pushdef([AC_MSG_CHECKING],[:])dnl
  30     pushdef([AC_CHECKING],[:])dnl
  31     pushdef([AC_MSG_RESULT],[:])dnl
  32     AC_CHECK_PROG([HAVE_JAVA_IN_PATH], [java], [yes])
  33     AC_CHECK_PROG([HAVE_JRE_IN_PATH], [jre], [yes])
  34     popdef([AC_MSG_RESULT])dnl
  35     popdef([AC_CHECKING])dnl
  36     popdef([AC_MSG_CHECKING])dnl
  37     m4_if([$1], , , [
  38       gt_saved_CLASSPATH="$CLASSPATH"
  39       CLASSPATH="$2"${CLASSPATH+"$CLASSPATH_SEPARATOR$CLASSPATH"}
  40       ])
  41     export CLASSPATH
  42     if test -n "$HAVE_JAVA_IN_PATH" \
  43        && java -version >/dev/null 2>/dev/null \
  44        m4_if([$1], , , [&& {
  45          echo "$as_me:__oline__: java $1" >&AS_MESSAGE_LOG_FD
  46          java $1 >&AS_MESSAGE_LOG_FD 2>&1
  47        }]); then
  48       HAVE_JAVA=1
  49       CONF_JAVA="java"
  50     else
  51       if test -n "$HAVE_JRE_IN_PATH" \
  52          && (jre >/dev/null 2>/dev/null || test $? = 1) \
  53          m4_if([$1], , , [&& {
  54            echo "$as_me:__oline__: jre $1" >&AS_MESSAGE_LOG_FD
  55            jre $1 >&AS_MESSAGE_LOG_FD 2>&1
  56          }]); then
  57         HAVE_JRE=1
  58         CONF_JAVA="jre"
  59       else
  60         HAVE_JAVAEXEC=
  61       fi
  62     fi
  63     m4_if([$1], , , [
  64       CLASSPATH="$gt_saved_CLASSPATH"
  65     ])
  66   fi
  67   if test -n "$HAVE_JAVAEXEC"; then
  68     ac_result="$CONF_JAVA"
  69   else
  70     ac_result="no"
  71   fi
  72   AC_MSG_RESULT([$ac_result])
  73   AC_SUBST([CONF_JAVA])
  74   AC_SUBST([CLASSPATH])
  75   AC_SUBST([CLASSPATH_SEPARATOR])
  76   AC_SUBST([HAVE_JAVA_ENVVAR])
  77   AC_SUBST([HAVE_JAVA])
  78   AC_SUBST([HAVE_JRE])
  79 ])
  80
  81 # Simulates gt_JAVAEXEC when no Java support is desired.
  82 AC_DEFUN([gt_JAVAEXEC_DISABLED],
  83 [
  84   CONF_JAVA=
  85   HAVE_JAVA_ENVVAR=
  86   HAVE_JAVA=
  87   HAVE_JRE=
  88   AC_SUBST([CONF_JAVA])
  89   AC_SUBST([HAVE_JAVA_ENVVAR])
  90   AC_SUBST([HAVE_JAVA])
  91   AC_SUBST([HAVE_JRE])
  92 ])