m4/rintf.m4

   1 # rintf.m4 serial 4
   2 dnl Copyright (C) 2011-2018 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_RINTF],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10
  11   dnl Persuade glibc <math.h> to declare rintf().
  12   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  13
  14   dnl Determine RINTF_LIBM.
  15   gl_MATHFUNC([rintf], [float], [(float)],
  16     [extern
  17      #ifdef __cplusplus
  18      "C"
  19      #endif
  20      float rintf (float);
  21     ])
  22   if test $gl_cv_func_rintf_no_libm = yes \
  23      || test $gl_cv_func_rintf_in_libm = yes; then
  24     HAVE_RINTF=1
  25     dnl Also check whether it's declared.
  26     dnl IRIX 6.5 has rintf() in libm but doesn't declare it in <math.h>.
  27     AC_CHECK_DECLS([rintf], , [HAVE_DECL_RINTF=0], [[#include <math.h>]])
  28   else
  29     HAVE_RINTF=0
  30     HAVE_DECL_RINTF=0
  31     RINTF_LIBM=
  32   fi
  33   AC_SUBST([RINTF_LIBM])
  34 ])