m4/log1p.m4

   1 # log1p.m4 serial 5
   2 dnl Copyright (C) 2012-2018 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_LOG1P],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_log1p_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11
  12   dnl Persuade glibc <math.h> to declare log1p().
  13   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  14
  15   dnl Determine LOG1P_LIBM.
  16   gl_COMMON_DOUBLE_MATHFUNC([log1p])
  17
  18   dnl Test whether log1p() exists.
  19   save_LIBS="$LIBS"
  20   LIBS="$LIBS $LOG1P_LIBM"
  21   AC_CHECK_FUNCS([log1p])
  22   LIBS="$save_LIBS"
  23   if test $ac_cv_func_log1p = yes; then
  24     :
  25     m4_ifdef([gl_FUNC_LOG1P_IEEE], [
  26       if test $gl_log1p_required = ieee && test $REPLACE_LOG1P = 0; then
  27         AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  28         AC_CACHE_CHECK([whether log1p works according to ISO C 99 with IEC 60559],
  29           [gl_cv_func_log1p_ieee],
  30           [
  31             save_LIBS="$LIBS"
  32             LIBS="$LIBS $LOG1P_LIBM"
  33             AC_RUN_IFELSE(
  34               [AC_LANG_SOURCE([[
  35 #ifndef __NO_MATH_INLINES
  36 # define __NO_MATH_INLINES 1 /* for glibc */
  37 #endif
  38 #include <math.h>
  39 ]gl_DOUBLE_MINUS_ZERO_CODE[
  40 ]gl_DOUBLE_SIGNBIT_CODE[
  41 static double dummy (double x) { return 0; }
  42 int main (int argc, char *argv[])
  43 {
  44   double (*my_log1p) (double) = argc ? log1p : dummy;
  45   /* This test fails on AIX, HP-UX 11.  */
  46   double y = my_log1p (minus_zerod);
  47   if (!(y == 0.0) || (signbitd (minus_zerod) && !signbitd (y)))
  48     return 1;
  49   return 0;
  50 }
  51               ]])],
  52               [gl_cv_func_log1p_ieee=yes],
  53               [gl_cv_func_log1p_ieee=no],
  54               [case "$host_os" in
  55                                 # Guess yes on glibc systems.
  56                  *-gnu* | gnu*) gl_cv_func_log1p_ieee="guessing yes" ;;
  57                                 # Guess yes on native Windows.
  58                  mingw*)        gl_cv_func_log1p_ieee="guessing yes" ;;
  59                                 # If we don't know, assume the worst.
  60                  *)             gl_cv_func_log1p_ieee="guessing no" ;;
  61                esac
  62               ])
  63             LIBS="$save_LIBS"
  64           ])
  65         case "$gl_cv_func_log1p_ieee" in
  66           *yes) ;;
  67           *) REPLACE_LOG1P=1 ;;
  68         esac
  69       fi
  70     ])
  71   else
  72     HAVE_LOG1P=0
  73   fi
  74   if test $HAVE_LOG1P = 0 || test $REPLACE_LOG1P = 1; then
  75     dnl Find libraries needed to link lib/log1p.c.
  76     AC_REQUIRE([gl_FUNC_ISNAND])
  77     AC_REQUIRE([gl_FUNC_LOG])
  78     AC_REQUIRE([gl_FUNC_ROUND])
  79     LOG1P_LIBM=
  80     dnl Append $ISNAND_LIBM to LOG1P_LIBM, avoiding gratuitous duplicates.
  81     case " $LOG1P_LIBM " in
  82       *" $ISNAND_LIBM "*) ;;
  83       *) LOG1P_LIBM="$LOG1P_LIBM $ISNAND_LIBM" ;;
  84     esac
  85     dnl Append $LOG_LIBM to LOG1P_LIBM, avoiding gratuitous duplicates.
  86     case " $LOG1P_LIBM " in
  87       *" $LOG_LIBM "*) ;;
  88       *) LOG1P_LIBM="$LOG1P_LIBM $LOG_LIBM" ;;
  89     esac
  90     dnl Append $ROUND_LIBM to LOG1P_LIBM, avoiding gratuitous duplicates.
  91     case " $LOG1P_LIBM " in
  92       *" $ROUND_LIBM "*) ;;
  93       *) LOG1P_LIBM="$LOG1P_LIBM $ROUND_LIBM" ;;
  94     esac
  95   fi
  96 ])