m4/host-cpu-c-abi.m4

   1 # host-cpu-c-abi.m4 serial 3
   2 dnl Copyright (C) 2002-2017 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Bruno Haible and Sam Steingold.
   8
   9 dnl Sets the HOST_CPU variable to the canonical name of the CPU.
  10 dnl Sets the HOST_CPU_C_ABI variable to the canonical name of the CPU with its
  11 dnl C language ABI (application binary interface).
  12 dnl Also defines __${HOST_CPU}__ and __${HOST_CPU_C_ABI}__ as C macros in
  13 dnl config.h.
  14 dnl
  15 dnl This canonical name can be used to select a particular assembly language
  16 dnl source file that will interoperate with C code on the given host.
  17 dnl
  18 dnl For example:
  19 dnl * 'i386' and 'sparc' are different canonical names, because code for i386
  20 dnl   will not run on SPARC CPUs and vice versa. They have different
  21 dnl   instruction sets.
  22 dnl * 'sparc' and 'sparc64' are different canonical names, because code for
  23 dnl   'sparc' and code for 'sparc64' cannot be linked together: 'sparc' code
  24 dnl   contains 32-bit instructions, whereas 'sparc64' code contains 64-bit
  25 dnl   instructions. A process on a SPARC CPU can be in 32-bit mode or in 64-bit
  26 dnl   mode, but not both.
  27 dnl * 'mips' and 'mipsn32' are different canonical names, because they use
  28 dnl   different argument passing and return conventions for C functions, and
  29 dnl   although the instruction set of 'mips' is a large subset of the
  30 dnl   instruction set of 'mipsn32'.
  31 dnl * 'mipsn32' and 'mips64' are different canonical names, because they use
  32 dnl   different sizes for the C types like 'int' and 'void *', and although
  33 dnl   the instruction sets of 'mipsn32' and 'mips64' are the same.
  34 dnl * The same canonical name is used for different endiannesses. You can
  35 dnl   determine the endianness through preprocessor symbols:
  36 dnl   - 'arm': test __ARMEL__.
  37 dnl   - 'mips', 'mipsn32', 'mips64': test _MIPSEB vs. _MIPSEL.
  38 dnl   - 'powerpc64': test _BIG_ENDIAN vs. _LITTLE_ENDIAN.
  39 dnl * The same name 'i386' is used for CPUs of type i386, i486, i586
  40 dnl   (Pentium), AMD K7, Pentium II, Pentium IV, etc., because
  41 dnl   - Instructions that do not exist on all of these CPUs (cmpxchg,
  42 dnl     MMX, SSE, SSE2, 3DNow! etc.) are not frequently used. If your
  43 dnl     assembly language source files use such instructions, you will
  44 dnl     need to make the distinction.
  45 dnl   - Speed of execution of the common instruction set is reasonable across
  46 dnl     the entire family of CPUs. If you have assembly language source files
  47 dnl     that are optimized for particular CPU types (like GNU gmp has), you
  48 dnl     will need to make the distinction.
  49 dnl   See <http://en.wikipedia.org/wiki/X86_instruction_listings>.
  50 AC_DEFUN([gl_HOST_CPU_C_ABI],
  51 [
  52   AC_REQUIRE([AC_CANONICAL_HOST])
  53   AC_REQUIRE([gl_C_ASM])
  54   AC_CACHE_CHECK([host CPU and C ABI], [gl_cv_host_cpu_c_abi],
  55     [case "$host_cpu" in
  56
  57 changequote(,)dnl
  58        i[4567]86 )
  59 changequote([,])dnl
  60          gl_cv_host_cpu_c_abi=i386
  61          ;;
  62
  63        x86_64 )
  64          # On x86_64 systems, the C compiler may be generating code in one of
  65          # these ABIs:
  66          # - 64-bit instruction set, 64-bit pointers, 64-bit 'long': x86_64.
  67          # - 64-bit instruction set, 64-bit pointers, 32-bit 'long': x86_64
  68          #   with native Windows (mingw, MSVC).
  69          # - 64-bit instruction set, 32-bit pointers, 32-bit 'long': x86_64-x32.
  70          # - 32-bit instruction set, 32-bit pointers, 32-bit 'long': i386.
  71          AC_EGREP_CPP([yes],
  72            [#if defined __x86_64__ || defined __amd64__ || defined _M_X64 || defined _M_AMD64
  73             yes
  74             #endif],
  75            [AC_EGREP_CPP([yes],
  76               [#if defined __ILP32__ || defined _ILP32
  77                yes
  78                #endif],
  79               [gl_cv_host_cpu_c_abi=x86_64-x32],
  80               [gl_cv_host_cpu_c_abi=x86_64])],
  81            [gl_cv_host_cpu_c_abi=i386])
  82          ;;
  83
  84 changequote(,)dnl
  85        alphaev[4-8] | alphaev56 | alphapca5[67] | alphaev6[78] )
  86 changequote([,])dnl
  87          gl_cv_host_cpu_c_abi=alpha
  88          ;;
  89
  90        arm* | aarch64 )
  91          # Assume arm with EABI.
  92          # On arm64, the C compiler may be generating 64-bit (= aarch64) code
  93          # or 32-bit (= arm) code.
  94          AC_EGREP_CPP([yes],
  95            [#if defined(__aarch64__) || defined(__ARM_64BIT_STATE) || defined(__ARM_PCS_AAPCS64)
  96             yes
  97             #endif],
  98            [gl_cv_host_cpu_c_abi=arm64],
  99            [# Don't distinguish little-endian and big-endian arm, since they
 100             # don't require different machine code for simple operations and
 101             # since the user can distinguish them through the preprocessot
 102             # defines __ARMEL__ vs. __ARMEB__.
 103             # But distinguish arm which passes floating-point arguments and
 104             # return values in integer registers (r0, r1, ...) - this is
 105             # gcc -mfloat-abi=soft or gcc -mfloat-abi=softfp - from arm which
 106             # passes them in float registers (s0, s1, ...) and double registers
 107             # (d0, d1, ...) - rhis is gcc -mfloat-abi=hard. GCC 4.6 or newer
 108             # sets the preprocessor defines __ARM_PCS (for the first case) and
 109             # __ARM_PCS_VFP (for the second case), but older GCC does not.
 110             echo 'double ddd; void func (double dd) { ddd = dd; }' > conftest.c
 111             # Look for a reference to the register d0 in the .s file.
 112             AC_TRY_COMMAND(${CC-cc} $CFLAGS $CPPFLAGS $gl_c_asm_opt conftest.c) >/dev/null 2>&1
 113             if LC_ALL=C grep -E 'd0,' conftest.$gl_asmext >/dev/null; then
 114               gl_cv_host_cpu_c_abi=armhf
 115             else
 116               gl_cv_host_cpu_c_abi=arm
 117             fi
 118             rm -f conftest*
 119            ])
 120          ;;
 121
 122        hppa1.0 | hppa1.1 | hppa2.0* | hppa64 )
 123          # On hppa, the C compiler may be generating 32-bit code or 64-bit
 124          # code. In the latter case, it defines _LP64 and __LP64__.
 125          AC_EGREP_CPP([yes],
 126            [#if defined(__LP64__)
 127             yes
 128             #endif],
 129            [gl_cv_host_cpu_c_abi=hppa64],
 130            [gl_cv_host_cpu_c_abi=hppa])
 131          ;;
 132
 133        mips* )
 134          # We should also check for (_MIPS_SZPTR == 64), but gcc keeps this
 135          # at 32.
 136          AC_EGREP_CPP([yes],
 137            [#if defined _MIPS_SZLONG && (_MIPS_SZLONG == 64)
 138             yes
 139             #endif],
 140            [gl_cv_host_cpu_c_abi=mips64],
 141            [# Strictly speaking, the MIPS ABI (-32 or -n32) is independent
 142             # from the CPU identification (-mips[12] or -mips[34]). But -n32
 143             # is commonly used together with -mips3, and it's easier to test
 144             # the CPU identification.
 145             AC_EGREP_CPP([yes],
 146               [#if __mips >= 3
 147                yes
 148                #endif],
 149               [gl_cv_host_cpu_c_abi=mipsn32],
 150               [gl_cv_host_cpu_c_abi=mips])])
 151          ;;
 152
 153        powerpc* )
 154          # Different ABIs are in use on AIX vs. Mac OS X vs. Linux,*BSD.
 155          # No need to distinguish them here; the caller may distinguish
 156          # them based on the OS.
 157          # On powerpc64 systems, the C compiler may still be generating
 158          # 32-bit code. And on powerpc-ibm-aix systems, the C compiler may
 159          # be generating 64-bit code.
 160          AC_EGREP_CPP([yes],
 161            [#if defined __powerpc64__ || defined _ARCH_PPC64
 162             yes
 163             #endif],
 164            [# On powerpc64, there are two ABIs on Linux: The AIX compatible
 165             # one and the ELFv2 one. The latter defines _CALL_ELF=2.
 166             AC_EGREP_CPP([yes],
 167               [#if defined _CALL_ELF && _CALL_ELF == 2
 168                yes
 169                #endif],
 170               [gl_cv_host_cpu_c_abi=powerpc64-elfv2],
 171               [gl_cv_host_cpu_c_abi=powerpc64])
 172            ],
 173            [gl_cv_host_cpu_c_abi=powerpc])
 174          ;;
 175
 176        rs6000 )
 177          gl_cv_host_cpu_c_abi=powerpc
 178          ;;
 179
 180        s390* )
 181          # On s390x, the C compiler may be generating 64-bit (= s390x) code
 182          # or 31-bit (= s390) code.
 183          AC_EGREP_CPP([yes],
 184            [#if defined(__LP64__) || defined(__s390x__)
 185             yes
 186             #endif],
 187            [gl_cv_host_cpu_c_abi=s390x],
 188            [gl_cv_host_cpu_c_abi=s390])
 189          ;;
 190
 191        sparc | sparc64 )
 192          # UltraSPARCs running Linux have `uname -m` = "sparc64", but the
 193          # C compiler still generates 32-bit code.
 194          AC_EGREP_CPP([yes],
 195            [#if defined __sparcv9 || defined __arch64__
 196             yes
 197             #endif],
 198            [gl_cv_host_cpu_c_abi=sparc64],
 199            [gl_cv_host_cpu_c_abi=sparc])
 200          ;;
 201
 202        *)
 203          gl_cv_host_cpu_c_abi="$host_cpu"
 204          ;;
 205      esac
 206     ])
 207
 208   dnl In most cases, $HOST_CPU and $HOST_CPU_C_ABI are the same.
 209   HOST_CPU=`echo "$gl_cv_host_cpu_c_abi" | sed -e 's/-.*//'`
 210   HOST_CPU_C_ABI="$gl_cv_host_cpu_c_abi"
 211   AC_SUBST([HOST_CPU])
 212   AC_SUBST([HOST_CPU_C_ABI])
 213
 214   # This was
 215   #   AC_DEFINE_UNQUOTED([__${HOST_CPU}__])
 216   #   AC_DEFINE_UNQUOTED([__${HOST_CPU_C_ABI}__])
 217   # earlier, but KAI C++ 3.2d doesn't like this.
 218   sed -e 's/-/_/g' >> confdefs.h <<EOF
 219 #ifndef __${HOST_CPU}__
 220 #define __${HOST_CPU}__ 1
 221 #endif
 222 #ifndef __${HOST_CPU_C_ABI}__
 223 #define __${HOST_CPU_C_ABI}__ 1
 224 #endif
 225 EOF
 226   AH_TOP([/* CPU and C ABI indicator */
 227 #ifndef __i386__
 228 #undef __i386__
 229 #endif
 230 #ifndef __x86_64_x32__
 231 #undef __x86_64_x32__
 232 #endif
 233 #ifndef __x86_64__
 234 #undef __x86_64__
 235 #endif
 236 #ifndef __alpha__
 237 #undef __alpha__
 238 #endif
 239 #ifndef __arm__
 240 #undef __arm__
 241 #endif
 242 #ifndef __armhf__
 243 #undef __armhf__
 244 #endif
 245 #ifndef __arm64__
 246 #undef __arm64__
 247 #endif
 248 #ifndef __hppa__
 249 #undef __hppa__
 250 #endif
 251 #ifndef __hppa64__
 252 #undef __hppa64__
 253 #endif
 254 #ifndef __ia64__
 255 #undef __ia64__
 256 #endif
 257 #ifndef __m68k__
 258 #undef __m68k__
 259 #endif
 260 #ifndef __mips__
 261 #undef __mips__
 262 #endif
 263 #ifndef __mipsn32__
 264 #undef __mipsn32__
 265 #endif
 266 #ifndef __mips64__
 267 #undef __mips64__
 268 #endif
 269 #ifndef __powerpc__
 270 #undef __powerpc__
 271 #endif
 272 #ifndef __powerpc64__
 273 #undef __powerpc64__
 274 #endif
 275 #ifndef __powerpc64_elfv2__
 276 #undef __powerpc64_elfv2__
 277 #endif
 278 #ifndef __s390__
 279 #undef __s390__
 280 #endif
 281 #ifndef __s390x__
 282 #undef __s390x__
 283 #endif
 284 #ifndef __sh__
 285 #undef __sh__
 286 #endif
 287 #ifndef __sparc__
 288 #undef __sparc__
 289 #endif
 290 #ifndef __sparc64__
 291 #undef __sparc64__
 292 #endif
 293 ])
 294
 295 ])