m4/asinl.m4

   1 # asinl.m4
   2 # serial 10
   3 dnl Copyright (C) 2010-2024 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 AC_DEFUN([gl_FUNC_ASINL],
   9 [
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11   AC_REQUIRE([gl_LONG_DOUBLE_VS_DOUBLE])
  12
  13   dnl Persuade glibc <math.h> to declare asinl().
  14   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  15
  16   ASINL_LIBM=
  17   AC_CACHE_CHECK([whether asinl() can be used without linking with libm],
  18     [gl_cv_func_asinl_no_libm],
  19     [
  20       AC_LINK_IFELSE(
  21         [AC_LANG_PROGRAM(
  22            [[#ifndef __NO_MATH_INLINES
  23              # define __NO_MATH_INLINES 1 /* for glibc */
  24              #endif
  25              #include <math.h>
  26              long double (* volatile funcptr) (long double) = asinl;
  27              long double x;]],
  28            [[return funcptr (x) > 1
  29                     || asinl (x) > 1;]])],
  30         [gl_cv_func_asinl_no_libm=yes],
  31         [gl_cv_func_asinl_no_libm=no])
  32     ])
  33   if test $gl_cv_func_asinl_no_libm = no; then
  34     AC_CACHE_CHECK([whether asinl() can be used with libm],
  35       [gl_cv_func_asinl_in_libm],
  36       [
  37         saved_LIBS="$LIBS"
  38         LIBS="$LIBS -lm"
  39         AC_LINK_IFELSE(
  40           [AC_LANG_PROGRAM(
  41              [[#ifndef __NO_MATH_INLINES
  42                # define __NO_MATH_INLINES 1 /* for glibc */
  43                #endif
  44                #include <math.h>
  45                long double (* volatile funcptr) (long double) = asinl;
  46                long double x;]],
  47              [[return funcptr (x) > 1
  48                       || asinl (x) > 1;]])],
  49           [gl_cv_func_asinl_in_libm=yes],
  50           [gl_cv_func_asinl_in_libm=no])
  51         LIBS="$saved_LIBS"
  52       ])
  53     if test $gl_cv_func_asinl_in_libm = yes; then
  54       ASINL_LIBM=-lm
  55     fi
  56   fi
  57   if test $gl_cv_func_asinl_no_libm = yes \
  58      || test $gl_cv_func_asinl_in_libm = yes; then
  59     dnl Also check whether it's declared.
  60     dnl Mac OS X 10.3 has asinl() in libc but doesn't declare it in <math.h>.
  61     AC_CHECK_DECL([asinl], , [HAVE_DECL_ASINL=0], [[#include <math.h>]])
  62   else
  63     HAVE_DECL_ASINL=0
  64     HAVE_ASINL=0
  65     dnl Find libraries needed to link lib/asinl.c.
  66     if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
  67       AC_REQUIRE([gl_FUNC_ASIN])
  68       ASINL_LIBM="$ASIN_LIBM"
  69     else
  70       AC_REQUIRE([gl_FUNC_SQRTL])
  71       dnl Append $SQRTL_LIBM to ASINL_LIBM, avoiding gratuitous duplicates.
  72       case " $ASINL_LIBM " in
  73         *" $SQRTL_LIBM "*) ;;
  74         *) ASINL_LIBM="$ASINL_LIBM $SQRTL_LIBM" ;;
  75       esac
  76     fi
  77   fi
  78   AC_SUBST([ASINL_LIBM])
  79 ])