m4/acosl.m4

   1 # acosl.m4 serial 9
   2 dnl Copyright (C) 2010-2020 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_ACOSL],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   AC_REQUIRE([gl_LONG_DOUBLE_VS_DOUBLE])
  11
  12   dnl Persuade glibc <math.h> to declare acosl().
  13   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  14
  15   ACOSL_LIBM=
  16   AC_CACHE_CHECK([whether acosl() can be used without linking with libm],
  17     [gl_cv_func_acosl_no_libm],
  18     [
  19       AC_LINK_IFELSE(
  20         [AC_LANG_PROGRAM(
  21            [[#ifndef __NO_MATH_INLINES
  22              # define __NO_MATH_INLINES 1 /* for glibc */
  23              #endif
  24              #include <math.h>
  25              long double (* volatile funcptr) (long double) = acosl;
  26              long double x;]],
  27            [[return funcptr (x) > 1
  28                     || acosl (x) > 1;]])],
  29         [gl_cv_func_acosl_no_libm=yes],
  30         [gl_cv_func_acosl_no_libm=no])
  31     ])
  32   if test $gl_cv_func_acosl_no_libm = no; then
  33     AC_CACHE_CHECK([whether acosl() can be used with libm],
  34       [gl_cv_func_acosl_in_libm],
  35       [
  36         save_LIBS="$LIBS"
  37         LIBS="$LIBS -lm"
  38         AC_LINK_IFELSE(
  39           [AC_LANG_PROGRAM(
  40              [[#ifndef __NO_MATH_INLINES
  41                # define __NO_MATH_INLINES 1 /* for glibc */
  42                #endif
  43                #include <math.h>
  44                long double (* volatile funcptr) (long double) = acosl;
  45                long double x;]],
  46              [[return funcptr (x) > 1
  47                       || acosl (x) > 1;]])],
  48           [gl_cv_func_acosl_in_libm=yes],
  49           [gl_cv_func_acosl_in_libm=no])
  50         LIBS="$save_LIBS"
  51       ])
  52     if test $gl_cv_func_acosl_in_libm = yes; then
  53       ACOSL_LIBM=-lm
  54     fi
  55   fi
  56   if test $gl_cv_func_acosl_no_libm = yes \
  57      || test $gl_cv_func_acosl_in_libm = yes; then
  58     dnl Also check whether it's declared.
  59     dnl Mac OS X 10.3 has acosl() in libc but doesn't declare it in <math.h>.
  60     AC_CHECK_DECL([acosl], , [HAVE_DECL_ACOSL=0], [[#include <math.h>]])
  61   else
  62     HAVE_DECL_ACOSL=0
  63     HAVE_ACOSL=0
  64     dnl Find libraries needed to link lib/acosl.c.
  65     if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
  66       AC_REQUIRE([gl_FUNC_ACOS])
  67       ACOSL_LIBM="$ACOS_LIBM"
  68     else
  69       AC_REQUIRE([gl_FUNC_ASINL])
  70       AC_REQUIRE([gl_FUNC_SQRTL])
  71       dnl Append $ASINL_LIBM to ACOSL_LIBM, avoiding gratuitous duplicates.
  72       case " $ACOSL_LIBM " in
  73         *" $ASINL_LIBM "*) ;;
  74         *) ACOSL_LIBM="$ACOSL_LIBM $ASINL_LIBM" ;;
  75       esac
  76       dnl Append $SQRTL_LIBM to ACOSL_LIBM, avoiding gratuitous duplicates.
  77       case " $ACOSL_LIBM " in
  78         *" $SQRTL_LIBM "*) ;;
  79         *) ACOSL_LIBM="$ACOSL_LIBM $SQRTL_LIBM" ;;
  80       esac
  81     fi
  82   fi
  83   AC_SUBST([ACOSL_LIBM])
  84 ])