m4/logl.m4

   1 # logl.m4 serial 14
   2 dnl Copyright (C) 2010-2020 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_LOGL],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   AC_REQUIRE([gl_LONG_DOUBLE_VS_DOUBLE])
  11
  12   dnl Persuade glibc <math.h> to declare logl().
  13   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  14
  15   LOGL_LIBM=
  16   AC_CACHE_CHECK([whether logl() can be used without linking with libm],
  17     [gl_cv_func_logl_no_libm],
  18     [
  19       AC_LINK_IFELSE(
  20         [AC_LANG_PROGRAM(
  21            [[#ifndef __NO_MATH_INLINES
  22              # define __NO_MATH_INLINES 1 /* for glibc */
  23              #endif
  24              #include <math.h>
  25              long double (*funcptr) (long double) = logl;
  26              long double x;]],
  27            [[return funcptr (x) > 1
  28                     || logl (x) > 1;]])],
  29         [gl_cv_func_logl_no_libm=yes],
  30         [gl_cv_func_logl_no_libm=no])
  31     ])
  32   if test $gl_cv_func_logl_no_libm = no; then
  33     AC_CACHE_CHECK([whether logl() can be used with libm],
  34       [gl_cv_func_logl_in_libm],
  35       [
  36         save_LIBS="$LIBS"
  37         LIBS="$LIBS -lm"
  38         AC_LINK_IFELSE(
  39           [AC_LANG_PROGRAM(
  40              [[#ifndef __NO_MATH_INLINES
  41                # define __NO_MATH_INLINES 1 /* for glibc */
  42                #endif
  43                #include <math.h>
  44                long double (*funcptr) (long double) = logl;
  45                long double x;]],
  46              [[return funcptr (x) > 1
  47                       || logl (x) > 1;]])],
  48           [gl_cv_func_logl_in_libm=yes],
  49           [gl_cv_func_logl_in_libm=no])
  50         LIBS="$save_LIBS"
  51       ])
  52     if test $gl_cv_func_logl_in_libm = yes; then
  53       LOGL_LIBM=-lm
  54     fi
  55   fi
  56   if test $gl_cv_func_logl_no_libm = yes \
  57      || test $gl_cv_func_logl_in_libm = yes; then
  58     dnl Also check whether it's declared.
  59     dnl Mac OS X 10.3 has logl() in libc but doesn't declare it in <math.h>.
  60     AC_CHECK_DECL([logl], , [HAVE_DECL_LOGL=0], [[#include <math.h>]])
  61     save_LIBS="$LIBS"
  62     LIBS="$LIBS $LOGL_LIBM"
  63     gl_FUNC_LOGL_WORKS
  64     LIBS="$save_LIBS"
  65     case "$gl_cv_func_logl_works" in
  66       *yes) ;;
  67       *) REPLACE_LOGL=1 ;;
  68     esac
  69   else
  70     HAVE_LOGL=0
  71     HAVE_DECL_LOGL=0
  72   fi
  73   if test $HAVE_LOGL = 0 || test $REPLACE_LOGL = 1; then
  74     dnl Find libraries needed to link lib/logl.c.
  75     if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
  76       AC_REQUIRE([gl_FUNC_LOG])
  77       LOGL_LIBM="$LOG_LIBM"
  78     else
  79       if test $HAVE_LOGL = 0; then
  80         AC_REQUIRE([gl_FUNC_FREXPL])
  81         AC_REQUIRE([gl_FUNC_ISNANL])
  82         AC_REQUIRE([gl_FUNC_FLOORL])
  83         dnl Append $FREXPL_LIBM to LOGL_LIBM, avoiding gratuitous duplicates.
  84         case " $LOGL_LIBM " in
  85           *" $FREXPL_LIBM "*) ;;
  86           *) LOGL_LIBM="$LOGL_LIBM $FREXPL_LIBM" ;;
  87         esac
  88         dnl Append $ISNANL_LIBM to LOGL_LIBM, avoiding gratuitous duplicates.
  89         case " $LOGL_LIBM " in
  90           *" $ISNANL_LIBM "*) ;;
  91           *) LOGL_LIBM="$LOGL_LIBM $ISNANL_LIBM" ;;
  92         esac
  93         dnl Append $FLOORL_LIBM to LOGL_LIBM, avoiding gratuitous duplicates.
  94         case " $LOGL_LIBM " in
  95           *" $FLOORL_LIBM "*) ;;
  96           *) LOGL_LIBM="$LOGL_LIBM $FLOORL_LIBM" ;;
  97         esac
  98       fi
  99     fi
 100   fi
 101   AC_SUBST([LOGL_LIBM])
 102 ])
 103
 104 dnl Test whether logl() works.
 105 dnl On OSF/1 5.1, logl(-0.0L) is NaN.
 106 dnl On NetBSD 9.0, the result is accurate to only 16 digits.
 107 AC_DEFUN([gl_FUNC_LOGL_WORKS],
 108 [
 109   AC_REQUIRE([AC_PROG_CC])
 110   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
 111   AC_CACHE_CHECK([whether logl works], [gl_cv_func_logl_works],
 112     [
 113       AC_RUN_IFELSE(
 114         [AC_LANG_SOURCE([[
 115 #ifndef __NO_MATH_INLINES
 116 # define __NO_MATH_INLINES 1 /* for glibc */
 117 #endif
 118 #include <float.h>
 119 #include <math.h>
 120 /* Override the values of <float.h>, like done in float.in.h.  */
 121 #if defined __i386__ && (defined __BEOS__ || defined __OpenBSD__)
 122 # undef LDBL_MANT_DIG
 123 # define LDBL_MANT_DIG   64
 124 # undef LDBL_MIN_EXP
 125 # define LDBL_MIN_EXP    (-16381)
 126 # undef LDBL_MAX_EXP
 127 # define LDBL_MAX_EXP    16384
 128 #endif
 129 #if defined __i386__ && (defined __FreeBSD__ || defined __DragonFly__)
 130 # undef LDBL_MANT_DIG
 131 # define LDBL_MANT_DIG   64
 132 # undef LDBL_MIN_EXP
 133 # define LDBL_MIN_EXP    (-16381)
 134 # undef LDBL_MAX_EXP
 135 # define LDBL_MAX_EXP    16384
 136 #endif
 137 #if (defined _ARCH_PPC || defined _POWER) && defined _AIX && (LDBL_MANT_DIG == 106) && defined __GNUC__
 138 # undef LDBL_MIN_EXP
 139 # define LDBL_MIN_EXP DBL_MIN_EXP
 140 #endif
 141 #if defined __sgi && (LDBL_MANT_DIG >= 106)
 142 # undef LDBL_MANT_DIG
 143 # define LDBL_MANT_DIG 106
 144 # if defined __GNUC__
 145 #  undef LDBL_MIN_EXP
 146 #  define LDBL_MIN_EXP DBL_MIN_EXP
 147 # endif
 148 #endif
 149 #undef logl
 150 extern
 151 #ifdef __cplusplus
 152 "C"
 153 #endif
 154 long double logl (long double);
 155 static long double dummy (long double x) { return 0; }
 156 volatile long double gx;
 157 long double gy;
 158 int main (int argc, char *argv[])
 159 {
 160   long double (* volatile my_logl) (long double) = argc ? logl : dummy;
 161   int result = 0;
 162   /* This test fails on OSF/1 5.1.  */
 163   {
 164     gx = -0.0L;
 165     gy = logl (gx);
 166     if (!(gy + gy == gy))
 167       result |= 1;
 168   }
 169   /* This test fails on NetBSD 9.0.  */
 170   {
 171     const long double TWO_LDBL_MANT_DIG = /* 2^LDBL_MANT_DIG */
 172       (long double) (1U << ((LDBL_MANT_DIG - 1) / 5))
 173       * (long double) (1U << ((LDBL_MANT_DIG - 1 + 1) / 5))
 174       * (long double) (1U << ((LDBL_MANT_DIG - 1 + 2) / 5))
 175       * (long double) (1U << ((LDBL_MANT_DIG - 1 + 3) / 5))
 176       * (long double) (1U << ((LDBL_MANT_DIG - 1 + 4) / 5));
 177     long double x = 16.981137113807045L;
 178     long double err = (my_logl (x) + my_logl (1.0L / x)) * TWO_LDBL_MANT_DIG;
 179     if (!(err >= -100.0L && err <= 100.0L))
 180       result |= 2;
 181   }
 182
 183   return result;
 184 }
 185 ]])],
 186         [gl_cv_func_logl_works=yes],
 187         [gl_cv_func_logl_works=no],
 188         [case "$host_os" in
 189                           # Guess yes on glibc systems.
 190            *-gnu* | gnu*) gl_cv_func_logl_works="guessing yes" ;;
 191                           # Guess yes on musl systems.
 192            *-musl*)       gl_cv_func_logl_works="guessing yes" ;;
 193                           # Guess yes on native Windows.
 194            mingw*)        gl_cv_func_logl_works="guessing yes" ;;
 195                           # If we don't know, obey --enable-cross-guesses.
 196            *)             gl_cv_func_logl_works="$gl_cross_guess_normal" ;;
 197          esac
 198         ])
 199     ])
 200 ])