m4/mkdir.m4

   1 # serial 12
   2
   3 # Copyright (C) 2001, 2003-2004, 2006, 2008-2017 Free Software Foundation, Inc.
   4 # This file is free software; the Free Software Foundation
   5 # gives unlimited permission to copy and/or distribute it,
   6 # with or without modifications, as long as this notice is preserved.
   7
   8 # On some systems, mkdir ("foo/", 0700) fails because of the trailing slash.
   9 # On others, mkdir ("foo/./", 0700) mistakenly succeeds.
  10 # On such systems, arrange to use a wrapper function.
  11 AC_DEFUN([gl_FUNC_MKDIR],
  12 [dnl
  13   AC_REQUIRE([gl_SYS_STAT_H_DEFAULTS])
  14   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  15   AC_CHECK_HEADERS_ONCE([unistd.h])
  16   AC_CACHE_CHECK([whether mkdir handles trailing slash],
  17     [gl_cv_func_mkdir_trailing_slash_works],
  18     [rm -rf conftest.dir
  19       AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  20 #       include <sys/types.h>
  21 #       include <sys/stat.h>
  22 ]], [return mkdir ("conftest.dir/", 0700);])],
  23       [gl_cv_func_mkdir_trailing_slash_works=yes],
  24       [gl_cv_func_mkdir_trailing_slash_works=no],
  25       [case "$host_os" in
  26                  # Guess yes on glibc systems.
  27          *-gnu*) gl_cv_func_mkdir_trailing_slash_works="guessing yes" ;;
  28                  # Guess yes on MSVC, no on mingw.
  29          mingw*) AC_EGREP_CPP([Known], [
  30 #ifdef _MSC_VER
  31  Known
  32 #endif
  33                    ],
  34                    [gl_cv_func_mkdir_trailing_slash_works="guessing yes"],
  35                    [gl_cv_func_mkdir_trailing_slash_works="guessing no"])
  36                  ;;
  37                  # If we don't know, assume the worst.
  38          *)      gl_cv_func_mkdir_trailing_slash_works="guessing no" ;;
  39        esac
  40       ])
  41     rm -rf conftest.dir
  42     ]
  43   )
  44   case "$gl_cv_func_mkdir_trailing_slash_works" in
  45     *yes) ;;
  46     *)
  47       REPLACE_MKDIR=1
  48       ;;
  49   esac
  50
  51   AC_CACHE_CHECK([whether mkdir handles trailing dot],
  52     [gl_cv_func_mkdir_trailing_dot_works],
  53     [rm -rf conftest.dir
  54       AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  55 #       include <sys/types.h>
  56 #       include <sys/stat.h>
  57 ]], [return !mkdir ("conftest.dir/./", 0700);])],
  58       [gl_cv_func_mkdir_trailing_dot_works=yes],
  59       [gl_cv_func_mkdir_trailing_dot_works=no],
  60       [case "$host_os" in
  61                  # Guess yes on glibc systems.
  62          *-gnu*) gl_cv_func_mkdir_trailing_dot_works="guessing yes" ;;
  63                  # Guess no on native Windows.
  64          mingw*) gl_cv_func_mkdir_trailing_dot_works="guessing no" ;;
  65                  # If we don't know, assume the worst.
  66          *)      gl_cv_func_mkdir_trailing_dot_works="guessing no" ;;
  67        esac
  68       ])
  69     rm -rf conftest.dir
  70     ]
  71   )
  72   case "$gl_cv_func_mkdir_trailing_dot_works" in
  73     *yes) ;;
  74     *)
  75       REPLACE_MKDIR=1
  76       AC_DEFINE([FUNC_MKDIR_DOT_BUG], [1], [Define to 1 if mkdir mistakenly
  77         creates a directory given with a trailing dot component.])
  78       ;;
  79   esac
  80 ])