m4/poll.m4

   1 # poll.m4 serial 18
   2 dnl Copyright (c) 2003, 2005-2007, 2009-2017 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_POLL],
   8 [
   9   AC_REQUIRE([gl_POLL_H])
  10   AC_REQUIRE([gl_SOCKETS])
  11   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  12   if test $ac_cv_header_poll_h = no; then
  13     ac_cv_func_poll=no
  14     gl_cv_func_poll=no
  15   else
  16     AC_CHECK_FUNC([poll],
  17       [# Check whether poll() works on special files (like /dev/null) and
  18        # and ttys (like /dev/tty). On Mac OS X 10.4.0 and AIX 5.3, it doesn't.
  19        AC_RUN_IFELSE([AC_LANG_SOURCE([[
  20 #include <fcntl.h>
  21 #include <poll.h>
  22          int main()
  23          {
  24            int result = 0;
  25            struct pollfd ufd;
  26            /* Try /dev/null for reading.  */
  27            ufd.fd = open ("/dev/null", O_RDONLY);
  28            /* If /dev/null does not exist, it's not Mac OS X nor AIX. */
  29            if (ufd.fd >= 0)
  30              {
  31                ufd.events = POLLIN;
  32                ufd.revents = 0;
  33                if (!(poll (&ufd, 1, 0) == 1 && ufd.revents == POLLIN))
  34                  result |= 1;
  35              }
  36            /* Try /dev/null for writing.  */
  37            ufd.fd = open ("/dev/null", O_WRONLY);
  38            /* If /dev/null does not exist, it's not Mac OS X nor AIX. */
  39            if (ufd.fd >= 0)
  40              {
  41                ufd.events = POLLOUT;
  42                ufd.revents = 0;
  43                if (!(poll (&ufd, 1, 0) == 1 && ufd.revents == POLLOUT))
  44                  result |= 2;
  45              }
  46            /* Trying /dev/tty may be too environment dependent.  */
  47            return result;
  48          }]])],
  49          [gl_cv_func_poll=yes],
  50          [gl_cv_func_poll=no],
  51          [# When cross-compiling, assume that poll() works everywhere except on
  52           # Mac OS X or AIX, regardless of its version.
  53           AC_EGREP_CPP([MacOSX], [
  54 #if (defined(__APPLE__) && defined(__MACH__)) || defined(_AIX)
  55 This is MacOSX or AIX
  56 #endif
  57 ], [gl_cv_func_poll=no], [gl_cv_func_poll=yes])])])
  58   fi
  59   if test $gl_cv_func_poll != yes; then
  60     AC_CHECK_FUNC([poll], [ac_cv_func_poll=yes], [ac_cv_func_poll=no])
  61     if test $ac_cv_func_poll = no; then
  62       HAVE_POLL=0
  63     else
  64       REPLACE_POLL=1
  65     fi
  66   fi
  67   if test $HAVE_POLL = 0 || test $REPLACE_POLL = 1; then
  68     :
  69   else
  70     AC_DEFINE([HAVE_POLL], [1],
  71       [Define to 1 if you have the 'poll' function and it works.])
  72   fi
  73
  74   dnl Determine the needed libraries.
  75   LIB_POLL="$LIBSOCKET"
  76   if test $HAVE_POLL = 0 || test $REPLACE_POLL = 1; then
  77     case "$host_os" in
  78       mingw*)
  79         dnl On the MSVC platform, the function MsgWaitForMultipleObjects
  80         dnl (used in lib/poll.c) requires linking with -luser32. On mingw,
  81         dnl it is implicit.
  82         AC_LINK_IFELSE(
  83           [AC_LANG_SOURCE([[
  84 #define WIN32_LEAN_AND_MEAN
  85 #include <windows.h>
  86 int
  87 main ()
  88 {
  89   MsgWaitForMultipleObjects (0, NULL, 0, 0, 0);
  90   return 0;
  91 }]])],
  92           [],
  93           [LIB_POLL="$LIB_POLL -luser32"])
  94         ;;
  95     esac
  96   fi
  97   AC_SUBST([LIB_POLL])
  98 ])
  99
 100 # Prerequisites of lib/poll.c.
 101 AC_DEFUN([gl_PREREQ_POLL],
 102 [
 103   AC_CHECK_HEADERS_ONCE([sys/ioctl.h sys/filio.h])
 104 ])