m4/utimensat.m4

   1 # serial 7
   2 # See if we need to provide utimensat replacement.
   3
   4 dnl Copyright (C) 2009-2020 Free Software Foundation, Inc.
   5 dnl This file is free software; the Free Software Foundation
   6 dnl gives unlimited permission to copy and/or distribute it,
   7 dnl with or without modifications, as long as this notice is preserved.
   8
   9 # Written by Eric Blake.
  10
  11 AC_DEFUN([gl_FUNC_UTIMENSAT],
  12 [
  13   AC_REQUIRE([gl_SYS_STAT_H_DEFAULTS])
  14   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  15   AC_CHECK_FUNCS_ONCE([utimensat])
  16   if test $ac_cv_func_utimensat = no; then
  17     HAVE_UTIMENSAT=0
  18   else
  19     AC_CACHE_CHECK([whether utimensat works],
  20       [gl_cv_func_utimensat_works],
  21       [AC_RUN_IFELSE(
  22          [AC_LANG_PROGRAM([[
  23 #include <fcntl.h>
  24 #include <sys/stat.h>
  25 #include <unistd.h>
  26 ]GL_MDA_DEFINES],
  27             [[int result = 0;
  28               const char *f = "conftest.file";
  29               if (close (creat (f, 0600)))
  30                 return 1;
  31               /* Test whether the AT_SYMLINK_NOFOLLOW flag is supported.  */
  32               {
  33                 if (utimensat (AT_FDCWD, f, NULL, AT_SYMLINK_NOFOLLOW))
  34                   result |= 2;
  35               }
  36               /* Test whether UTIME_NOW and UTIME_OMIT work.  */
  37               {
  38                 struct timespec ts[2];
  39                 ts[0].tv_sec = 1;
  40                 ts[0].tv_nsec = UTIME_OMIT;
  41                 ts[1].tv_sec = 1;
  42                 ts[1].tv_nsec = UTIME_NOW;
  43                 if (utimensat (AT_FDCWD, f, ts, 0))
  44                   result |= 4;
  45               }
  46               sleep (1);
  47               {
  48                 struct stat st;
  49                 struct timespec ts[2];
  50                 ts[0].tv_sec = 1;
  51                 ts[0].tv_nsec = UTIME_NOW;
  52                 ts[1].tv_sec = 1;
  53                 ts[1].tv_nsec = UTIME_OMIT;
  54                 if (utimensat (AT_FDCWD, f, ts, 0))
  55                   result |= 8;
  56                 if (stat (f, &st))
  57                   result |= 16;
  58                 else if (st.st_ctime < st.st_atime)
  59                   result |= 32;
  60               }
  61               return result;
  62             ]])],
  63          [gl_cv_func_utimensat_works=yes],
  64          [gl_cv_func_utimensat_works=no],
  65          [gl_cv_func_utimensat_works="guessing yes"])])
  66     if test "$gl_cv_func_utimensat_works" = no; then
  67       REPLACE_UTIMENSAT=1
  68     fi
  69   fi
  70 ])