m4/link.m4

   1 # link.m4 serial 8
   2 dnl Copyright (C) 2009-2017 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_LINK],
   8 [
   9   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  10   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  11   AC_CHECK_FUNCS_ONCE([link])
  12   if test $ac_cv_func_link = no; then
  13     HAVE_LINK=0
  14   else
  15     AC_CACHE_CHECK([whether link obeys POSIX],
  16       [gl_cv_func_link_works],
  17       [touch conftest.a
  18        # Assume that if we have lstat, we can also check symlinks.
  19        if test $ac_cv_func_lstat = yes; then
  20          ln -s conftest.a conftest.lnk
  21        fi
  22        AC_RUN_IFELSE(
  23          [AC_LANG_PROGRAM(
  24            [[#include <unistd.h>
  25              #include <stdio.h>
  26            ]],
  27            [[int result = 0;
  28              if (!link ("conftest.a", "conftest.b/"))
  29                result |= 1;
  30 #if HAVE_LSTAT
  31              if (!link ("conftest.lnk/", "conftest.b"))
  32                result |= 2;
  33              if (rename ("conftest.a", "conftest.b"))
  34                result |= 4;
  35              if (!link ("conftest.b", "conftest.lnk"))
  36                result |= 8;
  37 #endif
  38              return result;
  39            ]])],
  40          [gl_cv_func_link_works=yes], [gl_cv_func_link_works=no],
  41          [case "$host_os" in
  42                     # Guess yes on glibc systems.
  43             *-gnu*) gl_cv_func_link_works="guessing yes" ;;
  44                     # If we don't know, assume the worst.
  45             *)      gl_cv_func_link_works="guessing no" ;;
  46           esac
  47          ])
  48        rm -f conftest.a conftest.b conftest.lnk])
  49     case "$gl_cv_func_link_works" in
  50       *yes) ;;
  51       *)
  52         REPLACE_LINK=1
  53         ;;
  54     esac
  55   fi
  56 ])