m4/log2f.m4

   1 # log2f.m4 serial 7
   2 dnl Copyright (C) 2010-2018 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_LOG2F],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_log2f_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11   AC_REQUIRE([gl_FUNC_LOG2])
  12
  13   dnl Persuade glibc <math.h> to declare log2f().
  14   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  15
  16   dnl Determine LOG2F_LIBM.
  17   gl_COMMON_DOUBLE_MATHFUNC([log2f])
  18
  19   dnl Test whether log2f() exists.
  20   save_LIBS="$LIBS"
  21   LIBS="$LIBS $LOG2F_LIBM"
  22   AC_CHECK_FUNCS([log2f])
  23   LIBS="$save_LIBS"
  24   if test $ac_cv_func_log2f = yes; then
  25     HAVE_LOG2F=1
  26     dnl Also check whether it's declared.
  27     dnl IRIX 6.5 has log2f() in libm but doesn't declare it in <math.h>.
  28     AC_CHECK_DECL([log2f], , [HAVE_DECL_LOG2F=0], [[#include <math.h>]])
  29
  30     save_LIBS="$LIBS"
  31     LIBS="$LIBS $LOG2F_LIBM"
  32     gl_FUNC_LOG2F_WORKS
  33     LIBS="$save_LIBS"
  34     case "$gl_cv_func_log2f_works" in
  35       *yes) ;;
  36       *) REPLACE_LOG2F=1 ;;
  37     esac
  38
  39     m4_ifdef([gl_FUNC_LOG2F_IEEE], [
  40       if test $gl_log2f_required = ieee && test $REPLACE_LOG2F = 0; then
  41         AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  42         AC_CACHE_CHECK([whether log2f works according to ISO C 99 with IEC 60559],
  43           [gl_cv_func_log2f_ieee],
  44           [
  45             save_LIBS="$LIBS"
  46             LIBS="$LIBS $LOG2F_LIBM"
  47             AC_RUN_IFELSE(
  48               [AC_LANG_SOURCE([[
  49 #ifndef __NO_MATH_INLINES
  50 # define __NO_MATH_INLINES 1 /* for glibc */
  51 #endif
  52 #include <math.h>
  53 #ifndef log2f /* for Cygwin 1.7.x */
  54 extern
  55 #ifdef __cplusplus
  56 "C"
  57 #endif
  58 float log2f (float);
  59 #endif
  60 /* Compare two numbers with ==.
  61    This is a separate function because IRIX 6.5 "cc -O" miscompiles an
  62    'x == x' test.  */
  63 static int
  64 numeric_equal (float x, float y)
  65 {
  66   return x == y;
  67 }
  68 static float dummy (float x) { return 0; }
  69 int main (int argc, char *argv[])
  70 {
  71   float (*my_log2f) (float) = argc ? log2f : dummy;
  72   /* Test log2f(negative).
  73      This test fails on NetBSD 5.1 and Solaris 10/x86_64.  */
  74   float y = my_log2f (-1.0f);
  75   if (numeric_equal (y, y))
  76     return 1;
  77   return 0;
  78 }
  79               ]])],
  80               [gl_cv_func_log2f_ieee=yes],
  81               [gl_cv_func_log2f_ieee=no],
  82               [case "$host_os" in
  83                                 # Guess yes on glibc systems.
  84                  *-gnu* | gnu*) gl_cv_func_log2f_ieee="guessing yes" ;;
  85                                 # Guess yes on native Windows.
  86                  mingw*)        gl_cv_func_log2f_ieee="guessing yes" ;;
  87                                 # If we don't know, assume the worst.
  88                  *)             gl_cv_func_log2f_ieee="guessing no" ;;
  89                esac
  90               ])
  91             LIBS="$save_LIBS"
  92           ])
  93         case "$gl_cv_func_log2f_ieee" in
  94           *yes) ;;
  95           *) REPLACE_LOG2F=1 ;;
  96         esac
  97       fi
  98     ])
  99   else
 100     HAVE_LOG2F=0
 101     HAVE_DECL_LOG2F=0
 102   fi
 103   if test $HAVE_LOG2F = 0 || test $REPLACE_LOG2F = 1; then
 104     dnl Find libraries needed to link lib/log2f.c.
 105     if test $ac_cv_func_log2 = yes; then
 106       AC_DEFINE([HAVE_LOG2], [1],
 107         [Define to 1 if the log2() function is available in libc or libm.])
 108       LOG2F_LIBM="$LOG2_LIBM"
 109     else
 110       AC_REQUIRE([gl_FUNC_ISNANF])
 111       AC_REQUIRE([gl_FUNC_FREXPF])
 112       AC_REQUIRE([gl_FUNC_LOGF])
 113       LOG2F_LIBM=
 114       dnl Append $ISNANF_LIBM to LOG2F_LIBM, avoiding gratuitous duplicates.
 115       case " $LOG2F_LIBM " in
 116         *" $ISNANF_LIBM "*) ;;
 117         *) LOG2F_LIBM="$LOG2F_LIBM $ISNANF_LIBM" ;;
 118       esac
 119       dnl Append $FREXPF_LIBM to LOG2F_LIBM, avoiding gratuitous duplicates.
 120       case " $LOG2F_LIBM " in
 121         *" $FREXPF_LIBM "*) ;;
 122         *) LOG2F_LIBM="$LOG2F_LIBM $FREXPF_LIBM" ;;
 123       esac
 124       dnl Append $LOGF_LIBM to LOG2F_LIBM, avoiding gratuitous duplicates.
 125       case " $LOG2F_LIBM " in
 126         *" $LOGF_LIBM "*) ;;
 127         *) LOG2F_LIBM="$LOG2F_LIBM $LOGF_LIBM" ;;
 128       esac
 129     fi
 130   fi
 131 ])
 132
 133 dnl Test whether log2() works.
 134 dnl On OSF/1 5.1, log2f(-0.0f) is NaN.
 135 dnl On Cygwin 1.7.9, log2f(2^13) is not exactly 13.
 136 AC_DEFUN([gl_FUNC_LOG2F_WORKS],
 137 [
 138   AC_REQUIRE([AC_PROG_CC])
 139   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
 140   AC_CACHE_CHECK([whether log2f works], [gl_cv_func_log2f_works],
 141     [
 142       AC_RUN_IFELSE(
 143         [AC_LANG_SOURCE([[
 144 #include <math.h>
 145 #ifndef log2f /* for Cygwin 1.7.x */
 146 extern
 147 #ifdef __cplusplus
 148 "C"
 149 #endif
 150 float log2f (float);
 151 #endif
 152 volatile float x;
 153 volatile float y;
 154 int main ()
 155 {
 156   int result = 0;
 157   /* This test fails on OSF/1 5.1.  */
 158   x = -0.0f;
 159   y = log2f (x);
 160   if (!(y + y == y))
 161     result |= 1;
 162   /* This test fails on Cygwin 1.7.9.  */
 163   x = 8192.0f;
 164   y = log2f (x);
 165   if (!(y == 13.0f))
 166     result |= 2;
 167   return result;
 168 }
 169 ]])],
 170         [gl_cv_func_log2f_works=yes],
 171         [gl_cv_func_log2f_works=no],
 172         [case "$host_os" in
 173            cygwin* | osf*) gl_cv_func_log2f_works="guessing no" ;;
 174                            # Guess yes on native Windows.
 175            mingw*)         gl_cv_func_log2f_works="guessing yes" ;;
 176            *)              gl_cv_func_log2f_works="guessing yes" ;;
 177          esac
 178         ])
 179     ])
 180 ])