m4/stdint_h.m4

   1 # stdint_h.m4 serial 9
   2 dnl Copyright (C) 1997-2004, 2006, 2008-2021 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Paul Eggert.
   8
   9 # Define HAVE_STDINT_H_WITH_UINTMAX if <stdint.h> exists,
  10 # doesn't clash with <sys/types.h>, and declares uintmax_t.
  11
  12 AC_DEFUN([gl_AC_HEADER_STDINT_H],
  13 [
  14   AC_CACHE_CHECK([for stdint.h], [gl_cv_header_stdint_h],
  15     [AC_COMPILE_IFELSE(
  16        [AC_LANG_PROGRAM(
  17           [[#include <sys/types.h>
  18             #include <stdint.h>]],
  19           [[uintmax_t i = (uintmax_t) -1; return !i;]])],
  20        [gl_cv_header_stdint_h=yes],
  21        [gl_cv_header_stdint_h=no])])
  22   if test $gl_cv_header_stdint_h = yes; then
  23     AC_DEFINE_UNQUOTED([HAVE_STDINT_H_WITH_UINTMAX], [1],
  24       [Define if <stdint.h> exists, doesn't clash with <sys/types.h>,
  25        and declares uintmax_t. ])
  26   fi
  27 ])