m4/configmake.m4

   1 # configmake.m4
   2 # serial 6
   3 dnl Copyright (C) 2010-2024 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 AC_PREREQ([2.60])
   9
  10 # gl_CONFIGMAKE_PREP
  11 # ------------------
  12 # Guarantee all of the standard directory variables, even when used with
  13 # autoconf 2.64 (runstatedir wasn't supported before 2.70) or
  14 # automake 1.11 (runstatedir isn't supported even in 1.16.1).
  15 AC_DEFUN([gl_CONFIGMAKE_PREP],
  16 [
  17   if test "x$lispdir" = x; then
  18     AC_SUBST([lispdir], ['${datarootdir}/emacs/site-lisp'])
  19   fi
  20   dnl Added in autoconf 2.70.
  21   if test "x$runstatedir" = x; then
  22     AC_SUBST([runstatedir], ['${localstatedir}/run'])
  23   fi
  24
  25   dnl Automake 1.11 provides the pkg*dir variables merely without AC_SUBST,
  26   dnl that is, only at the Makefile.am level.  AC_SUBST them, so that
  27   dnl gl_CONFIGMAKE can compute the final values at configure time.
  28   dnl Blindly assigning the value at configure time is OK, since configure
  29   dnl does not have --pkg*dir=... options.
  30   AC_SUBST([pkgdatadir], ['${datadir}/${PACKAGE}'])
  31   AC_SUBST([pkgincludedir], ['${includedir}/${PACKAGE}'])
  32   AC_SUBST([pkglibdir], ['${libdir}/${PACKAGE}'])
  33   AC_SUBST([pkglibexecdir], ['${libexecdir}/${PACKAGE}'])
  34 ])
  35
  36 # gl_CONFIGMAKE
  37 # -------------
  38 # Find the final values of the standard directory variables, and create
  39 # AC_SUBSTed *_c and *_c_make variables with the corresponding values in
  40 # target runtime environment ($host_os) syntax.
  41 AC_DEFUN([gl_CONFIGMAKE],
  42 [
  43   AC_REQUIRE([gl_CONFIGMAKE_PREP])
  44
  45   dnl Save the values.
  46   gl_saved_prefix="${prefix}"
  47   gl_saved_exec_prefix="${exec_prefix}"
  48   gl_saved_bindir="${bindir}"
  49   gl_saved_sbindir="${sbindir}"
  50   gl_saved_libexecdir="${libexecdir}"
  51   gl_saved_datarootdir="${datarootdir}"
  52   gl_saved_datadir="${datadir}"
  53   gl_saved_sysconfdir="${sysconfdir}"
  54   gl_saved_sharedstatedir="${sharedstatedir}"
  55   gl_saved_localstatedir="${localstatedir}"
  56   gl_saved_runstatedir="${runstatedir}"
  57   gl_saved_includedir="${includedir}"
  58   gl_saved_oldincludedir="${oldincludedir}"
  59   gl_saved_docdir="${docdir}"
  60   gl_saved_infodir="${infodir}"
  61   gl_saved_htmldir="${htmldir}"
  62   gl_saved_dvidir="${dvidir}"
  63   gl_saved_pdfdir="${pdfdir}"
  64   gl_saved_psdir="${psdir}"
  65   gl_saved_libdir="${libdir}"
  66   gl_saved_lispdir="${lispdir}"
  67   gl_saved_localedir="${localedir}"
  68   gl_saved_mandir="${mandir}"
  69   gl_saved_pkgdatadir="${pkgdatadir}"
  70   gl_saved_pkgincludedir="${pkgincludedir}"
  71   gl_saved_pkglibdir="${pkglibdir}"
  72   gl_saved_pkglibexecdir="${pkglibexecdir}"
  73
  74   dnl Find the final values.
  75   dnl Unfortunately, prefix gets only finally determined at the end of
  76   dnl configure.
  77   if test "X$prefix" = "XNONE"; then
  78     prefix="$ac_default_prefix"
  79   fi
  80   dnl Unfortunately, exec_prefix gets only finally determined at the end of
  81   dnl configure.
  82   if test "X$exec_prefix" = "XNONE"; then
  83     exec_prefix='${prefix}'
  84   fi
  85   eval exec_prefix="$exec_prefix"
  86   eval bindir="$bindir"
  87   eval sbindir="$sbindir"
  88   eval libexecdir="$libexecdir"
  89   eval datarootdir="$datarootdir"
  90   eval datadir="$datadir"
  91   eval sysconfdir="$sysconfdir"
  92   eval sharedstatedir="$sharedstatedir"
  93   eval localstatedir="$localstatedir"
  94   eval runstatedir="$runstatedir"
  95   eval includedir="$includedir"
  96   eval oldincludedir="$oldincludedir"
  97   eval docdir="$docdir"
  98   eval infodir="$infodir"
  99   eval htmldir="$htmldir"
 100   eval dvidir="$dvidir"
 101   eval pdfdir="$pdfdir"
 102   eval psdir="$psdir"
 103   eval libdir="$libdir"
 104   eval lispdir="$lispdir"
 105   eval localedir="$localedir"
 106   eval mandir="$mandir"
 107   eval pkgdatadir="$pkgdatadir"
 108   eval pkgincludedir="$pkgincludedir"
 109   eval pkglibdir="$pkglibdir"
 110   eval pkglibexecdir="$pkglibexecdir"
 111
 112   dnl Transform the final values.
 113   gl_BUILD_TO_HOST([prefix])
 114   gl_BUILD_TO_HOST([exec_prefix])
 115   gl_BUILD_TO_HOST([bindir])
 116   gl_BUILD_TO_HOST([sbindir])
 117   gl_BUILD_TO_HOST([libexecdir])
 118   gl_BUILD_TO_HOST([datarootdir])
 119   gl_BUILD_TO_HOST([datadir])
 120   gl_BUILD_TO_HOST([sysconfdir])
 121   gl_BUILD_TO_HOST([sharedstatedir])
 122   gl_BUILD_TO_HOST([localstatedir])
 123   gl_BUILD_TO_HOST([runstatedir])
 124   gl_BUILD_TO_HOST([includedir])
 125   gl_BUILD_TO_HOST([oldincludedir])
 126   gl_BUILD_TO_HOST([docdir])
 127   gl_BUILD_TO_HOST([infodir])
 128   gl_BUILD_TO_HOST([htmldir])
 129   gl_BUILD_TO_HOST([dvidir])
 130   gl_BUILD_TO_HOST([pdfdir])
 131   gl_BUILD_TO_HOST([psdir])
 132   gl_BUILD_TO_HOST([libdir])
 133   gl_BUILD_TO_HOST([lispdir])
 134   gl_BUILD_TO_HOST([localedir])
 135   gl_BUILD_TO_HOST([mandir])
 136   gl_BUILD_TO_HOST([pkgdatadir])
 137   gl_BUILD_TO_HOST([pkgincludedir])
 138   gl_BUILD_TO_HOST([pkglibdir])
 139   gl_BUILD_TO_HOST([pkglibexecdir])
 140
 141   dnl Restore the values.
 142   pkglibexecdir="${gl_saved_pkglibexecdir}"
 143   pkglibdir="${gl_saved_pkglibdir}"
 144   pkgincludedir="${gl_saved_pkgincludedir}"
 145   pkgdatadir="${gl_saved_pkgdatadir}"
 146   mandir="${gl_saved_mandir}"
 147   localedir="${gl_saved_localedir}"
 148   lispdir="${gl_saved_lispdir}"
 149   libdir="${gl_saved_libdir}"
 150   psdir="${gl_saved_psdir}"
 151   pdfdir="${gl_saved_pdfdir}"
 152   dvidir="${gl_saved_dvidir}"
 153   htmldir="${gl_saved_htmldir}"
 154   infodir="${gl_saved_infodir}"
 155   docdir="${gl_saved_docdir}"
 156   oldincludedir="${gl_saved_oldincludedir}"
 157   includedir="${gl_saved_includedir}"
 158   runstatedir="${gl_saved_runstatedir}"
 159   localstatedir="${gl_saved_localstatedir}"
 160   sharedstatedir="${gl_saved_sharedstatedir}"
 161   sysconfdir="${gl_saved_sysconfdir}"
 162   datadir="${gl_saved_datadir}"
 163   datarootdir="${gl_saved_datarootdir}"
 164   libexecdir="${gl_saved_libexecdir}"
 165   sbindir="${gl_saved_sbindir}"
 166   bindir="${gl_saved_bindir}"
 167   exec_prefix="${gl_saved_exec_prefix}"
 168   prefix="${gl_saved_prefix}"
 169 ])