m4/memchr.m4

   1 # memchr.m4 serial 16
   2 dnl Copyright (C) 2002-2004, 2009-2020 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN_ONCE([gl_FUNC_MEMCHR],
   8 [
   9   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  10
  11   dnl Check for prerequisites for memory fence checks.
  12   gl_FUNC_MMAP_ANON
  13   AC_CHECK_HEADERS_ONCE([sys/mman.h])
  14   AC_CHECK_FUNCS_ONCE([mprotect])
  15
  16   AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
  17   # Detect platform-specific bugs in some versions of glibc:
  18   # memchr should not dereference anything with length 0
  19   #   https://bugzilla.redhat.com/show_bug.cgi?id=499689
  20   # memchr should not dereference overestimated length after a match
  21   #   https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=521737
  22   #   https://sourceware.org/bugzilla/show_bug.cgi?id=10162
  23   # memchr should cast the second argument to 'unsigned char'.
  24   #   This bug exists in Android 4.3.
  25   # Assume that memchr works on platforms that lack mprotect.
  26   AC_CACHE_CHECK([whether memchr works], [gl_cv_func_memchr_works],
  27     [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  28 #include <string.h>
  29 #if HAVE_SYS_MMAN_H
  30 # include <fcntl.h>
  31 # include <unistd.h>
  32 # include <sys/types.h>
  33 # include <sys/mman.h>
  34 # ifndef MAP_FILE
  35 #  define MAP_FILE 0
  36 # endif
  37 #endif
  38 ]], [[
  39   int result = 0;
  40   char *fence = NULL;
  41 #if HAVE_SYS_MMAN_H && HAVE_MPROTECT
  42 # if HAVE_MAP_ANONYMOUS
  43   const int flags = MAP_ANONYMOUS | MAP_PRIVATE;
  44   const int fd = -1;
  45 # else /* !HAVE_MAP_ANONYMOUS */
  46   const int flags = MAP_FILE | MAP_PRIVATE;
  47   int fd = open ("/dev/zero", O_RDONLY, 0666);
  48   if (fd >= 0)
  49 # endif
  50     {
  51       int pagesize = getpagesize ();
  52       char *two_pages =
  53         (char *) mmap (NULL, 2 * pagesize, PROT_READ | PROT_WRITE,
  54                        flags, fd, 0);
  55       if (two_pages != (char *)(-1)
  56           && mprotect (two_pages + pagesize, pagesize, PROT_NONE) == 0)
  57         fence = two_pages + pagesize;
  58     }
  59 #endif
  60   if (fence)
  61     {
  62       if (memchr (fence, 0, 0))
  63         result |= 1;
  64       strcpy (fence - 9, "12345678");
  65       if (memchr (fence - 9, 0, 79) != fence - 1)
  66         result |= 2;
  67       if (memchr (fence - 1, 0, 3) != fence - 1)
  68         result |= 4;
  69     }
  70   /* Test against bug on Android 4.3.  */
  71   {
  72     char input[3];
  73     input[0] = 'a';
  74     input[1] = 'b';
  75     input[2] = 'c';
  76     if (memchr (input, 0x789abc00 | 'b', 3) != input + 1)
  77       result |= 8;
  78   }
  79   return result;
  80 ]])],
  81        [gl_cv_func_memchr_works=yes],
  82        [gl_cv_func_memchr_works=no],
  83        [case "$host_os" in
  84                            # Guess no on Android.
  85           linux*-android*) gl_cv_func_memchr_works="guessing no" ;;
  86                            # Guess yes on native Windows.
  87           mingw*)          gl_cv_func_memchr_works="guessing yes" ;;
  88                            # If we don't know, obey --enable-cross-guesses.
  89           *)               gl_cv_func_memchr_works="$gl_cross_guess_normal" ;;
  90         esac
  91        ])
  92     ])
  93   case "$gl_cv_func_memchr_works" in
  94     *yes) ;;
  95     *) REPLACE_MEMCHR=1 ;;
  96   esac
  97 ])
  98
  99 # Prerequisites of lib/memchr.c.
 100 AC_DEFUN([gl_PREREQ_MEMCHR], [
 101   AC_CHECK_HEADERS([bp-sym.h])
 102 ])