m4/log1pl.m4

   1 # log1pl.m4 serial 4
   2 dnl Copyright (C) 2012-2017 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_LOG1PL],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_log1pl_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11   AC_REQUIRE([gl_LONG_DOUBLE_VS_DOUBLE])
  12   AC_REQUIRE([gl_FUNC_LOG1P])
  13
  14   dnl Persuade glibc <math.h> to declare log1pl().
  15   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  16
  17   dnl Test whether log1pl() exists. Assume that log1pl(), if it exists, is
  18   dnl defined in the same library as log1p().
  19   save_LIBS="$LIBS"
  20   LIBS="$LIBS $LOG1P_LIBM"
  21   AC_CHECK_FUNCS([log1pl])
  22   LIBS="$save_LIBS"
  23   if test $ac_cv_func_log1pl = yes; then
  24     LOG1PL_LIBM="$LOG1P_LIBM"
  25     m4_ifdef([gl_FUNC_LOG1PL_IEEE], [
  26       if test $gl_log1pl_required = ieee && test $REPLACE_LOG1PL = 0; then
  27         AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  28         AC_CACHE_CHECK([whether log1pl works according to ISO C 99 with IEC 60559],
  29           [gl_cv_func_log1pl_ieee],
  30           [
  31             save_LIBS="$LIBS"
  32             LIBS="$LIBS $LOG1PL_LIBM"
  33             AC_RUN_IFELSE(
  34               [AC_LANG_SOURCE([[
  35 #ifndef __NO_MATH_INLINES
  36 # define __NO_MATH_INLINES 1 /* for glibc */
  37 #endif
  38 #include <math.h>
  39 ]gl_LONG_DOUBLE_MINUS_ZERO_CODE[
  40 ]gl_LONG_DOUBLE_SIGNBIT_CODE[
  41 static long double dummy (long double x) { return 0; }
  42 int main (int argc, char *argv[])
  43 {
  44   long double (*my_log1pl) (long double) = argc ? log1pl : dummy;
  45   /* This test fails on AIX 7.1, IRIX 6.5.  */
  46   long double y = my_log1pl (minus_zerol);
  47   if (!(y == 0.0L) || (signbitl (minus_zerol) && !signbitl (y)))
  48     return 1;
  49   return 0;
  50 }
  51               ]])],
  52               [gl_cv_func_log1pl_ieee=yes],
  53               [gl_cv_func_log1pl_ieee=no],
  54               [case "$host_os" in
  55                          # Guess yes on glibc systems.
  56                  *-gnu*) gl_cv_func_log1pl_ieee="guessing yes" ;;
  57                          # Guess yes on native Windows.
  58                  mingw*) gl_cv_func_log1pl_ieee="guessing yes" ;;
  59                          # If we don't know, assume the worst.
  60                  *)      gl_cv_func_log1pl_ieee="guessing no" ;;
  61                esac
  62               ])
  63             LIBS="$save_LIBS"
  64           ])
  65         case "$gl_cv_func_log1pl_ieee" in
  66           *yes) ;;
  67           *) REPLACE_LOG1PL=1 ;;
  68         esac
  69       fi
  70     ])
  71   else
  72     HAVE_LOG1PL=0
  73     dnl Find libraries needed to link lib/log1pl.c.
  74     if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
  75       LOG1PL_LIBM="$LOG1P_LIBM"
  76     else
  77       AC_REQUIRE([gl_FUNC_ISNANL])
  78       AC_REQUIRE([gl_FUNC_LOGL])
  79       AC_REQUIRE([gl_FUNC_ROUNDL])
  80       LOG1PL_LIBM=
  81       dnl Append $ISNANL_LIBM to LOG1PL_LIBM, avoiding gratuitous duplicates.
  82       case " $LOG1PL_LIBM " in
  83         *" $ISNANL_LIBM "*) ;;
  84         *) LOG1PL_LIBM="$LOG1PL_LIBM $ISNANL_LIBM" ;;
  85       esac
  86       dnl Append $LOGL_LIBM to LOG1PL_LIBM, avoiding gratuitous duplicates.
  87       case " $LOG1PL_LIBM " in
  88         *" $LOGL_LIBM "*) ;;
  89         *) LOG1PL_LIBM="$LOG1PL_LIBM $LOGL_LIBM" ;;
  90       esac
  91       dnl Append $ROUNDL_LIBM to LOG1PL_LIBM, avoiding gratuitous duplicates.
  92       case " $LOG1PL_LIBM " in
  93         *" $ROUNDL_LIBM "*) ;;
  94         *) LOG1PL_LIBM="$LOG1PL_LIBM $ROUNDL_LIBM" ;;
  95       esac
  96     fi
  97   fi
  98   AC_SUBST([LOG1PL_LIBM])
  99 ])