m4/sinhf.m4

   1 # sinhf.m4 serial 3
   2 dnl Copyright (C) 2011-2020 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_SINHF],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   AC_REQUIRE([gl_FUNC_SINH])
  11
  12   dnl Persuade glibc <math.h> to declare sinhf().
  13   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  14
  15   dnl Test whether sinhf() exists. Assume that sinhf(), if it exists, is
  16   dnl defined in the same library as sinh().
  17   save_LIBS="$LIBS"
  18   LIBS="$LIBS $SINH_LIBM"
  19   AC_CHECK_FUNCS([sinhf])
  20   LIBS="$save_LIBS"
  21   if test $ac_cv_func_sinhf = yes; then
  22     SINHF_LIBM="$SINH_LIBM"
  23   else
  24     HAVE_SINHF=0
  25     dnl If the function is declared but does not appear to exist, it may be
  26     dnl defined as an inline function. In order to avoid a conflict, we have
  27     dnl to define rpl_sinhf, not sinhf.
  28     AC_CHECK_DECLS([sinhf], [REPLACE_SINHF=1], , [[#include <math.h>]])
  29     SINHF_LIBM="$SINH_LIBM"
  30   fi
  31   AC_SUBST([SINHF_LIBM])
  32 ])