m4/d-ino.m4

   1 # serial 15
   2
   3 dnl From Jim Meyering.
   4 dnl
   5 dnl Check whether struct dirent has a member named d_ino.
   6 dnl
   7
   8 # Copyright (C) 1997, 1999-2001, 2003-2004, 2006-2007, 2009-2017 Free Software
   9 # Foundation, Inc.
  10
  11 # This file is free software; the Free Software Foundation
  12 # gives unlimited permission to copy and/or distribute it,
  13 # with or without modifications, as long as this notice is preserved.
  14
  15 AC_DEFUN([gl_CHECK_TYPE_STRUCT_DIRENT_D_INO],
  16   [AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  17    AC_CACHE_CHECK([for d_ino member in directory struct],
  18                   gl_cv_struct_dirent_d_ino,
  19      [AC_RUN_IFELSE(
  20         [AC_LANG_PROGRAM(
  21            [[#include <sys/types.h>
  22              #include <sys/stat.h>
  23              #include <dirent.h>
  24            ]],
  25            [[DIR *dp = opendir (".");
  26              struct dirent *e;
  27              struct stat st;
  28              if (! dp)
  29                return 1;
  30              e = readdir (dp);
  31              if (! e)
  32                return 2;
  33              if (lstat (e->d_name, &st) != 0)
  34                return 3;
  35              if (e->d_ino != st.st_ino)
  36                return 4;
  37              closedir (dp);
  38              return 0;
  39            ]])],
  40            [gl_cv_struct_dirent_d_ino=yes],
  41            [gl_cv_struct_dirent_d_ino=no],
  42            [case "$host_os" in
  43                            # Guess yes on glibc systems with Linux kernel.
  44               linux*-gnu*) gl_cv_struct_dirent_d_ino="guessing yes" ;;
  45                            # If we don't know, assume the worst.
  46               *)           gl_cv_struct_dirent_d_ino="guessing no" ;;
  47             esac
  48            ])])
  49    case "$gl_cv_struct_dirent_d_ino" in
  50      *yes)
  51        AC_DEFINE([D_INO_IN_DIRENT], [1],
  52          [Define if struct dirent has a member d_ino that actually works.])
  53        ;;
  54    esac
  55   ]
  56 )