m4/netinet_in_h.m4

   1 # netinet_in_h.m4 serial 5
   2 dnl Copyright (C) 2006-2020 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_HEADER_NETINET_IN],
   8 [
   9   AC_CACHE_CHECK([whether <netinet/in.h> is self-contained],
  10     [gl_cv_header_netinet_in_h_selfcontained],
  11     [
  12       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[]])],
  13         [gl_cv_header_netinet_in_h_selfcontained=yes],
  14         [gl_cv_header_netinet_in_h_selfcontained=no])
  15     ])
  16   if test $gl_cv_header_netinet_in_h_selfcontained = yes; then
  17     NETINET_IN_H=''
  18   else
  19     NETINET_IN_H='netinet/in.h'
  20     AC_CHECK_HEADERS([netinet/in.h])
  21     gl_CHECK_NEXT_HEADERS([netinet/in.h])
  22     if test $ac_cv_header_netinet_in_h = yes; then
  23       HAVE_NETINET_IN_H=1
  24     else
  25       HAVE_NETINET_IN_H=0
  26     fi
  27     AC_SUBST([HAVE_NETINET_IN_H])
  28   fi
  29   AC_SUBST([NETINET_IN_H])
  30   AM_CONDITIONAL([GL_GENERATE_NETINET_IN_H], [test -n "$NETINET_IN_H"])
  31 ])