m4/atanf.m4

   1 # atanf.m4
   2 # serial 4
   3 dnl Copyright (C) 2011-2024 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 AC_DEFUN([gl_FUNC_ATANF],
   9 [
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11   AC_REQUIRE([gl_FUNC_ATAN])
  12
  13   dnl Persuade glibc <math.h> to declare atanf().
  14   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  15
  16   dnl Test whether atanf() exists. Assume that atanf(), if it exists, is
  17   dnl defined in the same library as atan().
  18   saved_LIBS="$LIBS"
  19   LIBS="$LIBS $ATAN_LIBM"
  20   AC_CHECK_FUNCS([atanf])
  21   LIBS="$saved_LIBS"
  22   if test $ac_cv_func_atanf = yes; then
  23     ATANF_LIBM="$ATAN_LIBM"
  24   else
  25     HAVE_ATANF=0
  26     dnl If the function is declared but does not appear to exist, it may be
  27     dnl defined as an inline function. In order to avoid a conflict, we have
  28     dnl to define rpl_atanf, not atanf.
  29     AC_CHECK_DECLS([atanf], [REPLACE_ATANF=1], , [[#include <math.h>]])
  30     ATANF_LIBM="$ATAN_LIBM"
  31   fi
  32   AC_SUBST([ATANF_LIBM])
  33 ])