m4/floorf.m4

   1 # floorf.m4 serial 15
   2 dnl Copyright (C) 2007, 2009-2018 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FLOORF],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_floorf_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11   dnl Persuade glibc <math.h> to declare floorf().
  12   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  13   dnl Test whether floorf() is declared.
  14   AC_CHECK_DECLS([floorf], , , [[#include <math.h>]])
  15   if test "$ac_cv_have_decl_floorf" = yes; then
  16     dnl Test whether floorf() can be used without libm.
  17     gl_FUNC_FLOORF_LIBS
  18     if test "$FLOORF_LIBM" = "?"; then
  19       dnl Sun C 5.0 on Solaris declares floorf() and has it in the system-wide
  20       dnl libm.so, but not in the libm.so that the compiler uses.
  21       REPLACE_FLOORF=1
  22     fi
  23     m4_ifdef([gl_FUNC_FLOORF_IEEE], [
  24       if test $gl_floorf_required = ieee && test $REPLACE_FLOORF = 0; then
  25         AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  26         AC_CACHE_CHECK([whether floorf works according to ISO C 99 with IEC 60559],
  27           [gl_cv_func_floorf_ieee],
  28           [
  29             save_LIBS="$LIBS"
  30             LIBS="$LIBS $FLOORF_LIBM"
  31             AC_RUN_IFELSE(
  32               [AC_LANG_SOURCE([[
  33 #ifndef __NO_MATH_INLINES
  34 # define __NO_MATH_INLINES 1 /* for glibc */
  35 #endif
  36 #include <math.h>
  37 ]gl_FLOAT_MINUS_ZERO_CODE[
  38 ]gl_FLOAT_SIGNBIT_CODE[
  39 static float dummy (float f) { return 0; }
  40 int main (int argc, char *argv[])
  41 {
  42   float (*my_floorf) (float) = argc ? floorf : dummy;
  43   /* Test whether floorf (-0.0f) is -0.0f.  */
  44   if (signbitf (minus_zerof) && !signbitf (my_floorf (minus_zerof)))
  45     return 1;
  46   return 0;
  47 }
  48               ]])],
  49               [gl_cv_func_floorf_ieee=yes],
  50               [gl_cv_func_floorf_ieee=no],
  51               [case "$host_os" in
  52                                 # Guess yes on glibc systems.
  53                  *-gnu* | gnu*) gl_cv_func_floorf_ieee="guessing yes" ;;
  54                                 # Guess yes on native Windows.
  55                  mingw*)        gl_cv_func_floorf_ieee="guessing yes" ;;
  56                                 # If we don't know, assume the worst.
  57                  *)             gl_cv_func_floorf_ieee="guessing no" ;;
  58                esac
  59               ])
  60             LIBS="$save_LIBS"
  61           ])
  62         case "$gl_cv_func_floorf_ieee" in
  63           *yes) ;;
  64           *) REPLACE_FLOORF=1 ;;
  65         esac
  66       fi
  67     ])
  68   else
  69     HAVE_DECL_FLOORF=0
  70   fi
  71   if test $HAVE_DECL_FLOORF = 0 || test $REPLACE_FLOORF = 1; then
  72     dnl No libraries are needed to link lib/floorf.c.
  73     FLOORF_LIBM=
  74   fi
  75   AC_SUBST([FLOORF_LIBM])
  76 ])
  77
  78 # Determines the libraries needed to get the floorf() function.
  79 # Sets FLOORF_LIBM.
  80 AC_DEFUN([gl_FUNC_FLOORF_LIBS],
  81 [
  82   gl_CACHE_VAL_SILENT([gl_cv_func_floorf_libm], [
  83     gl_cv_func_floorf_libm=?
  84     AC_LINK_IFELSE(
  85       [AC_LANG_PROGRAM(
  86          [[#ifndef __NO_MATH_INLINES
  87            # define __NO_MATH_INLINES 1 /* for glibc */
  88            #endif
  89            #include <math.h>
  90            float (*funcptr) (float) = floorf;
  91            float x;]],
  92          [[x = funcptr(x) + floorf(x);]])],
  93       [gl_cv_func_floorf_libm=])
  94     if test "$gl_cv_func_floorf_libm" = "?"; then
  95       save_LIBS="$LIBS"
  96       LIBS="$LIBS -lm"
  97       AC_LINK_IFELSE(
  98         [AC_LANG_PROGRAM(
  99            [[#ifndef __NO_MATH_INLINES
 100              # define __NO_MATH_INLINES 1 /* for glibc */
 101              #endif
 102              #include <math.h>
 103              float (*funcptr) (float) = floorf;
 104              float x;]],
 105            [[x = funcptr(x) + floorf(x);]])],
 106         [gl_cv_func_floorf_libm="-lm"])
 107       LIBS="$save_LIBS"
 108     fi
 109   ])
 110   FLOORF_LIBM="$gl_cv_func_floorf_libm"
 111 ])