m4/grantpt.m4

   1 # grantpt.m4 serial 3
   2 dnl Copyright (C) 2010-2018 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_GRANTPT],
   8 [
   9   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  10
  11   dnl Persuade glibc <stdlib.h> to declare grantpt().
  12   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  13
  14   dnl We can't use AC_CHECK_FUNC here, because grantpt() is defined as a
  15   dnl static inline function when compiling for Android 4.4 or older.
  16   AC_CACHE_CHECK([for grantpt], [gl_cv_func_grantpt],
  17     [AC_LINK_IFELSE(
  18        [AC_LANG_PROGRAM(
  19           [[#include <stdlib.h>]],
  20           [[return grantpt(0);]])
  21        ],
  22        [gl_cv_func_grantpt=yes],
  23        [gl_cv_func_grantpt=no])
  24     ])
  25   if test $gl_cv_func_grantpt = no; then
  26     HAVE_GRANTPT=0
  27   fi
  28 ])
  29
  30 # Prerequisites of lib/grantpt.c.
  31 AC_DEFUN([gl_PREREQ_GRANTPT], [
  32   AC_CHECK_FUNCS([setrlimit])
  33 ])