m4/termios_h.m4

   1 # termios_h.m4 serial 4
   2 dnl Copyright (C) 2010-2020 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_TERMIOS_H],
   8 [
   9   dnl Use AC_REQUIRE here, so that the default behavior below is expanded
  10   dnl once only, before all statements that occur in other macros.
  11   AC_REQUIRE([gl_TERMIOS_H_DEFAULTS])
  12
  13   gl_CHECK_NEXT_HEADERS([termios.h])
  14   if test $ac_cv_header_termios_h != yes; then
  15     HAVE_TERMIOS_H=0
  16   fi
  17
  18   dnl Ensure the type pid_t gets defined.
  19   AC_REQUIRE([AC_TYPE_PID_T])
  20
  21   dnl Check for declarations of anything we want to poison if the
  22   dnl corresponding gnulib module is not in use, and which is not
  23   dnl guaranteed by C89.
  24   gl_WARN_ON_USE_PREPARE([[#include <termios.h>]],
  25     [tcgetsid])
  26 ])
  27
  28 AC_DEFUN([gl_TERMIOS_MODULE_INDICATOR],
  29 [
  30   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  31   AC_REQUIRE([gl_TERMIOS_H_DEFAULTS])
  32   gl_MODULE_INDICATOR_SET_VARIABLE([$1])
  33   dnl Define it also as a C macro, for the benefit of the unit tests.
  34   gl_MODULE_INDICATOR_FOR_TESTS([$1])
  35 ])
  36
  37 AC_DEFUN([gl_TERMIOS_H_DEFAULTS],
  38 [
  39   GNULIB_TCGETSID=0;      AC_SUBST([GNULIB_TCGETSID])
  40   dnl Assume proper GNU behavior unless another module says otherwise.
  41   HAVE_DECL_TCGETSID=1;   AC_SUBST([HAVE_DECL_TCGETSID])
  42   HAVE_TERMIOS_H=1;       AC_SUBST([HAVE_TERMIOS_H])
  43 ])