m4/tanl.m4

   1 # tanl.m4 serial 9
   2 dnl Copyright (C) 2010-2020 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_TANL],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   AC_REQUIRE([gl_LONG_DOUBLE_VS_DOUBLE])
  11
  12   dnl Persuade glibc <math.h> to declare tanl().
  13   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  14
  15   TANL_LIBM=
  16   AC_CACHE_CHECK([whether tanl() can be used without linking with libm],
  17     [gl_cv_func_tanl_no_libm],
  18     [
  19       AC_LINK_IFELSE(
  20         [AC_LANG_PROGRAM(
  21            [[#ifndef __NO_MATH_INLINES
  22              # define __NO_MATH_INLINES 1 /* for glibc */
  23              #endif
  24              #include <math.h>
  25              long double (* volatile funcptr) (long double) = tanl;
  26              long double x;]],
  27            [[return funcptr (x) > 0.4
  28                     || tanl (x) > 0.4;]])],
  29         [gl_cv_func_tanl_no_libm=yes],
  30         [gl_cv_func_tanl_no_libm=no])
  31     ])
  32   if test $gl_cv_func_tanl_no_libm = no; then
  33     AC_CACHE_CHECK([whether tanl() can be used with libm],
  34       [gl_cv_func_tanl_in_libm],
  35       [
  36         save_LIBS="$LIBS"
  37         LIBS="$LIBS -lm"
  38         AC_LINK_IFELSE(
  39           [AC_LANG_PROGRAM(
  40              [[#ifndef __NO_MATH_INLINES
  41                # define __NO_MATH_INLINES 1 /* for glibc */
  42                #endif
  43                #include <math.h>
  44                long double (* volatile funcptr) (long double) = tanl;
  45                long double x;]],
  46              [[return funcptr (x) > 0.4
  47                       || tanl (x) > 0.4;]])],
  48           [gl_cv_func_tanl_in_libm=yes],
  49           [gl_cv_func_tanl_in_libm=no])
  50         LIBS="$save_LIBS"
  51       ])
  52     if test $gl_cv_func_tanl_in_libm = yes; then
  53       TANL_LIBM=-lm
  54     fi
  55   fi
  56   if test $gl_cv_func_tanl_no_libm = yes \
  57      || test $gl_cv_func_tanl_in_libm = yes; then
  58     dnl Also check whether it's declared.
  59     dnl Mac OS X 10.3 has tanl() in libc but doesn't declare it in <math.h>.
  60     AC_CHECK_DECL([tanl], , [HAVE_DECL_TANL=0], [[#include <math.h>]])
  61   else
  62     HAVE_DECL_TANL=0
  63     HAVE_TANL=0
  64     dnl Find libraries needed to link lib/tanl.c, lib/trigl.c.
  65     if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
  66       AC_REQUIRE([gl_FUNC_TAN])
  67       TANL_LIBM="$TAN_LIBM"
  68     else
  69       AC_REQUIRE([gl_FUNC_ISNANL])
  70       AC_REQUIRE([gl_FUNC_FLOOR])
  71       AC_REQUIRE([gl_FUNC_FLOORL])
  72       dnl Append $ISNANL_LIBM to TANL_LIBM, avoiding gratuitous duplicates.
  73       case " $TANL_LIBM " in
  74         *" $ISNANL_LIBM "*) ;;
  75         *) TANL_LIBM="$TANL_LIBM $ISNANL_LIBM" ;;
  76       esac
  77       dnl Append $FLOOR_LIBM to TANL_LIBM, avoiding gratuitous duplicates.
  78       case " $TANL_LIBM " in
  79         *" $FLOOR_LIBM "*) ;;
  80         *) TANL_LIBM="$TANL_LIBM $FLOOR_LIBM" ;;
  81       esac
  82       dnl Append $FLOORL_LIBM to TANL_LIBM, avoiding gratuitous duplicates.
  83       case " $TANL_LIBM " in
  84         *" $FLOORL_LIBM "*) ;;
  85         *) TANL_LIBM="$TANL_LIBM $FLOORL_LIBM" ;;
  86       esac
  87     fi
  88   fi
  89   AC_SUBST([TANL_LIBM])
  90 ])