m4/fstat.m4

   1 # fstat.m4 serial 7
   2 dnl Copyright (C) 2011-2020 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FSTAT],
   8 [
   9   AC_REQUIRE([AC_CANONICAL_HOST])
  10   AC_REQUIRE([gl_SYS_STAT_H_DEFAULTS])
  11
  12   case "$host_os" in
  13     mingw* | solaris*)
  14       dnl On MinGW, the original stat() returns st_atime, st_mtime,
  15       dnl st_ctime values that are affected by the time zone.
  16       dnl Solaris stat can return a negative tv_nsec.
  17       REPLACE_FSTAT=1
  18       ;;
  19   esac
  20
  21   dnl Replace fstat() for supporting the gnulib-defined open() on directories.
  22   m4_ifdef([gl_FUNC_FCHDIR], [
  23     gl_TEST_FCHDIR
  24     if test $HAVE_FCHDIR = 0; then
  25       case "$gl_cv_func_open_directory_works" in
  26         *yes) ;;
  27         *)
  28           REPLACE_FSTAT=1
  29           ;;
  30       esac
  31     fi
  32   ])
  33 ])
  34
  35 # Prerequisites of lib/fstat.c and lib/stat-w32.c.
  36 AC_DEFUN([gl_PREREQ_FSTAT], [
  37   AC_REQUIRE([gl_HEADER_SYS_STAT_H])
  38   AC_REQUIRE([gl_PREREQ_STAT_W32])
  39   :
  40 ])